[RIKO]

Следующие три функции помогут преобразовать длинные имена файлов в коротки и наоборот. Функция Mince служит для отображения полного имени файла, включая путь.




Function Mince(PathToMince: String; InSpace: Integer): String;


Var
 sl: TStringList;
 sHelp, sFile: String;
 iPos: Integer;

Begin
 sHelp := PathToMince;
 iPos := Pos('\', sHelp);
 If iPos = 0 Then
 Begin
   Result := PathToMince;
 End
 Else
 Begin
   sl := TStringList.Create;
   // Decode string
   While iPos <> 0 Do
   Begin
     sl.Add(Copy(sHelp, 1, (iPos - 1)));
     sHelp := Copy(sHelp, (iPos + 1), Length(sHelp));
     iPos := Pos('\', sHelp);
   End;
   If sHelp <> '' Then
   Begin
     sl.Add(sHelp);
   End;
   // Encode string
   sFile := sl[sl.Count - 1];
   sl.Delete(sl.Count - 1);
   Result := '';
   While (Length(Result + sFile) < InSpace) And (sl.Count <> 0) Do
   Begin
     Result := Result + sl[0] + '\';
     sl.Delete(0);
   End;
   If sl.Count = 0 Then
   Begin
     Result := Result + sFile;
   End
   Else
   Begin
     Result := Result + '..\' + sFile;
   End;
   sl.Free;
 End;
End;

{===================================================}
Function ShortFileName(Const FileName: String): String;
{===================================================}
Var
 aTmp: Array[0..255] Of Char;

Begin
 If Not FileExists(FileName) Then
 Begin
   Result := '';
 End
 Else
 Begin
   If GetShortPathName(PChar (FileName), aTmp, Sizeof (aTmp) - 1) = 0 Then
   Begin
     Result:= FileName;
   End
   Else
   Begin
     Result:= StrPas (aTmp);
   End;
 End;
End;

{==============================================}
Function LongFileName(ShortName: String): String;
{==============================================}
Var
 SR: TSearchRec;

Begin
 Result := '';
 If (pos ('\\', ShortName) + pos ('*', ShortName) +
     pos ('?', ShortName) <> 0) Or Not FileExists(ShortName) Then
 Begin
   { ignore NetBIOS name, joker chars and invalid file names }
   Exit;
 End;
 While FindFirst(ShortName, faAnyFile, SR) = 0 Do
 Begin
   { next part as prefix }
   Result := '\' + SR.Name + Result;
   SysUtils.FindClose(SR);  { the SysUtils, not the WinProcs procedure! }
   { directory up (cut before '\') }
   ShortName := ExtractFileDir (ShortName);
   If length (ShortName) <= 2 Then
   Begin
     Break;  { ShortName contains drive letter followed by ':' }
   End;
 End;
 Result := ExtractFileDrive (ShortName) + Result;
end;




Добавлено:

На будущее
Основные функции и процедуры для работы с файлами

AssignFile - Устанавливает ассоциативную связь между файловой переменной и внешним файлом.
BlockRead - Читает несколько записей из файла в переменную.
BlockWrite - Записывает несколько записей в файл.
CloseFile - Разрывает ассоциативную связь между файловой переменной и файлом.
DeleteFile - Удаляет файл с диска.
DiskFree - Определяет количество свободного места на диске.
DiskSize - Определяет размер указанного диска.
Eof - Определяет, стоит ли указатель в конце файла.
Erase - Удаляет файл, связанный с файловой переменной.
DiskSize - Определяет размер указанного диска.
FileExists - Проверяет, существует ли указанный файл.
FileGetAttr - Возвращает атрибуты указанного файла.
FilePos - Возвращает текущую позицию файлового указателя.
FileSearch - Производит поиск файла в нескольких заданных каталогах.
FileSetAttr - Устанавливает атрибуты файла.
FileSize - Возвращает размер файла в байтах, а для файлов типа Record - количество записей.
FindClose - Высвобождает память, выделенную процедурой FindFirst.
FindFirst - Находит файл с заданным набором атрибутов по заданной маске в указанном каталоге.
FindNext - Производит повторный поиск файла.
IOResult - Возвращает статус ошибки последней выполненной операции ввода/вывода.
Read - Читает данные из файла.
Rename - Переименовывает файл.
RenameFile - Переименовывает файл.
Reset - Открывает существующий файл.
Rewrite - Создает новый файл и открывает его.
Seek - Устанавливает файловый указатель в заданную позицию.
Truncate - Удаляет все записи в файле, находящиеся после текущей позиции.
Write - Записывает данные в файл.





Функции и процедуры для работы с каталогами

ChDir - Устанавливает текущий каталог.
CreateDir - Создает новый каталог.
DirectoryExists - Определяет, существует ли указанный каталог.
ForceDirectories - Создает все недостающие каталоги по заданному пути.
GetCurrentDir - Возвращает полное имя текущего каталога.
GetDir - Возвращает имя текущего каталога на указанном диске.
MkDir - Создает подкаталог.
RemoveDir - Удаляет заданный каталог.
RmDir - Удаляет заданный каталог.
SetCurrentDir - Устанавливает текущий каталог.





Функции и процедуры для работы с именем файла

ChangeFileExt - Возвращает имя файла с новым заданным расширением.
ExcludeTrailingBackslash (Delphi 5 и выше) - удаляет в конце строки (пути к файлу) символ наклонной влево черты '\'.
ExpandFileName - Возвращает полное имя файла, добавляя указанное имя файла к имени текущего каталога.
ExpandUNCFileName - Возвращает полное имя файла на сетевом диске.
ExtractFileDir - звлекает из полного имени файла полное имя каталога, в котором находится файл.
ExtractFileDrive - Извлекает из полного имени файла имя диска.
ExtractFileExt - Возвращает расширение файла.
ExtractFileName - Извлекает имя файла из полного имени файла.
ExtractFilePath - Извлекает из полного имени файла имя диска и каталогов (путь к файлу).
ExtractRelativePath - Преобразовывает полный путь в относительный.
ExtractShortPathName - Конвертирует длинное имя файла в формат DOS.
IncludeTrailingBackslash (Delphi 5 и выше) - Добавляет в конец строки символ наклонной влево черты '\'.
MatchesMask - Проверяет, соответствует ли имя файла заданной маске (фильтру).
MinimizeName (Delphi 4 и выше) - Заменяет часть имени файла многоточием, для того, чтобы уместить его в заданный размер холста. ProcessPath - Извлекает из полного имени файла имя диска, имя каталога и имя файла.