[Serega]

(в идеале разбить бы как то секцию [Tasks] на 2 странички: одна(с вариантами установки) до странички выбора компонентов, вторая - после.) »

Пример

Код:

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Languages]
Name: rus; MessagesFile: compiler:Languages\Russian.isl

[Types]
Name: full; Description: Полная установка
Name: custom; Description: Выборочная установка; Flags: iscustom

[Components]
Name: a; Description: Моя программа™; Types: full custom
Name: a\a; Description: Руководство пользователя; Types: full
Name: a\a\a; Description: Русский; Flags: exclusive
Name: a\a\b; Description: English; Flags: exclusive
Name: a\b; Description: Справка; Types: full

[Tasks]
Name: main; Description: Я точно зарегистрированный пользователь :); GroupDescription: Вы точно зарегистрированный пользователь?; Flags: unchecked

[Files]
Source: compiler:Examples\MyProg.exe; DestDir: {app}; Components: a
Source: compiler:Examples\Readme-ru.txt; DestDir: {app}; Components: a\a\a
Source: compiler:Examples\Readme-en.txt; DestDir: {app}; Components: a\a\b
Source: compiler:Examples\MyProg.chm; DestDir: {app}; Components: a\b

[Code]
var
  Page: TInputOptionWizardPage;
  IsRegisteredUser: Boolean;

procedure InitializeWizard();
begin
  // Создание страницы
  Page:= CreateInputOptionPage(wpSelectDir, 'Лицензионное соглашение',
         'Вы зарегистрированный пользователь?',
         'Если вы зарегистрированы, поставьте флажок ниже и нажмите Далее.',False, False);
  // Добавление значений
  Page.Add('Я зарегистрированный пользователь');
  // Задание первоначальных значений (не обязательно)
  Page.Values[0]:= False;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID > Page.ID then
  // Передача значений переменным
  IsRegisteredUser:= Page.Values[0];
end;