CMD/BAT

Iska · Отправлено: **11:12, 29-12-2011** | #2

Bigsom85, смотрите пример кода здесь.

Bigsom85 · Отправлено: **13:30, 29-12-2011** | #3

не понял?

что означает On Error Resume Next так начинается составление кода?

Iska · Отправлено: **18:32, 29-12-2011** | #4

Bigsom85, расставьте, пожалуйста, заглавные буквы и знаки препинания в Ваших предложениях, дабы в них появился смысл.

Bigsom85 · Отправлено: **08:05, 30-12-2011** | #5

Цитата:

On Error Resume Next
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objIE = CreateObject("InternetExplorer.Application")
strFile = Wscript.arguments.Item(0)
strFile = objFSO.GetAbsolutePathName(strFile)
If Not(objFSO.FileExists(strFile)) Then
WScript.Echo "Файл не найден"
WScript.Quit End If objIE.Visible = True objIE.Navigate strFile
While objIE.Busy
WScript.Sleep 100 Wend
objIE.ExecWB 6, 2 WScript.Sleep 1000
objIE.Quit

Как его можно разобрать? Вы мне этот код дали для примера, не так ли?!

Iska · Отправлено: **03:22, 31-12-2011** | #6

Bigsom85, попробуйте так (по этому коду):

Код:

Option Explicit

Const READYSTATE_COMPLETE = 4

Const OLECMDID_PRINT = 6
Const OLECMDEXECOPT_DONTPROMPTUSER = 2

Dim strAddress
Dim boolDone


With WScript.CreateObject("InternetExplorer.Application", "IE_")
	.Visible = True
	
	For Each strAddress In Array("http://www.script-coding.com", "http://pda.mail.ru", "http://www.google.com")
		.Navigate strAddress
		
		Do
			WScript.Sleep 100
		Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
		
		boolDone = False
		
		.ExecWB OLECMDID_PRINT, OLECMDEXECOPT_DONTPROMPTUSER
		
		Do
			WScript.Sleep 100
		Loop Until boolDone
	Next
	
	.Quit
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub IE_PrintTemplateTeardown(ByVal pDisp)
	boolDone = True
End Sub
'=============================================================================

«"http://www.script-coding.com", "http://pda.mail.ru", "http://www.google.com"» — меняете на адреса/Url страниц Ваших принтеров. После того, как убедитесь, что всё работает как надо — строку «.Visible = True» можно будет закомментировать.

Bigsom85 · Отправлено: **08:13, 04-01-2012** | #7

Все отлично распечатывает!!!! Большой спс