[Iska]

Вот вариант скрипта с некоторыми проверками:

читать дальше »

Код:

Option Explicit

' Enum IOMode
Const ForReading   = 1
Const ForWriting   = 2
Const ForAppending = 8


Dim strURL
Dim strFolder
Dim strFile

Dim objFSO
Dim objTS
Dim objFile

Dim objShell
Dim objFolder
Dim objFolderItem


With WScript.Arguments
	If .Count = 3 Then
		strURL    = .Item(0)
		strFolder = .Item(1)
		strFile   = .Item(2)
	Else
		WScript.Echo "Usage: " & WScript.ScriptName & " <Url path> <Folder to scan> <File to output>"
		WScript.Quit 1
	End If
End With


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

strFolder = objFSO.GetAbsolutePathName(strFolder)
strFile   = objFSO.GetAbsolutePathName(strFile)

If objFSO.FolderExists(strFolder) Then
	If objFSO.FolderExists(objFSO.GetParentFolderName(strFile)) Then
		If Right(strURL, 1) <> "/" Then
			strURL = strURL & "/"
		End If
		
		With objFSO.OpenTextFile(strFile, ForWriting, True)
			For Each objFile In objFSO.GetFolder(strFolder).Files
				If objFile.Path <> strFile Then
					.WriteLine strURL & objFile.Name
					.WriteLine objFile.Size
				End If
			Next
			
			.Close
		End With
		
		Set objShell = WScript.CreateObject("Shell.Application")
		Set objFolder = objShell.NameSpace(objFSO.GetParentFolderName(strFile))
		
		If Not objFolder Is Nothing Then
			Set objFolderItem = objFolder.ParseName(objFSO.GetFileName(strFile))
			
			If Not objFolderItem Is Nothing Then
				objFolderItem.InvokeVerb "Edit"
				
				Set objFolderItem = Nothing
			End If
			
			Set objFolder = Nothing
		End If
		
		Set objShell = Nothing
	Else
		WScript.Echo "Can't find path [" & objFSO.GetParentFolderName(strFile) & "] to create file [" & strFile & "]"
	End If
Else
	WScript.Echo "Can't find folder [" & strFolder & "]"
End If

Set objFSO = Nothing

WScript.Quit 0

* проверяется существование путей папки для сканирования и файла со сгенерированным текстом;
* url может задаваться как с конечным слэшем, так и без — слэш будет добавлен в Url автоматически;
* имя самого создаваемого текстового файла не будет помещёно в список.