[wolkow70]

А чем плох ОБЫЧНЫЙ ярлык? »

1. Полагал, что значок интернета должен сам отражаться на ярлыках url.
2. Браузер по умолчанию Opera.
3. Как обычно все сделал сложнее:

- создал интернет-иконку нейтрального вида, а далее:


!define PRODUCT_WEB_SITE "http://www.xnview.com"

!macro CreateInternetShortcut FILENAME URL ICONFILE ICONINDEX
WriteINIStr "${FILENAME}.url" "InternetShortcut" "URL" "${URL}"
WriteINIStr "${FILENAME}.url" "InternetShortcut" "IconFile" "${ICONFILE}"
WriteINIStr "${FILENAME}.url" "InternetShortcut" "IconIndex" "${ICONINDEX}"
!macroend

!insertmacro CreateInternetShortcut \
"$SMPROGRAMS\${PRODUCT_NAME}\Веб-сайт ${PRODUCT_NAME}" \
"${PRODUCT_WEB_SITE}" \
"$INSTDIR\url.ico" "0"
SectionEnd


Получилось здорово!

[wolkow70]

kotkovets,

Внедряю функцию сохранения настроек для Opera. Столкнулся с проблемой:

Section "PreInstall" sec01
IfFileExists "$APPDATA\Opera\Opera\*.ini" 0 check_localappdata
MessageBox MB_YESNO|MB_ICONQUESTION "Файлы настроек Opera обнаружены в профиле Пользователя. Выполнить резервное копирование файлов настроек для дальнейшего использования? (Будут находиться в каталоге $DOCUMENTS\Opera Backup)" IDNO no_backup
CreateDirectory "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$APPDATA\Opera\Opera\*.adr" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$APPDATA\Opera\Opera\*.ini" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$APPDATA\Opera\Opera\*.xml" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$APPDATA\Opera\Opera\*.dat" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$APPDATA\Opera\Opera\*.js" "$DOCUMENTS\Opera Backup\"
check_localappdata:
IfFileExists "$LOCALAPPDATA\Opera\Opera\cache" 0 check_programdir
MessageBox MB_YESNO|MB_ICONQUESTION "Кэш браузера, файлы почты и иные данные обнаружены в профиле Пользователя. Выполнить резервное копирование данных для дальнейшего использования? (Будут находиться в каталоге $DOCUMENTS\Opera Backup)" IDNO no_backup
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\cache\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\mail\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\application_cache\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\icons\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\thumbnails\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\widgets\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\vps\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\opcashe\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\temporary_downloads\*" "$DOCUMENTS\Opera Backup\"
goto no_backup
check_programdir:
IfFileExists "$INSTDIR\profile\*.ini" 0 no_backup
MessageBox MB_YESNO|MB_ICONQUESTION "Файлы настроек Opera обнаружены в папке назначения. Выполнить резервное копирование файлов настроек для дальнейшего использования? (Будут находиться в каталоге $PROGRAMFILES\Opera Backup)" IDNO no_backup
CreateDirectory "$PROGRAMFILES\Opera Backup\"
CopyFiles "$INSTDIR\Profile\*.xml" "$PROGRAMFILES\Opera Backup\"
CopyFiles "$INSTDIR\Profile\*.ini" "$PROGRAMFILES\Opera Backup\"
CopyFiles "$INSTDIR\Profile\*.adr" "$PROGRAMFILES\Opera Backup\"
CopyFiles "$INSTDIR\Profile\*.dat" "$PROGRAMFILES\Opera Backup\"
CopyFiles "$INSTDIR\Profile\*.js" "$PROGRAMFILES\Opera Backup\"
no_backup:

В общем, резервные копии создаются, но в этом месте:
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\cache\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\mail\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\application_cache\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\icons\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\thumbnails\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\widgets\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\vps\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\opcashe\*" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\temporary_downloads\*" "$DOCUMENTS\Opera Backup\"
копируются как сами папки , так и еще файлы в них содержащиеся отдельно. В результате получается каша...
Хочу посоветоваться в чем может быть дело?

[kotkovets]

wolkow70, вечно вы все перевернете с головы на ноги в тех местах, где совершенно не нужно..рекурсия знаете ли вы...
ну чего уж проще...

Код:

CopyFiles /silent "C:\Documents and Settings\АТС\Рабочий стол\договор" "C:\"

целиком папка договор (и все, что в ней находится) с рабочего стола окажется на диске С:\

[wolkow70]

попроще можно жешь... Код: CreateDirectory "$INSTDIR\config\BACKUP\" CopyFiles /silent "$INSTDIR\config\*" "$INSTDIR\config\BACKUP" »

Не ваша ли рекомендация?

