CMD/BAT - [решено] Автоматизация запуска на удаленных машинах

Iska · Отправлено: **16:07, 30-10-2011** | #2

Eug.., можно попробовать так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

title Waiting child batches...

start "Working with Server 0001..." 0001.cmd ^& exit
start "Working with Server 0002..." 0002.cmd ^& exit
start "Working with Server 0003..." 0003.cmd ^& exit
start "Working with Server 0004..." 0004.cmd ^& exit

:Repeat
	ping.exe -n 2 localhost >nul

	>nul (2>nul tasklist.exe /fi "WINDOWTITLE eq Working with Server 000*" | find.exe /i "cmd.exe") && goto :Repeat

title Now this batch working...

echo Здесь Ваш код

pause

endlocal
exit /b 0

Eug.. · Отправлено: **12:13, 01-11-2011** | #3

Начало отличное - стартуют все 4 cmd-шника оновременно и пока psexec соединяется, окна действительно называются
"Working with ..." и основной job ждет, но как только psexec соеденился и начинается выполнение cmd файлов на самих
серверах, названия окон меняются на \\имя_сервера: путь_к_cmd_файлу, и основной job сразу же стартует (не дождавшись
окончания рабрты cmd-шников на сервере).

Попробовал вставить строку

>nul (2>nul tasklist.exe /fi "WINDOWTITLE eq Working with Server 000*" | find.exe /i "cmd.exe") && goto :Repeat
>nul (2>nul tasklist.exe /fi "WINDOWTITLE eq \\192б168*" | find.exe /i "cmd.exe") && goto :Repeat

- не помогает...

Eug.. · Отправлено: **13:15, 01-11-2011** | #4

О! Вот так - работает! Респект!

@echo off
setlocal enableextensions enabledelayedexpansion

title Waiting child batches...

start "Working with Server 0001..." 0001.cmd ^& exit
start "Working with Server 0002..." 0002.cmd ^& exit
start "Working with Server 0003..." 0003.cmd ^& exit
start "Working with Server 0004..." 0004.cmd ^& exit

:Repeat
ping.exe -n 2 localhost >nul

>nul (2>nul tasklist.exe /fi "WINDOWTITLE eq Working with Server 000*" | find.exe /i "cmd.exe") && goto :Repeat
>nul (2>nul tasklist.exe /fi "WINDOWTITLE eq \\192.168.*" | find.exe /i "cmd.exe") && goto :Repeat

title Now this batch working...

echo Здесь Ваш код

pause

endlocal
exit /b 0

Iska · Отправлено: **13:49, 01-11-2011** | #5

Цитата Eug..:

но как только psexec соеденился и начинается выполнение cmd файлов на самих
серверах, названия окон меняются на \\имя_сервера: путь_к_cmd_файлу, и основной job сразу же стартует (не дождавшись
окончания рабрты cmd-шников на сервере). »

Цитата Eug..:

О! Вот так - работает! »

Ну и славненько

. На самом «PsExec.exe» я не проверял сетевую работу по причине отсутствия на тот момент доступа к самой сети.