[Peredreifus]

Вопрос: Peredreifus, Как вместо названия поставить дату в формате YYYY_MM_DD »

Код:

Set WShell = CreateObject("WScript.Shell")
' Если скрипт запущен с параметром, то..
If WScript.Arguments.Count>0 Then
	Randomize Timer
	' Запрашиваем имя папки. В качестве стандартного имени будет дата в формате YYYY_MM_DD
	' Проверяем, если число месяца или дня состоит из одного разряда, то добавляем перед ним ноль, иначе оставляем как есть
	If Len(Month(Now))<2 Then tempMonth="0"&Month(Now) Else tempMonth=Month(Now)
	If Len(Day(Now))<2 Then tempDay="0"&Day(Now) Else tempDay=Day(Now)
	Name=InputBox("Имя папки:", "Создать папку", Year(Now)&"_"&tempMonth&" "&tempDay)
	' Если пользователь нажал кнопку Отмена, то выходим из скрипта
	If Name="" Then WScript.Quit
	' Создаем папку с указанным именем
	WShell.run "cmd /C md """&Name&"""", 0
Else
' Если скрипт запущен без параметров, то..
	' Если запись в реестре есть, то удаляем наш раздел
	If WShell.Run("cmd.exe /C REG QUERY ""HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\Создать папку""", 0, True)=0 Then
		WShell.Run "cmd /C REG DELETE ""HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\Создать папку"" /f", 0
	Else
		' Иначе добавляем запись в реестр
		' Иконка папки
		WShell.RegWrite "HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\Создать папку\Icon", "%SystemRoot%\System32\shell32.dll,3", "REG_SZ"
		' Ставим наш пункт в самый верх контекстного меню
		WShell.RegWrite "HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\Создать папку\Position", "Top", "REG_SZ"
		' Прописываем действия, которые будут выполняться при клике по нашему пункту меню
		WShell.RegWrite "HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\Создать папку\command\", "wscript.exe """&WScript.ScriptFullName&""" -folder", "REG_SZ"
	End If
End if