[Sisin]

Up 2018

Никто не нашел решения случаем?

Нашел такие скрипты:

Установить пункт контекстного меню.cmd

Код:

@set @x=0; /*
@echo off
SetLocal EnableExtensions DisableDelayedExpansion
set "live=%USERPROFILE%"

REG ADD "HKCR\AllFilesystemObjects\Shell" /f >nul 2>&1 || if "%~2" neq "Admin" (
  echo Для установки надстройки требуются повышенные права.
  cscript.exe //nologo //e:jscript "%~f0"& Exit /B) else (echo Вы не обладаете необходимыми привилегиями& pause& Exit /B
)

:begin
cls
echo. Введите цифру и нажмите { ENTER }
echo.
echo. Установить:
echo.
echo 1. Поиск в Google
echo 2. Поиск в Yandex
echo.
set /p "ch=Ваш выбор: "

::Первая часть VBS
for /f "delims=[]" %%N in ('find /n ":UnpackVBS" ^<"%~f0"') do set /a num=%%N
more +%num% >"%live%\KozaN.vbs" <"%~f0"

::Вторая часть VBS
if "%ch%"=="1" (
  set VerbName=Найти в "Google"
  >> "%live%\KozaN.vbs" echo CreateObject^("WScript.Shell"^).Run "explorer ""https://google.ru/search?ie=UTF-8&hl=ru&q=" ^& Arg ^& """"
  REG ADD "HKCR\AllFilesystemObjects\Shell\CopyAsPath"  /v Icon  /t REG_SZ /d "%USERPROFILE%\google.ico" /f
  1>nul copy "%~dp0google.ico" "%USERPROFILE%" /y
)

if "%ch%"=="2" (
  set VerbName=Найти в "Яндекс"
  >> "%live%\KozaN.vbs" echo CreateObject^("WScript.Shell"^).Run "explorer ""http://yandex.ru/yandsearch?text=" ^& Arg ^& """"
  REG ADD "HKCR\AllFilesystemObjects\Shell\CopyAsPath"  /v Icon  /t REG_SZ /d "%USERPROFILE%\yandex.ico" /f
  1>nul copy "%~dp0yandex.ico" "%USERPROFILE%" /y
)

if not Defined VerbName goto begin

REG ADD "HKCR\AllFilesystemObjects\Shell\CopyAsPath" /f
REG ADD "HKCR\AllFilesystemObjects\Shell\CopyAsPath"  /ve  /t REG_SZ /d "%VerbName%" /f
REG ADD "HKCR\AllFilesystemObjects\Shell\CopyAsPath\command" /f
REG ADD "HKCR\AllFilesystemObjects\Shell\CopyAsPath\command" /ve /d "wscript.exe //nologo \"%live%\KozaN.vbs\" \"%%1\"" /f

echo.
echo Установка завершена.
echo.
echo "SafeZone.cc"
echo.
pause
Exit /B

*/try {
  var ShellApp = new ActiveXObject('Shell.Application');
  ShellApp.ShellExecute ('cmd.exe', '/c ""' + WScript.ScriptFullName + '" "" "Admin"','','runas',1);
} catch (e) { }/*

:UnpackVBS
  On Error Resume Next
  if WScript.Arguments.Count = 0 then WScript.Quit
  Arg = WScript.Arguments(0)
  Arg = Mid(Arg, InStrRev(Arg, "\") + 1)
  Arg = Replace(Arg, " ", "%20")
  set ShellApp = CreateObject("Shell.Application")'*/

Удаление пункта контексного меню.bat

Код:

@set @x=0; /*
@echo off
SetLocal EnableExtensions DisableDelayedExpansion

echo Удалить пункт котексного меню поиска в Яндекс/Google ?
echo.

:begin

echo 1. Да,удалить (введите цифру 1 и нажмите клавишу Enter)
echo 2. Нет,не удалять (введите цифру 2 и нажмите клавишу Enter)
echo.
set /p "ch=Ваш выбор: "
echo.
echo.

if "%ch%"=="1" (REG DELETE "HKCR\AllFilesystemObjects\Shell\CopyAsPath" /f || if "%~2" neq "Admin" (
  echo Для выполнения операции требуются повышенные права.
  cscript.exe //nologo //e:jscript "%~f0"& Exit /B) else (echo Вы не обладаете необходимыми привилегиями& pause& Exit /B
)

if exist "%USERPROFILE%\google.ico" (del "%USERPROFILE%\google.ico" /q) else del "%USERPROFILE%\yandex.ico" /q 
cls
echo.
echo Удаление завершено.
echo Для выхода нажмите клавишу Enter
echo.
echo "SafeZone.cc"
echo.
pause > nul
Exit /B
)

if "%ch%"=="2" (echo Операция отменена,для выхода нажмите клавишу Enter
pause > nul
exit /b
)

if not Defined VerbName (echo Неверный выбор!
echo.
echo Выберите один из пунктов:
echo.
 goto begin)

*/try {
  var ShellApp = new ActiveXObject('Shell.Application');
  ShellApp.ShellExecute ('cmd.exe', '/c ""' + WScript.ScriptFullName + '" "" "Admin"','','runas',1);
} catch (e) { }/*

:UnpackVBS
  On Error Resume Next
  if WScript.Arguments.Count = 0 then WScript.Quit
  Arg = WScript.Arguments(0)
  Arg = Mid(Arg, InStrRev(Arg, "\") + 1)
  Arg = Replace(Arg, " ", "%20")
  set ShellApp = CreateObject("Shell.Application")'*/

Но они добавляют в контекстное меню только поиск в Яндекс и Google. Может кто сообразит как переделать их под Яндекс.Картинки??