И мне не надо всю папку копировать, а выборочно папки из нее. Поэтому попробовал так.

Убрал \* и нормально стало копироваться.

CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\cache" "$DOCUMENTS\Opera Backup\"
CopyFiles /silent "$LOCALAPPDATA\Opera\Opera\mail" "$DOCUMENTS\Opera Backup\"

[kotkovets]

wolkow70,
исходя из-за каких задач...
CreateDirectory "$INSTDIR\config\BACKUP"
CopyFiles /silent "$INSTDIR\config\*" "$INSTDIR\config\BACKUP"
одно и тоже но... разницу видете - я думаю, что вы не видете
CreateDirectory "$INSTDIR\config\BACKUP"
CopyFiles /silent "$INSTDIR\config" "$INSTDIR\config\BACKUP"

[wolkow70]

wolkow70, исходя из-за каких задач... CreateDirectory "$INSTDIR\config\BACKUP" CopyFiles /silent "$INSTDIR\config\*" "$INSTDIR\config\BACKUP" одно и тоже но... разницу видете - я думаю, что вы не видете CreateDirectory "$INSTDIR\config\BACKUP" CopyFiles /silent "$INSTDIR\config" "$INSTDIR\config\BACKUP" »

Разница в наличии \*
Вот я и написал, что убрал и все заработало.
А что касается задач, то про эту же задачу и шла речь.
Насколько я помню \* означает, что папка будет копироваться со всем вложенным.
Оно и копировалось, только почему-то дублировалось - копировались папки с файлами, и еще файлы отдельно....

[sawe]

Прошу прощения за возможный флуд.
Меня интересует реальный пример заказной страницы с использованием MUI2 и nsDialog.
Страница должна содержать две ${NSD_CreateCheckBox} с поддержкой флагов и памятью,
для выбора ярлыков на Рабочий стол и Быстрый запуск и ниже две радио кнопки для выбора текущего или всех пользователей.
И возможно ли это реализовать без дополнительных секций?

Так же, хотелось бы увидеть имитацию страницы директории в nsDialog с нормальной кнопкой Обзор...
За ранее благодарен!

[kotkovets]

Так же, хотелось бы увидеть имитацию страницы директории в nsDialog с нормальной кнопкой Обзор... »

Все есть и примеры в папке NSIS\Examples\nsDialogs и читать тут обязательно NSIS\Docs\nsDialogs\Readme.html
В общем пример для всех.

тыц

Код:

!include "MUI2.nsh"
!include "FileFunc.nsh"
!insertmacro MUI_PAGE_WELCOME
Page custom fnCustomShow fnCustomLeave
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Russian"
OutFile "nsdSetup.exe"
ShowInstDetails show
InstallDir "$PROGRAMFILES"
Var Text
Var Dialog
Var Radio1
Var Radio2
Var Check1
Var Check2
Var CheckBox1
Var CheckBox2
Var RadioButton1
Var RadioButton2
Var BrowseButton

Function fnCustomShow
    !insertmacro MUI_HEADER_TEXT "O-па!" \
     "Вот оно чё Михалыч!"
  nsDialogs::Create 1018
      Pop $Dialog
/******************************************************************************/
      ${NSD_CreateCheckBox} 0u 0u 100u 10u "Ярлык на рабочий стол"
      Pop $CheckBox1
      ${NSD_OnClick} $CheckBox1 CheckBox1 ;обработка события на клик
      ${If} $Check1 == 1
         ${NSD_SetState} $CheckBox1 1
      ${ElseIf} $Check1 == 0
         ${NSD_SetState} $CheckBox1 0
      ${Else}
         ${NSD_SetState} $CheckBox1 1
      ${EndIf}
/******************************************************************************/
      ${NSD_CreateCheckBox} 0u 15u 140u 10u "Ярлык на панель быстрого запуска"
      Pop $CheckBox2
      ${NSD_OnClick} $CheckBox2 CheckBox2
      ${If} $Check2 == 1
         ${NSD_SetState} $CheckBox2 1
      ${ElseIf} $Check2 == 0
         ${NSD_SetState} $CheckBox2 0
      ${Else}
         ${NSD_SetState} $CheckBox2 0
      ${EndIf}
/******************************************************************************/
      ${NSD_CreateRadioButton} 192u 0u 120u 10u "Для текущего пользователя"
      Pop $RadioButton1
      ${NSD_OnClick} $RadioButton1 RadioButton1
/******************************************************************************/
      ${NSD_CreateRadioButton} 192u 15u 120u 10u "Для всех пользователей"
      Pop $RadioButton2
      ${NSD_OnClick} $RadioButton2 RadioButton2
