Имя пользователя:
Пароль:  
Помощь | Регистрация | Забыли пароль?  

Показать сообщение отдельно

Googler


Сообщения: 3665
Благодарности: 1563

Профиль | Отправить PM | Цитировать


Medic84
не так просто, как вариант:
Код: Выделить весь код
@Echo Off
:: -- Ключ, параметр рееста и имя выходного файла
Set $RKEY=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon
Set $PARM=DCacheUpdate
Set $FILE=%~dpn0.reg
:: -- Чтение типа параметра и значения в переменные
For /F "Tokens=2-3 Delims=	" %%i In ('REG QUERY "%$RKEY%" /v "%$PARM%"') Do (
    Set $TYPE=%%i
    Set $RVAL=%%j)
)
:: -- Временные ключ реестра и имя файла
Set $RTMP=HKEY_CURRENT_USER\Software\~TMP
Set $FTMP=%~dpn0.tmp
:: -- Копируем параметр во временную ветку и экспоритуем ее в файл
REG DELETE %$RTMP% /f >Nul 2>&1
REG ADD %$RTMP% /v "%$PARM%" /t %$TYPE% /d "%$RVAL%" >Nul
REG EXPORT "%$RTMP%" "%$FTMP%" >Nul
REG DELETE %$RTMP% /f >Nul

IF EXIST "%$FILE%" DEL /F /Q "%$FILE%"
:: -- Замена в REG-файле имени ключа на нужный
CHCP 1251 >Nul
For /F "Delims=" %%i In ('Type %$FTMP%') Do (
    IF "%%i"=="[%$RTMP%]" ( @Echo.[%$RKEY%] >>"%$FILE%"
    ) ELSE ( @Echo.%%i >>"%$FILE%" )
)
Это сообщение посчитали полезным следующие участники:

Отправлено: 07:27, 19-09-2008 | #353