[YuriPet]

что то я не понял кому нибудь удалось сделать тихую инсталяшку из Kis 7.125? >>>

Сегодня, воспользовавшись наработками BarNet и Alex333, сделал для себя "тихий" дистрибутив Kaspersky Internet Security 7.0.0.125 - всё прекрасно отрабатывает!
Содержание моего setup.cmd (добавлен твик "Установить "флаг" завершения полного сканирования компьютера"):

читать дальше »

Пароль - для примера тот-же, что и у BarNet

Код:

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion

:: Назначаем переменные
Set wdir=%~dp0
Set wdir=%wdir:~0,-1%
Set KISRoot=%programfiles%\Kaspersky Lab\Kaspersky Internet Security 7.0
Set KISData=%AllUsersProfile%\Application Data\Kaspersky Lab\AVP7
Set key=HKEY_LOCAL_MACHINE\SOFTWARE\KasperskyLab\protected\AVP7

:: Копируем актуальные базы
XCopy "%wdir%\Kaspersky Lab\AVP7" "%KISData%\" /E /Q /Y

:: Устанавливаем KIS
Start /Wait kis.ru.msi TRANSFORMS=kis.ru.mst /qn /norestart

:: Вносим изменения в реестр:
:: - установить "флаг" завершения полного сканирования компьютера
Reg Add "%key%\Data" /v "LastSuccessfulFullScan" /t REG_DWORD /d "00000000" /f
:: - установить значение пароля
Reg Add "%key%\settings" /v "OPEP" /d "jAAAAAECAAABaAAAAKQAAAJ1qz2JSrlH+7dP3K8r9okzj5c1idioX0pFEmoqGH2RO4tNGhDO3rR3hTk1foZ0APQJGkkQFHi2LhsoVc8gLhnQ4kCfCXbhsGG76UaD7xXj2XOA1Q1J/FqpqvED3BB9vfaAtIJ2ytth1LJw4qjeNuOpgXXXNf+cR+tfI1WBqhkt4eRjNKKWRZSNni1MphcZBhHnк" /f
:: - включить самозащиту
Reg Add "%key%\settings" /v "EnableSelfProtection" /t REG_DWORD /d "00000001" /f

:: Копируем файл настроек в папку KIS
XCopy "%wdir%\settings.dat" "%KISRoot%\" /Q /Y

:: Переходим в папку KIS
CD %KISRoot%

:: Импортируем настройки
Start /Wait avp.com IMPORT settings.dat /password=aquarium

:: Небольшая "приборка"
If Exist %HOMEDRIVE%\Config.Msi RD /S /Q %HOMEDRIVE%\Config.Msi
Exit