[Iska]

PoltavaPGS, если без проверок, то примерно так:

читать дальше »

Код:

Option Explicit

Const ForReading   = 1
Const ForWriting   = 2

Const TristateTrue       = -1


Dim strFIO

Dim strFileName
Dim strContent

Dim strFind
Dim strReplace


strFileName = WScript.Arguments.Item(0)

strFind    = "MENUITEM ""&Поликарпов П.П.|Поликарпов"""
strReplace = ""

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FileExists(strFileName) Then
		strFIO = Trim(InputBox("Введите Ваши фамилию, имя, отчество в виде:" & vbCrLf & vbCrLf & _
			"Иванов И.И.", "Введите фамилию, имя, отчество", ""))
		
		If Len(strFIO) <> 0 Then
			strReplace = "MENUITEM ""&" & strFIO & "|" & Split(strFIO)(0) & """"
			
			With .OpenTextFile(strFileName, ForReading, False, TristateTrue)
				strContent = .ReadAll()
				
				.Close
			End With
			
			With .OpenTextFile(strFileName, ForWriting)
				.Write Replace(strContent, strFind, strReplace)
				
				.Close
			End With
		End If
	Else
		WScript.Echo "Файл [" & strFileName & "] не найден"
	End If
End With

WScript.Quit 0

Файл для обработки указываете аргументом скрипта:

Код:

Script.vbs "c:\Sample folder\GRAPHIC.PMN"

либо непосредственно в коде вместо присвоения аргумента:

Код:

strFileName = "c:\Sample folder\GRAPHIC.PMN"

P.S. Если Вам действительно надо будет регулярно менять, я бы вместо конкретной фамилии «&Поликарпов П.П.|Поликарпов» вставил шаблон-заполнитель, который бы потом искался и заменялся.