[amel27]

YuriPet

Уж коли заикнулся о расшифровке... Пошарившись по Гуглю, накарябал VBS-скрипт, который ищет в зашифрованном MRU нужный объект... параметр реестра можно скопировать в буфер и найти в Regedit.

Код:

Const HKCU = &H80000001

strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\count"
strFind = InputBox ("Правая часть имени (с расширением) ярлыка, программы или документа:","Поиск объекта в MRU List", "regedit.exe")

Set oReg = GetObject("WinMgmts:\\.\root\default:StdRegProv")
Set oWSS = CreateObject ("WScript.Shell")

boolFind = vbFalse
If Len (strFind) > 0 Then
	oReg.EnumValues HKCU, strKeyPath, arrValueNames, arrValueTypes
	For Each strValueName In arrValueNames
		strPath = StrMod (strValueName)
		strProg = Right (strPath, Len(strFind))
		If StrComp (strProg, strFind, 1) = 0 Then
			boolFind = vbTrue
			strNew = InputBox ("Значение ключа:" & vbCRLF & vbCRLF & strPath,"Поиск объекта в MRU List", strValueName)
		End If
	Next
	If boolFind = vbFalse Then WScript.Echo "Искомый объект не найден!"
End If

Function StrMod (strLine)
	StrMod = ""
	For iChr = 1 To Len (strLine)
		char = Mid (strLine, iChr, 1)
		achr = Asc (char)
		ochr = Asc ("A") * (achr >= (Asc("A")) And (achr <= Asc("Z") )) + Asc("a") * ((achr >= Asc("a")) And (achr <= Asc("z") ))
		If ochr<0 Then
			achr = achr + ochr + 13
			achr = achr - Int(achr/26)*26
			char = Chr(achr - ochr)
		End If
		StrMod = StrMod & char
	Next
End Function