[amel27]

пробовал сделать так »

должно быть примерно так:

Код:

$ExtraPuTTY = EnvGet("ExtraPuTTY") ; путь к программе
$thConn = DllStructCreate("ulong") ; структура описателя соединения
If $ExtraPuTTY=="" Then MsgBox(16, "Script Error!", "Переменная окружения ExtraPuTTY н задана!")
; Открываем DLL
$hDll = DllOpen($ExtraPuTTY &"\ExtraPuTTY.dll")
If $hDll=-1 Then MsgBox(16, "Script Error!", "Файл ExtraPuTTY.DLL не найден!")
; Подключаемся...
$aRet = DllCall($hDll, "int", "Connexion", _
    "str", "94.100.177.6", _           ; TargetName (TargetName or PuttySession Name )
    "ptr", DllStructGetPtr($thConn), _ ; ConnexionId (Connexion Handle)
    "str", "", _                       ; Login
    "str", "", _                       ; Password
    "int", 0, _                        ; ShowPuTTY (TRUE: Putty Terminal is display, FALSE: not display)
    "int", 0, _                        ; Protocol (0:Telnet,1:SSH,2:Rlogin,3:Raw,4:LoadPutty Session)
    "int", 110, _                      ; PortNumber (If the parameter is set to 0, the value of the default settings of putty is used)
    "int", 0, _                        ; GenerateReport (1:extraputty report activate,0:Not activate)
    "ptr", 0 )                         ; CallBackRcvData
; Анализируем результат
If @error Then MsgBox(16, "DllCall Error!", @error &":"& @extended)
$hConn = DllStructGetData($thConn, 1) ; Получаем описатель соединения
ConsoleWrite("Результат выполнения ф-ции Connexion = "& $aRet[0] &@CRLF)
; Закрываем соединение
If $hConn <> 0 Then
    DllCall($hDll, "int", "CloseConnexion", "ulong", $hConn)
EndIf

Не понял зачем нужно "GenerateReport" и "CallBackRcvData"... »

это опциональные параметры... судя по имени, GenerateReport должен генерить отчет о сеансе, CallBackRcvData - определяет CallBack-функцию, которая будет перехватывать все промежуточные данные еще до завершения команды (обычно используется для всяких индикаторов состояния/прогрессбаров)

P.S. Для POP3 не нужно передавать Login/Password при установке соединения - для этого есть отдельные команды (USER/PASS), передаваемые уже в самом сеансе.