CMD/BAT

amel27 · Отправлено: **17:10, 18-06-2010** | #11

shadowbat, в файл выводятся только файлы, длина пути которых (без расширения) превышает заданный лимит

shadowbat · Отправлено: **18:13, 18-06-2010** | #12

я так понял папка из которой запускается батник не важна.
при таком коде создается пустой cmd

Код:

set $m=C:\08. Дом и Хобби\Йога\Йога - искусство быть стройным\*.pdf
set $f=%~n0_tst.cmd
set mp=60

(for /f "delims=" %%a in ('dir /b/s "%$m%"') do @(
set "b=%%~dpna"& call set "c=%%b:~0,%mp%%%"& call call set "d=%%%%b:%%c%%=%%%%"
if defined d call echo move "%%a" "%%c%%%%~xa"))>"%$f%"

amel27 · Отправлено: **18:25, 18-06-2010** | #13

shadowbat, кодировка самого батника DOS (866)? (блокнот не катит)

shadowbat · Отправлено: **18:58, 18-06-2010** | #14

Цитата amel27:

shadowbat, кодировка самого батника DOS (866)? (блокнот не катит) »

старею... создавал ПКМ -> txt, открывая и сохраняя его через Bred2k. оказывается Bred2k не всегда сохраняет правильно. bat не выполнялся из-за кодировки, благодарю за наводку

РЕШЕНИЕ:

Код:

chcp 1251

set $m=C:\Program Files\*.txt
set $f=%~n0_tst.cmd
set mp=50

(for /f "delims=" %%a in ('dir /b/s "%$m%"') do @(
set "b=%%~dpna"& call set "c=%%b:~0,%mp%%%"& call call set "d=%%%%b:%%c%%=%%%%"
if defined d call echo move "%%a" "%%c%%%%~xa"))>"%$f%"

"%$f%"

chcp 866

P.S. причем если mp меньше "длины пути до файла", то батник вытягивает файл наверх, т.е. удаляет папки начиная с глубины. и чем больше разница между mp и "длиной пути до файла" тем выше окажется конечный файл. а в решении через Autoit если mp<"длины пути до файла" то скрипт работает некорректно

-----
1. P.S.S. а как удалить файл cmd после выполнения?
del "%$f%" перед chcp866 не помогает

2. P.S.S.S.

amel27 · Отправлено: **05:01, 19-06-2010** | #15

Цитата shadowbat:

РЕШЕНИЕ »

область действия CHCP должна быть по возможности минимальной... Во-первых, это избавит скрипт от бессмысленных перекодировок и ускорит его работу... Во-вторых, предохранит от глюков в реализации этих перекодировок - далеко не все CMD команды корректно её проводят (FindStr делает это весьма своеобразно), а в некоторых её просто "забыли" реализовать (REG в локализованной WinXP)

Цитата shadowbat:

как удалить файл cmd после выполнения?
del "%$f%" перед chcp866 не помогает »

помогает, нужно только использовать CALL при вызове батника, иначе это будет последней выполненной командой... если лог работы не нужен, можно запустить MOVE на выполнение без вывода в промежуточный файл:

Цитата shadowbat:

как сделать только путь до файла без добавления имени файла?»

Код:

(for /f "usebackq delims=" %%a in ("2.txt") do @echo %%~dpa)>3.txt

Цитата shadowbat:

а в решении через Autoit если mp<"длины пути до файла" то скрипт работает некорректно »

это решается скурпулезным анализом всех возможных вариантов и четкой формулировкой задачи (грубо говоря, чего заказали то и получили), уже отмечал, что некоторые очевидные ситуации в условии не оговорены, например:
- разные имена файлов могут стать одинаковыми, как должен вести себя скрипт: пропускать файл, перезаписывать последним, выдавать запрос или переименовывать по какому-то правилу?
- имя файла может быть потеряно полностью, каковы действия скрипта: перемещать файл с именем папки или пытаться сохранить хотя бы часть имени файла?... возможны и забавные ситуации типа "C:\DIR1\DIR2\.pdf"

shadowbat · Отправлено: **06:47, 19-06-2010** | #16

значит получается так?:
РЕШЕНИЕ без лога работы:

РЕШЕНИЕ с логом работы:

amel27, Вы профессионал своего дела!

Цитата amel27:

(for /f "usebackq delims=" %%a in ("2.txt") do @echo %%~dpa)>3.txt

создал новую тему по этому вопросу

by.Serj · Отправлено: **18:37, 07-07-2010** | #17

Цитата shadowbat:

set $m=C:\Program Files\*.txt
set $f=2.txt
set mp=50
(for /f "delims=" %%a in ('dir /b/s "%$m%"') do @(
set "b=%%~dpna"&call echo.%%b:~0,%mp%%%%%~xa))>"%$f%" »

Пожалуйста, обЪясните происходящее в цикле, а то уже мозг ломается...

amel27 · Отправлено: **06:04, 08-07-2010** | #18

by.Serj, если речь про две строки в цикле:

Код:

(for /f "delims=" %%a in ('dir /b/s "%$m%"') do @(
   set "b=%%~dpna"
   call echo.%%b:~0,%mp%%%%%~xa
 )
)>"%$f%"

присвоение переменной b пути\имени файла (%%a) без расширения:

Код:

set "b=%%~dpna"

при включенном режиме EnableDelayedExpansion вторая строка имела бы вид:

Код:

echo.!b:~0,%mp%!%%~xa

где "%%~xa" - расширение файла (%%a);
"%mp%" - значение переменной mp
"!b:~0,%mp%!" - %mp% первых символов переменной b

чтобы избежать использования EnableDelayedExpansion используем трикс с CALL: добавляем перед командой CALL и заменяем "!" на "%%" (отложенная подстановка), в результате при (первом) вызове CALL будут подставлены значения %%a и %mp%, при (втором) вызове ECHO - значение b