Vlad87, этот пакетный файл создаст Вам другой пакетный файл, просмотрев содержимое которого, Вы сделаете вывод: запускать его или нет.
Код:
@echo off
set "folder=D:\Webcam"
set days=7
set min=15000000
set max=40000000
(
echo @echo off
echo.
echo.
echo :: Удаляем все папки, которые старше %days% дней, вместе с файлами:
(
forfiles /p "%folder%" /d -%days% /c "cmd /c if /i @isdir==true echo rd /q/s @path" 2>nul
)|| echo rem Не найдены.
echo.
echo.
echo :: Удаляем файлы, размер которых меньше %min% байтов:
echo.
(
for /f "tokens=*" %%i in ('
robocopy "%folder%" %random% /nc /ns /ndl /njh /njs /l /e /max:%min%
') do (
echo del "%%i"
)
)|| echo rem Не найдены.
echo.
echo.
echo :: Удаляем файлы, размер которых больше %max% байтов:
echo.
(
for /f "tokens=*" %%i in ('
robocopy "%folder%" %random% /nc /ns /ndl /njh /njs /l /e /lev:2 /min:%max%
') do (
echo del "%%i"
)
)|| echo rem Не найдены.
echo.
echo.
echo :: Удаляем пустые папки:
echo.
(
for /d %%i in ("%folder%\*") do (
(
for /f %%j in ('dir /a/b "%%i"') do pause<nul>nul
)|| echo rd /q/s "%%i"
)
)|| echo rem Не найдены.
echo.
echo.
echo exit
)>"Delete.cmd"
exit /b
.
