Автоматическая смена заголовка окна сообщений
Занятное решение...
Код:
OutFile "MB_Title.exe"
!include "WinMessages.nsh"
!define InstCaption "Обычный заголовок"
!define MBCaption1 "А сейчас - необычный !"
!define MBCaption2 "Во как !"
Caption "${InstCaption}"
Function .onInit
# If you don't want the blinking caption on the taskbar as well, use .onGUIInit
InitPluginsDir
WriteUninstaller $PLUGINSDIR\MBCaption.exe
MessageBox MB_OK|MB_ICONINFORMATION|MB_TOPMOST "Обычный заголовок"
Exec "$PLUGINSDIR\MBCaption.exe"
MessageBox MB_OK|MB_USERICON|MB_TOPMOST "А сейчас - необычный !"
MessageBox MB_OK|MB_ICONINFORMATION|MB_TOPMOST "Снова обычный заголовок"
Abort
FunctionEnd
Section "Blank"
SectionEnd
Function un.onInit
FindWindow $0 "" "${InstCaption}" "" ""
IsWindow $0 0 -1
CaptionLoop:
SendMessage $0 ${WM_SETTEXT} "0" "STR:${MBCaption1}"
Sleep 800
SendMessage $0 ${WM_SETTEXT} "0" "STR:"
Sleep 400
SendMessage $0 ${WM_SETTEXT} "0" "STR:${MBCaption2}"
Sleep 800
SendMessage $0 ${WM_SETTEXT} "0" "STR:"
Sleep 400
FindWindow $1 "" "${InstCaption}" "" ""
IsWindow $1 0 CaptionLoop
Abort
FunctionEnd
Section "un.Blank"
SectionEnd
При использовании на Win7 надо позаботиться , чтобы не мешал UAC
