[Iska]

Могу предложить такой вариант:

читать дальше »

Код:

Option Explicit

Dim strSourceFolder
Dim strDestFolder

Dim objFile
Dim objMagickImage


If WScript.Arguments.Count = 2 Then
	strSourceFolder = WScript.Arguments.Item(0)
	strDestFolder   = WScript.Arguments.Item(1)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FolderExists(strSourceFolder) Then
			If .FolderExists(strDestFolder) Then
				Set objMagickImage = WScript.CreateObject("ImageMagickObject.MagickImage.1")
				
				For Each objFile In .GetFolder(strSourceFolder).Files
					Select Case LCase(.GetExtensionName(objFile.Name))
						Case "jpg", "jpeg", "jpe"
							On Error Resume Next
							objMagickImage.Identify "-format", "Name:[%f] Type:[%m] Dim:[%wx%hx%z]\r\n", objFile.Path
							
							If Err.Number = 0 Then
								On Error Goto 0
								objFile.Move strDestFolder & "\"
							Else
								Err.Clear
								On Error Goto 0
							End If
						Case Else
							' Nothing to do
					End Select
				Next
				
				Set objMagickImage = Nothing
			Else
				WScript.Echo "Destination folder [" & strDestFolder & "] not found."
				WScript.Quit 2
			End If
		Else
			WScript.Echo "Source folder [" & strSourceFolder & "] not found."
			WScript.Quit 2
		End If
	End With
Else
	WScript.Echo "Usage:   cscript.exe //nologo " & WScript.ScriptName & " <Source folder> <Destination folder>"
	WScript.Echo "Example: cscript.exe //nologo " & WScript.ScriptName & " ""E:\Песочница\0335\Source"" ""E:\Песочница\0335\Destination"""
	WScript.Quit 1
End If

WScript.Quit 0

с использованием ImageMagick.