[megaloman]

Если в папке Data должны остаться перечисленные файлы, в том числе и в подпапках

Код:

@Echo Off
	Set Att=Dawnguard.esm Dragonborn.esm HearthFires.esm "Skyrim - Animations.bsa" "Skyrim - Interface.bsa" "Skyrim - Meshes0.bsa" "Skyrim - Meshes1.bsa" "Skyrim - Misc.bsa" "Skyrim - Patch.bsa" "Skyrim - Shaders.bsa" "Skyrim - Sounds.bsa" "Skyrim - Textures0.bsa" "Skyrim - Textures1.bsa" "Skyrim - Textures2.bsa" "Skyrim - Textures3.bsa" "Skyrim - Textures4.bsa" "Skyrim - Textures5.bsa" "Skyrim - Textures6.bsa" "Skyrim - Textures7.bsa" "Skyrim - Textures8.bsa" Skyrim.esm Update.esm
	Set "Fold=Data"

	FOR %%f IN (%Att%) DO If Exist "%Fold%\%%~f" Attrib +H "%Fold%\%%~f"
	FOR /F "usebackq delims=" %%d IN (`2^>nul Dir "%Fold%\" /S /B /A:D`) DO (
		FOR %%f IN (%Att%) DO If Exist "%%d\%%~f" Attrib +H "%%d\%%~f"
	)

	>nul Del "%Fold%\*.*" /S /Q

	FOR %%f IN (%Att%) DO If Exist "%Fold%\%%~f" Attrib -H "%Fold%\%%~f"
	FOR /F "usebackq delims=" %%d IN (`2^>nul Dir "%Fold%\" /S /B /A:D`) DO (
		FOR %%f IN (%Att%) DO If Exist "%%d\%%~f" Attrib -H "%%d\%%~f"
	)

Если в папке Data должны остаться только перечисленные файлы, а всё остальное, включая подпапки, должно быть убито

Код:

@Echo Off
	Set Att=Dawnguard.esm Dragonborn.esm HearthFires.esm "Skyrim - Animations.bsa" "Skyrim - Interface.bsa" "Skyrim - Meshes0.bsa" "Skyrim - Meshes1.bsa" "Skyrim - Misc.bsa" "Skyrim - Patch.bsa" "Skyrim - Shaders.bsa" "Skyrim - Sounds.bsa" "Skyrim - Textures0.bsa" "Skyrim - Textures1.bsa" "Skyrim - Textures2.bsa" "Skyrim - Textures3.bsa" "Skyrim - Textures4.bsa" "Skyrim - Textures5.bsa" "Skyrim - Textures6.bsa" "Skyrim - Textures7.bsa" "Skyrim - Textures8.bsa" Skyrim.esm Update.esm
	Set "Fold=Data"

	FOR %%f IN (%Att%) DO If Exist "%Fold%\%%~f" Attrib +H "%Fold%\%%~f"
	>nul Del "%Fold%\*.*" /Q
	FOR %%f IN (%Att%) DO If Exist "%Fold%\%%~f" Attrib -H "%Fold%\%%~f"

	FOR /F "usebackq delims=" %%d IN (`2^>nul Dir "%Fold%\" /B /A:D`) DO Rd /S /Q "%Fold%\%%d"