[Iska]

csv — это немного другое:

Код:

"D:\folderA\folderK\folderX\file1.ext1","D:\folderA\folderK\folderX\","file1.ext1","file1","ext1"

Пробуйте:

читать дальше »

Код:

Option Explicit

Dim strSourceFile
Dim strDestFile

Dim objFSO
Dim objTS
Dim strLine


strSourceFile = "C:\Песочница\035\List.txt"
strDestFile   = "C:\Песочница\035\Out.txt"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strSourceFile) Then
	Set objTS = objFSO.CreateTextFile(strDestFile, True)
	
	With objFSO.OpenTextFile(strSourceFile)
		Do Until .AtEndOfStream
			strLine = .ReadLine
			
			objTS.WriteLine                              """" & _
				strLine                             & """,""" & _
				objFSO.GetParentFolderName(strLine) & "\"",""" & _
				objFSO.GetFileName(strLine)         & """,""" & _
				objFSO.GetBaseName(strLine)         & """,""" & _
				objFSO.GetExtensionName(strLine)    & """"
		Loop
		
		.Close
	End With
	
	objTS.Close
	
	Set objTS = Nothing
Else
	WScript.Echo "Can't find source file [" & strSourceFile & "]."
End If

Set objFSO = Nothing

WScript.Quit 0

Путь Вам обязательно с завершающим слэшем?