[HOLY DIVER]

Petya V4sechkin, эту (пункт "Описание" в свойствах Моего компьютера на каждой юзерской машине) задачу решил. Мне же надо "Описание" у компьютера в оснастке Active Directory - Пользователи и Компьютеры:



Есть решение на CMD (спасибо smaharbA ), но малогибкое:

Код:

echo off
setlocal ENABLEDELAYEDEXPANSION
set exclude=proxy;pavel igor,ws013
for %%i in (%exclude%) do (
    set "regexclude=!regexclude! \<%%i\>"
    )
set domain=
set user=
for /f "delims=\ " %%i in ('net view ^| find "\\"') do (
    set comp=%%~i
    ping -n 1 -w 10 !comp! > nul 2>&1 && dsquery server -o rdn | find /v /i "!comp!" > nul && echo !comp! | findstr /i /v /r "%regexclude%" > nul && (
        for /f "tokens=2,3 delims==\" %%d in ('wmic /failfast:on /output:STDOUT /node:"!comp!" ComputerSystem get username /format:value 2^> nul ^| find "="') do (
            set user=%%~e
            set domain=%%~d
            set domain=!domain:~0!
            if /i "%userdomain%"=="!domain!" (
                set user=!user:~0,-1!
                net user "!user!" /domain > nul 2>&1 && (
                    for /f "delims=" %%u in ('dsquery user -samid "!user!" -scope subtree -o dn ^| dsget user -fn -mi -ln -display -L 2^> nul ^| find ": "') do (
                            set name=%%~u
                            set name=set !name:: ==!
                            !name!
                        )
                        set fullname=!fn! !mi! !ln!
                        set fullname=!fullname:"='!
                        set display=!display:"='!
                        dsquery computer domainroot -name "!comp!" -scope subtree -o dn | dsmod computer -desc "!fullname! (!display!)" 2> nul && echo !comp! - !fullname! (!display!^)
                    )
                )
            )
        )
    )