krylovlf, попробуйте WSH:
читать дальше »
Код:
Option Explicit
Dim strSourceFolder
Dim strDestFolder
Dim strComputer
Dim objSWbemLocator
Dim objSWbemServicesEx
Dim objSWbemObjectEx
Dim objSWbemSink
strSourceFolder = "e:\Песочница\0190\Source"
strDestFolder = "e:\Песочница\0190\Destination"
strComputer = "."
Set objSWbemLocator = WScript.CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServicesEx = objSWbemLocator.ConnectServer(strComputer, "root\cimv2")
Set objSWbemSink = WScript.CreateObject("WbemScripting.SWbemSink", "Sink_")
objSWbemServicesEx.ExecNotificationQueryAsync objSWbemSink, _
"SELECT * FROM __InstanceCreationEvent WITHIN 1 WHERE " &_
"TargetInstance ISA 'CIM_DirectoryContainsFile' AND " &_
"TargetInstance.GroupComponent = 'Win32_Directory.Name=""" & Replace(strSourceFolder, "\", "\\\\") & """'"
WScript.Echo "Folder: [" & strSourceFolder & "] (waiting for files...)"
WScript.Echo
Do
WScript.Sleep 100
Loop
objSWbemSink.Cancel
Set objSWbemSink = Nothing
Set objSWbemServicesEx = Nothing
Set objSWbemLocator = Nothing
WScript.Quit 0
'=============================================================================
'=============================================================================
Sub Sink_OnObjectReady(objSWbemObjectEx, objSWbemAsyncContext)
With objSWbemServicesEx.Get(objSWbemObjectEx.TargetInstance.PartComponent)
Select Case LCase(.Extension)
Case "jpg", "jpeg"
WScript.Echo Now() & " | | [" & .Name & "]"
If WScript.CreateObject("WScript.Shell").Run("""%ProgramFiles%\ImageMagick-6.3.4-Q8\convert.exe"" """ & .Name & """ -format pdf """ & strDestFolder & "\" & .FileName & ".pdf""", 0, True) = 0 Then
.Delete
Else
WScript.Echo Now() & " | | Can't convert [" & .Name & "] into pdf"
End If
Case Else
' Nothing to do
End Select
End With
End Sub
Запускать при помощи консольного хоста:
Код:
cscript.exe //nologo "Путь\Скрипт.vbs"
Имейте в виду: существующие одноимённые pdf-файлы в «strDestFolder» будут перезаписываться без запросов.
