Цитата Striker1000:
|
Подскажите пожалуйста что переделать в нем ???? »
|
Переделывать ничего не нужно. Надо писать пакетный файл "с нуля", ориентируясь на свои нужды.
Цитата Striker1000:
|
чтобы на комп скидывались недостающие файлы с ftp »
|
Код:
@echo off& :Команда "echo off" обязательна!
rem Подставить в значения переменных свои данные!
set $#@1_server=open ftp.opera.com
set $#@2_user=anonymous
rem В случае наличия пароля вставить его между кавычек вместо символа процента!
set $#@3_password="%"
set $#@4_ftp_folder=cd "pub/opera/win/1216/int"
set "local_folder=C:\Users\1\AppData\Local\Temp\Work\537"
(for /f "tokens=1* delims==" %%i in ('set $#@') do echo.%%~j)>ftp_cmd.tmp
(for %%i in ("ls . ftp_lst.tmp" close bye) do echo %%~i)>>ftp_cmd.tmp
ftp -s:ftp_cmd.tmp
chcp 1251>nul
dir /a-d /b "%local_folder%">cmp_lst.tmp
chcp 866>nul
findstr /ilvxg:"cmp_lst.tmp" "ftp_lst.tmp">ftp_new.tmp
(for /f "tokens=1* delims==" %%i in ('set $#@') do echo.%%~j)>ftp_cmd.tmp
echo lcd "%local_folder%">>ftp_cmd.tmp
(for %%i in (binary hash) do echo %%i)>>ftp_cmd.tmp
(for /f "usebackq delims=" %%i in ("ftp_new.tmp") do echo get "%%i")>>ftp_cmd.tmp
(for %%i in (close bye) do echo %%i)>>ftp_cmd.tmp
ftp -s:ftp_cmd.tmp
rem Удаление временных файлов "закомментировано": могут пригодиться для "разбора полётов"!
:del cmp_lst.tmp ftp_cmd.tmp ftp_lst.tmp ftp_new.tmp
exit /b