/******************************************************************************/
      ${If} $Radio1 == 1
      ${OrIf} $Radio2 == 0
           ${NSD_SetState} $RadioButton1 1
           ${NSD_SetState} $RadioButton2 0
      ${ElseIf} $Radio1 == 0
      ${OrIf} $Radio2 == 1
           ${NSD_SetState} $RadioButton1 0
           ${NSD_SetState} $RadioButton2 1
      ${Else}
           ${NSD_SetState} $RadioButton1 1
           ${NSD_SetState} $RadioButton2 0
      ${EndIf}
      ${NSD_CreateBrowseButton} 250u 70u 50u 13u "Обзор..."
      Pop $BrowseButton
      ${NSD_OnClick} $BrowseButton BrowseButton
/******************************************************************************/
      ${NSD_CreateText} 0u 70u 80% 13u "$INSTDIR"
      Pop $Text
      System::Call `shlwapi::SHAutoComplete(i$Text,i1)`
      ${NSD_OnChange} $Text DirChange
/******************************************************************************/
  nsDialogs::Show
FunctionEnd
/******************************************************************************/
Function CheckBox1
  Pop $CheckBox1
  ${NSD_GetState} $CheckBox1 $Check1
FunctionEnd
Function CheckBox2
  Pop $CheckBox2
  ${NSD_GetState} $CheckBox2 $Check2
FunctionEnd
Function RadioButton1
  Pop $RadioButton1
  ${NSD_GetState} $RadioButton1 $Radio1
  ${NSD_GetState} $RadioButton2 $Radio2
FunctionEnd
Function RadioButton2
  Pop $RadioButton2
  ${NSD_GetState} $RadioButton1 $Radio1
  ${NSD_GetState} $RadioButton2 $Radio2
FunctionEnd
/******************************************************************************/
Function BrowseButton
  Pop $BrowseButton
  nsDialogs::SelectFolderDialog "Выберите папку..." "$INSTDIR"
  Pop $INSTDIR
  ${IfNot} $INSTDIR == "error"
     ${NSD_SetText} $Text "$INSTDIR"
  ${EndIf}
FunctionEnd
/******************************************************************************/
Function DirChange
	Pop $Text
	GetDlgItem $0 $HWNDPARENT 1
	${NSD_GetText} $Text `$INSTDIR`
	${GetRoot} $INSTDIR $1
	${If} $INSTDIR == ""
	${OrIf} $1 == ""
		EnableWindow $0 0
	${Else}
		EnableWindow $0 1
	${EndIf}
FunctionEnd
/******************************************************************************/
Function fnCustomLeave
  ${NSD_GetText} $Text "$INSTDIR"
  ${If} $INSTDIR == ""
     Abort
  ${EndIf}
  ${NSD_GetState} $CheckBox1 $Check1
  ${NSD_GetState} $CheckBox2 $Check2
  ${NSD_GetState} $RadioButton1 $Radio1
  ${NSD_GetState} $RadioButton2 $Radio2
FunctionEnd
/******************************************************************************/
/******************************************************************************/
Section Test
   DetailPrint "$$INSTDIR = $INSTDIR"
   DetailPrint ""
/**********/
  ${If} $Check1 = 1
      DetailPrint '"Ярлык на рабочий стол"'
      DetailPrint ""
  ${EndIf}
/**********/
  ${If} $Check2 = 1
      DetailPrint '"Ярлык на панель быстрого запуска"'
      DetailPrint ""
  ${EndIf}
/**********/
  ${If} $Radio1 = 1
      DetailPrint '"Для текущего пользователя"'
      DetailPrint ""
  ${EndIf}
/**********/
  ${If} $Radio2 = 1
      DetailPrint '"Для всех пользователей"'
      DetailPrint ""
  ${EndIf}
SectionEnd

[sawe]

В общем пример для всех.

Большое человеческое спасибо!
Но я имел ввиду две разных (отдельных) страницы, но и этого с головой хватит как основа, там разберёмся.
NSIS\Docs\nsDialogs\Readme.html - мне пока плохо даётся освоить его.
Как то я у вас спрашивал на счёт редактора форм для nsDialogs, вы тогда ответили, что такого нет.
За чем обманывать наивных людей, недавно мне попался NSIS Dialog Designer,
но к сожалению он заточен только под Unicode, но это не беда.

[kotkovets]

Как то я у вас спрашивал на счёт редактора форм для nsDialogs, вы тогда ответили, что такого нет. »

хех, а кто обманывал, первичный релиз 18.04.2011, а когда вы спрашивали?
Сначала почитайте, а потом обвиняйте!!!что за народ пошел ни хрена сами не могут ниче сделать, дай все готовое...