[boss911]

Proektor

"при подключении вывести значок в области уведомлений", отвечающая за отображение значка из двух компьютеров в трее?

Подобного твика нет, так как при переустановки системы, он уже не работает! Там каждый раз формируется разное название ветки в реестре. Где-то тут проскакивал vbs скрипт, который, и ставит эту галочку. Все происходит мгновенно и тихо!

Сохранить с расширением vbs:

Код:

' use "." for local computer 
sComputer = "." 
 
'Constants for WMI StdRegProv 
Const HKCR = &H80000000 
Const HKCU = &H80000001 
Const HKLM = &H80000002 
 
Const NetBase = "SYSTEM\CurrentControlSet\Control\Network\" 
 
On Error Resume Next 
 
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & sComputer & "\root\default:StdRegProv") 
 
' Finding the right place in registry is not so easy 
' You must find the SettingID for the correct network adapter 
 
' Get adapter collection 
Set oAdapters = GetObject("winmgmts:").ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled=True") 
 
' Get all subkeys under NetBase in an array 
iRC = oReg.EnumKey(HKLM, NetBase, aRegKeys) 
 
' Поиск адаптера с именем подключения "Подключение по локальной сети" 
' или с именем "Подключение по локальной сети 2" 
If (Err.Number = 0) And (iRC = 0) Then 
   On Error Goto 0 
   bAdapterFound = False 
   For Each oAdapter In oAdapters 
     sSettingID = oAdapter.SettingID 
     ' Loop through all registry keys 
     For i = 0 To Ubound(aRegKeys) 
       sKeyName = NetBase & aRegKeys(i) & "\" & sSettingID & "\Connection" 
       oReg.GetStringValue HKLM, sKeyName, "Name", sValue 
       If sValue = "Подключение по локальной сети" or sValue = "Подключение по локальной сети 2" Then 
         '' bAdapterFound = True 
         ' WScript.Echo "Updating this setting id: " & sSettingID 
         ' WScript.Echo "Registry path: " & sKeyName 
         ' Now we can get to the network icon setting in registry 
         oReg.SetDWORDValue HKLM, sKeyName, "ShowIcon", 1 
         '' Exit For 
       End If 
     Next 
     If bAdapterFound Then 
       Exit For 
     End If 
   Next 
 
   ' WScript.Echo "Finished, you must log off and on to see the change" 
 
Else 
   WScript.Echo "Error in WMI registry parsing!" 
End If