[Amigos]

вот набросок скрипта для копирования дистрибутива, просьба потестить
1 копирует ли дистрибутив у вас?
2 после копирования и вынимания дистрибутива система защиты переключается на копию, не просит вставить диск с дистрибутивом при изменении системных файлов?

Код:

@Echo off

REM задание места КУДА копировать дистрибутив
Set copyPlace=%SystemRoot%\OEM

Echo.
Echo Проверка, не был ли скопирован дистрибутив ранее.
if exist %copyPlace%\i386 (
	Echo.
	Echo Дистрибутив Windows уже скопирован в %copyPlace% 
	Echo.
	pause
	goto :EOF
)
Echo.
Echo Дистрибутив ранее не копировался

Echo.
Echo Поиск места, откуда была установлена Windows

REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "SourcePath" >nul
if %ERRORLEVEL% NEQ 0 (
	Echo.
	Echo Windows не помнит, откуда её устанавливали 
	Echo.
	pause
	goto :EOF
)
FOR /F "TOKENS=3" %%I IN ('REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "SourcePath" ^| FINDSTR "SourcePath"') DO SET InstallPath=%%I

Echo.
echo Windows устанавливалась из %InstallPath%
Echo.

set INSTALLCD=%InstallPath:\I386=%
echo Дистрибутив будет копироватся из %INSTALLCD% в в %copyPlace%
Echo.

echo Проверка наличия дистрибутива в %INSTALLCD%
Echo.
if exist %InstallPath%\TXTSETUP.SIF (
	Echo Дистрибутив Windows найден в %INSTALLCD% 
) else (
	Echo Дистрибутив Windows НЕ найден в %INSTALLCD% ,  
	Echo пожалуйста вставте диск с дистрибутивом в этот привод 
	Echo и запустите копирование заново
	Echo.
	pause
	goto :EOF
)
Echo.
echo Подготовка к копированию дистрибутива

if exist %copyPlace% RD %copyPlace%
md %copyPlace%\I386\SVCPACK

copy /y %INSTALLCD%\*. %copyPlace% >copyDistr.log

Echo.
echo Копирование ASMS
Echo.
xcopy %InstallPath%\ASMS %copyPlace%\I386\ASMS /y /s /i >>copyDistr.log

echo Копирование SVCPack
Echo.
copy /y %InstallPath%\SVCPACK\*.ca_ %copyPlace%\I386\SVCPACK >>copyDistr.log

echo Основное копирование .... Пожалуйста подождите несколько минут,
echo это окошко закроется автоматически
Echo.
copy /y %InstallPath%\*.* %copyPlace%\I386 >>copyDistr.log

reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /f /v "SourcePath" /t REG_SZ /d "%copyPlace%\I386"
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup" /f /v "ServicePackSourcePath" /t REG_SZ /d %copyPlace%\
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup" /f /v "SourcePath" /t REG_SZ /d %copyPlace%\

скрипт ведет лог копирования в текущем каталоге, поэтому запуск его с ReadOnly носителей выдаст ошибку.
по умолчанию копирование ведётся в c:\WINDOWS\OEM ,
копируются
\I386\ASMS\*.*
\I386\SVCPACK\*.ca_
\I386\*.*