[Iska]

Но у меня почему-то он не совсем работает, выдает только "0:00:00".. Даже не знаю в чем причина.. »

Возможно в версии ОС и в ином именовании столбца (я раньше натыкался как-то на список свойств в разных ОС где-то на форуме KiXtart'а). Перетащите ту же папку на этот скрипт:

читать дальше »

Код:

Option Explicit

Const READYSTATE_COMPLETE = 4


Dim strSourceFolder

Dim objShell
Dim objFolder
Dim objFolderItem

Dim intDuration

Dim objSWbemObjectEx
Dim strContent

If WScript.Arguments.Count = 1 Then
	strSourceFolder = WScript.Arguments.Item(0)
	
	Set objShell  = WScript.CreateObject("Shell.Application")
	Set objFolder = objShell.NameSpace(strSourceFolder)
	
	If Not objFolder Is Nothing Then
		strContent = ""
		
		For Each objSWbemObjectEx In GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2").InstancesOf("Win32_OperatingSystem")
			strContent = strContent & objSWbemObjectEx.Caption & " " & objSWbemObjectEx.Version & vbCrLf & vbCrLf
		Next
		
		For intDuration = 0 To 86
			strContent = strContent & CStr(intDuration) & vbTab & objFolder.GetDetailsOf(, intDuration) & vbCrLf
		Next
		
		With WScript.CreateObject("InternetExplorer.Application")
			.Navigate("about:blank")
			
			Do
				WScript.Sleep 100
			Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
			
			.document.parentWindow.clipboardData.setData "text", strContent
			
			.Quit
		End With
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]"
	End If
	
	Set objFolder = Nothing
	Set objShell  = Nothing
Else
	WScript.Echo "Usage: " & WScript.ScriptName & " <Source folder>" & vbCrLf & _
		"" & vbCrLf & _
		"Or drag one folder into this script"
End If

WScript.Quit 0

Затем выложите полученное содержимое буфера обмена сюда.