[amel27]

Babullika,

нужно при каждом подключении к интернету ( через адсл модэм , высокоскоросное подключение ) , записывать в файлик IP адрес »

ADSL под рукой нет, попробуй пример - в качестве параметра можно ввести часть имени адаптера или его индекс, в процессе работы в консоли SciTE выводится список ВСЕХ подключенных адаптеров, там можно подсмотреть правильные имя и индекс:

Код:

$sAdapter = "Realtek RTL8139"
$sFile = "C:\TEST.TXT"

$sAdapterIP = _NetAdapterGetIP($sAdapter)
FileWriteLine($sFile, $sAdapterIP)

Func _NetAdapterGetIP($Find = "", $sHostName = "localhost")
    Local $objItem, $sRes, $objWMIService = ObjGet( "winmgmts:\\"& $sHostName &"\root\CIMV2")
    Local $sQuery = 'SELECT Index, Caption, IPAddress FROM Win32_NetworkAdapterConfiguration Where IPEnabled = True'
    Local $colItems = $objWMIService.ExecQuery($sQuery, "WQL", 0x30)
    If IsObj($colItems) Then
        For $colItem In $colItems
            If  (IsString($Find) And ($Find == "" Or StringInStr($colItem.Caption, $Find))) Or _
                (IsInt($Find) And ($Find == 0 Or $Find == $colItem.Index)) Then
                ConsoleWrite ("Index  :"& $colItem.Index &@CRLF)
                ConsoleWrite ("Address:"& $colItem.IPAddress(0) &@CRLF)
                ConsoleWrite ("Caption:"& $colItem.Caption &@CRLF&@CRLF)

                $sRes = $colItem.IPAddress(0)
            EndIf
        Next
    EndIf
    Return $sRes
EndFunc  ;==> _NetAdapterGetIP