CMD/BAT - [решено] как удалить 1ю строку и склеить строки 3+4, 6+7, 9+10

amel27 · Отправлено: **13:42, 22-05-2010** | #2

shadowbat, типа такого?

Код:

@Echo Off

Set INI=1.ini
Set DST=all.ini

If Exist "%DST%" DEL /F/Q "%DST%"
For /F "Delims=" %%a In ('DIR /S/B/A-D %INI%') Do (
  For /F "Tokens=1* Delims=:" %%i In ('FindStr /ERNC:"$" "%%a"') Do (
    Call :TestNum %%i&& <Nul Set /P $X="%%j. ">>"%DST%"
    If Defined $F <Nul Set /P $X="%%j">>"%DST%"& Echo.>>"%DST%")
  Echo.>>"%DST%")
Exit

:TestNum
 Set /A $N=%~1-(%~1+1)/3*3+1
 If %~1  EQU 1 Set $F=& Exit /B 2
 If %$N% EQU 2 Set $F=T&Exit /B 1
 If %$N% EQU 1 Set $F=& Exit /B 0
Set $F=& Exit /B 2

shadowbat · Отправлено: **14:01, 22-05-2010** | #3

amel27

совсем не типа такого, а именно так!!

а как добавить, чтобы при создании строк добавлялся порядковый номер, и с каждого нового 1.ini он начинался с 001

amel27 · Отправлено: **14:37, 22-05-2010** | #4

shadowbat, точно, пропустил, тогда попробуй так:

Код:

@Echo Off

Set INI=1.ini
Set DST=all.ini

If Exist "%DST%" DEL /F/Q "%DST%"
For /F "Delims=" %%a In ('DIR /S/B/A-D %INI%') Do (Set $N=1
    For /F "Tokens=1* Delims=:" %%i In ('FindStr /ERNC:"$" "%%a"') Do (
    Call :TestN1 %%i&& <Nul Set /P $X="%%j. ">>"%DST%"
    Call :TestN2 %%i&&(<Nul Set /P $X="%%j">>"%DST%"&Echo.>>"%DST%"))
  Echo.>>"%DST%")
Exit

:TestN1
 Set /A $I=%~1-(%~1+1)/3*3+1
 If %$I% NEQ 1 Exit /B 1
 <Nul Set /P $X="%$N%.">>"%DST%"
Set /A $N+=1& Exit /B 0

:TestN2
 Set /A $I=%~1-(%~1+1)/3*3+1
 If %~1  EQU 1 Exit /B 1
 If %$I% NEQ 2 Exit /B 1
Exit /B 0

shadowbat · Отправлено: **14:46, 22-05-2010** | #5

отлично делает!
как бы теперь поменять с 1, 2, 3 на 001 002 003 или это нереализуемо?

тут видимо через условие либо функцию нужно реализовывать?
или через 3 функции? для номеров 0-9 10-99 100-999

пока что приспособился: BAT + программа Renamer с прибавлением 0 и 00 перед началом нужных файлов

amel27, благодарю!

amel27 · Отправлено: **16:50, 22-05-2010** | #6

Цитата shadowbat:

в итоге 1я строчка создается "001" а вторая "2" а не "002" »

после арифметических операций ведущие нули обрезаются

Цитата shadowbat:

создается 001 002 003 ... 0010 0011 »

почти так, только оставить три последних символа (в процедуре TestN1):

Код:

 Set $S=00%$N%
 <Nul Set /P $X="%$S:~-3%.">>"%DST%"

shadowbat · Отправлено: **16:59, 22-05-2010** | #7

красота! amel27, отличная работа!

итоговое решение:

Код:

@Echo Off

Set INI=1.ini
Set DST=all.ini

If Exist "%DST%" DEL /F/Q "%DST%"
For /F "Delims=" %%a In ('DIR /S/B/A-D %INI%') Do (Set $N=1
    For /F "Tokens=1* Delims=:" %%i In ('FindStr /ERNC:"$" "%%a"') Do (
    Call :TestN1 %%i&& <Nul Set /P $X="%%j. ">>"%DST%"
    Call :TestN2 %%i&&(<Nul Set /P $X="%%j">>"%DST%"&Echo.>>"%DST%"))
  Echo.>>"%DST%")
Exit

:TestN1
 Set /A $I=%~1-(%~1+1)/3*3+1
 If %$I% NEQ 1 Exit /B 1
 Set $S=00%$N%
 <Nul Set /P $X="%$S:~-3%.">>"%DST%"
Set /A $N+=1& Exit /B 0

:TestN2
 Set /A $I=%~1-(%~1+1)/3*3+1
 If %~1  EQU 1 Exit /B 1
 If %$I% NEQ 2 Exit /B 1
Exit /B 0

shadowbat · Отправлено: **21:04, 23-05-2010** | #8

я уже минут 10 подбираю - не могу справиться

как сделать еще одну модификацию батника, чтобы он вставлял порядковый номер между блоками?

т.е. сейчас

Код:

            //all.ini
1
2
3

1
2
3

а как сделать: ?

Код:

1            //all.ini
1
2
3

2
1
2
3

3
1
2
3
...

amel27 · Отправлено: **03:46, 24-05-2010** | #9

shadowbat, не уверен, что правильно понял:

Код:

@Echo Off

Set INI=1.ini
Set DST=all.ini

If Exist "%DST%" DEL /F/Q "%DST%"
For /F "Tokens=1* Delims=[]" %%a In ('DIR /S/B/A-D %INI%^|Find /N /V ""') Do (
    Set $N=1& Echo %%a>>"%DST%"
    For /F "Tokens=1* Delims=:" %%i In ('FindStr /ERNC:"$" "%%b"') Do (
    Call :TestN1 %%i&& <Nul Set /P $X="%%j. ">>"%DST%"
    Call :TestN2 %%i&&(<Nul Set /P $X="%%j">>"%DST%"&Echo.>>"%DST%"))
  Echo.>>"%DST%")
Exit

:TestN1
 Set /A $I=%~1-(%~1+1)/3*3+1
 If %$I% NEQ 1 Exit /B 1
 Set $S=00%$N%
 <Nul Set /P $X="%$S:~-3%.">>"%DST%"
Set /A $N+=1& Exit /B 0

:TestN2
 Set /A $I=%~1-(%~1+1)/3*3+1
 If %~1  EQU 1 Exit /B 1
 If %$I% NEQ 2 Exit /B 1
Exit /B 0

shadowbat · Отправлено: **08:16, 24-05-2010** | #10

amel27, зато я уверен!!

все правильно понял!