[R.i.m.s.k.y.]

oleg_teacher,
ChangesAssociations=true
ChangesEnvironment=true
и перезапустить тотал/эксплорер

[XNick]

Вот еще вопрос...Как сделать чтобы InnoSetup не создавал файлы удаления для моего приложения, в папке с установленной игрой (uninst000.exe, uninst000.exe)???

[XNick]

Neutron,
Спасибо, комрад!!!!!!

[R.i.m.s.k.y.]

Если можно как-то другим способом жду ваших предложений! »

Способ 1

Код:

[Files]
Source: vorbis.acm; DestDir: {sys}\; Flags: restartreplace

[Registry]
Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows NT\CurrentVersion\drivers.desc"; ValueName: "vorbis.acm"; ValueType: String; ValueData: "Ogg Vorbis Audio CODEC"; Components: ffd; Flags: uninsdeletevalue
Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows NT\CurrentVersion\Drivers32"; ValueName: "msacm.vorbis"; ValueType: String; ValueData: "vorbis.acm"; Components: ffd; Flags: uninsdeletevalue

Способ 2 отсюда http://windata.ru/windows-xp/faq-xp/...andnoj-stroki/

Код:

[Files]
Source: vorbis.acm; DestDir: {tmp}\; Flags: 
Source: vorbis.inf; DestDir: {tmp}\; Flags: 

[Run]
Filename: {sys}\rundll32.exe; Parameters: " syssetup, SetupInfObjectInstallAction DefaultInstall 128 ""{tmp}\vorbis.inf"""; StatusMsg: Установка Vorbis; Flags: runhidden waituntilterminated

Про 3 кнопки не знаю, про две ДА/НЕТ могу подсказать

[nik1967]

Можно ли сделать так, что бы если например какая программа или игра установлена, и при запуске инсталлятора были 3 кнопки Запустить Удалить Отмена? »

Набросал на скорую руку

Код:

#define Name "My Program"

[Setup]
AppName={#Name}
AppVerName={#Name}
DefaultDirName={pf}\{#Name}

[Languages]
Name: rus; MessagesFile: compiler:Languages\Russian.isl

[Messages]
rus.SetupWindowTitle={#Name}

[Files]
;Source: My Program.exe; DestDir: {app}; Flags: ignoreversion nocompression;

[Registry]
Root: HKLM; Subkey: "SOFTWARE\{#Name}"; Flags: uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\{#Name}"; ValueName: "Path"; ValueType: String; ValueData: "{app}\"; Flags: uninsdeletekey

[UninstallDelete]
Type: filesandordirs; Name: {app};

[_Code]
var
  AppDir, unins, run: string;
  ResultCode: Integer;
  UninsButton, RunButton: TButton;
  MyLabel: TLabel;

procedure ReadEntries;
begin
	RegQueryStringValue(HKLM, 'SOFTWARE\{#Name}', 'Path', AppDir);
end;

procedure CancelButtonClick(CurPageID: Integer; var Cancel, Confirm: Boolean);
begin
  Confirm:= False;
end;

procedure Uninstall(Sender: TObject);
begin
  unins:='unins000.exe';
  ReadEntries;
  if not (FileExists(AddBackslash(AppDir) + unins)) then
    MsgBox('Невозможно запустить деинсталляцию программы ' + ExpandConstant('{#Name}') + ', т.к. исполняемый файл деинсталляции unins000.exe не найден.', mbCriticalError, MB_OK or MB_DEFBUTTON1)
  else
    Exec(AddBackslash(AppDir) + unins, '', ExtractFilePath(AddBackslash(AppDir) + unins), SW_SHOW, ewNoWait, ResultCode);
  WizardForm.Close;
end;

procedure RunProgramm(Sender: TObject);
begin
  run:='My Program.exe';
  ReadEntries;
  if (FileExists(AddBackslash(AppDir) + run)) then
    Exec(AddBackslash(AppDir) + run, '', ExtractFilePath(AddBackslash(AppDir) + run), SW_SHOW, ewNoWait, ResultCode);
  WizardForm.Close;
end;

procedure NewForm;
begin
  ReadEntries;
  if (RegValueExists(HKLM, 'SOFTWARE\{#Name}', 'Path')) and (FileExists(ExpandConstant(AppDir)+'\My Program.exe')) then begin
  with WizardForm do
  begin
    ClientWidth := ScaleX(395);
    ClientHeight := ScaleY(120);
    Bevel.Hide;
    InnerNotebook.Hide;
    OuterNotebook.Hide;
    BorderStyle:= bsDialog;
    Center;
    with CancelButton do
    begin
      Left := WizardForm.CancelButton.Left -100;
      Top := WizardForm.ClientHeight - CancelButton.Height - ScaleY(10);
      BringToFront;
    end;
    UninsButton:= TButton.Create(WizardForm);
    with UninsButton do
    begin
      Left := WizardForm.NextButton.Left -100;
      Top := WizardForm.ClientHeight - NextButton.Height - ScaleY(10);
      Width:= WizardForm.NextButton.Width;
      Parent:= WizardForm;
      Caption:= 'Удалить';
      OnClick := @Uninstall;
      BringToFront;
    end;
    RunButton:= TButton.Create(WizardForm);
    with RunButton do
    begin
      Left := WizardForm.BackButton.Left -110;
      Top := WizardForm.ClientHeight - BackButton.Height - ScaleY(10);
      Width:= WizardForm.BackButton.Width;
      Parent:= WizardForm;
      Caption:= 'Запустить';
      OnClick := @RunProgramm;
      BringToFront;
    end;
    MyLabel:= TLabel.Create(WizardForm);
    with MyLabel do
    begin
      SetBounds(10,10,380,80);
      AutoSize:=False;
      WordWrap:=True;
      Font.Color:=$000000;
      Font.Style:=[fsBold];
      Font.Size:=10;
      Parent:=WizardForm;
      Transparent:=True;
      Caption:= 'Программа ' + ExpandConstant('{#Name}') + ' уже установлена на Ваш компьютер.' +#13#13+ 'Выберите нужное действие.';
      end;
    end;
  end;
end;

procedure InitializeWizard;
begin
  NewForm;
end;

[duxa]

nik1967, Благодарю за пример. Только вот у меня работать не хочет. Ветка реестра появляется, а вот выбора нет, стандартное окно приветствия.
Мои замечания: имя деинсталлятора лучше бы было выразить "переменной", т.к. инно в некоторых случаях переименовывает (unins001.exe...)

[nik1967]

duxa,
Повнимательнее. У меня организована проверка не только ветки реестра, но и присутствия запускающего файла (в моём случае My Program.exe). Если его нет, то стандартное окно приветствия.

Код:

if (RegValueExists(HKLM, 'SOFTWARE\{#Name}', 'Path')) and (FileExists(ExpandConstant(AppDir)+'\My Program.exe')) then begin

У меня работает. Я всегда по несколько раз проверяю, прежде чем выложить.

[EvilAlex]

Огромная просьба поправить в скрипте "Откат изменений" !

А то он продолжает установку, а не отменяет ее ...

http://rghost.ru/4224722

Зарание спасибо !