[madmasles]

TERMINAL,
Через FTP примерно так можно попробовать:

Код:

#include <FTPEx.au3>

Global $iTimer, $iPause = 2 ;(часа) пауза между проверками
Global $sFile = 'Полный путь к загружаемому файлу'
Global $iHour = 15 ;время, когда будем загружать
Global $iCheck

$iTimer = TimerInit()
While 1
    If TimerDiff($iTimer) >= (1000 * 60 * 60 * $iPause) Then
        If @HOUR >= $iHour Then
            For $i = 1 To 5
                $iCheck = _My_FTP($sFile)
                If $iCheck Then ExitLoop
            Next
            If $iCheck Then Exit
        EndIf
        $iTimer = TimerInit()
    EndIf
    Sleep(500)
WEnd


Func _My_FTP($sPathFile)
    Local $sServer = 'ftp-сервер'
    Local $sUsername = 'Логин'
    Local $sPass = 'пароль'
    Local $sRemote = '/Папка в которую загружаем/'
    Local $hOpen, $hConn, $iPut, $aFile, $sFile
    If Not Ping($sServer) Then Return 0
    $aFile = StringSplit($sPathFile, '\')
    If Not IsArray($aFile) Then Return 0
    $sFile = $aFile[$aFile[0]]
    If Not $sFile Then Return 0
    $hOpen = _FTP_Open('MyFTP')
    If $hOpen = 0 Then Return 0
    $hConn = _FTP_Connect($hOpen, $sServer, $sUsername, $sPass, 1)
    If $hConn = 0 Then
        _FTP_Close($hOpen)
        Return 0
    EndIf
    For $i = 1 To 3
        $iPut = _FTP_ProgressUpload($hConn, $sPathFile, $sRemote & $sFile); с прогрессбаром
        ;$iPut = _FTP_FilePut($hConn, $sPathFile, $sRemote & $sFile); без прогрессбара
        If $iPut <> 0 Then ExitLoop
    Next
    If $iPut = 0 Then
        _FTP_Close($hOpen)
        Return 0
    EndIf
    _FTP_Close($hOpen)
    Return 1
EndFunc   ;==>_My_FTP