[статья] Интеграция драйверов

CtrlSoft · Конфигурация компьютера

Создал командный файл который автоматизирует процесс установки драйверов в образ:

Код:

:: Drivers Automated Integration Script  v.09.02.22 (C) CtrlSoft 2009
@echo off
color 2e
::------------------------------------------------------------------------------------------------------------
:: Установка переменной %dvd%
SET dvd=\VistaWork\DVD

:: Установка переменной %mount%
SET mount=\VistaWork\Mount

:: Установка переменной %install.wim%
SET install.wim=\VistaWork\DVD\sources\install.wim

:: Установка переменной %peimg%
SET peimg="%ProgramFiles%\Windows AIK\Tools\PETools\peimg.exe"

:: Установка переменной %imagex%
SET imagex="%ProgramFiles%\Windows AIK\Tools\%processor_architecture%\imagex.exe"
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal enabledelayedexpansion
::------------------------------------------------------------------------------------------------------------
:: Определение архитектуры дистрибутива
IF EXIST %dvd%\bootmgr.efi GOTO :x64
IF NOT EXIST %dvd%\bootmgr.efi GOTO :x86
::------------------------------------------------------------------------------------------------------------
:x64
Call :mount
for /f %%F in ('dir \VistaWork\Drivers\x64\*.inf /b /s') do Call :Integrate "%%F"
goto :commit
::------------------------------------------------------------------------------------------------------------
:x86
Call :mount
for /f %%F in ('dir \VistaWork\Drivers\x86\*.inf /b /s') do Call :Integrate "%%F"
goto :commit
::------------------------------------------------------------------------------------------------------------
:Integrate
TITLE Интеграция драйверов c помощью PEImg - Интеграция драйверов
cls
echo.
%peimg% /inf=%1 %mount%\windows
GoTo :EOF
::------------------------------------------------------------------------------------------------------------
:commit
TITLE Интеграция драйверов c помощью PEImg - Применение изменений
CLS
%imagex% /unmount /commit %mount%
GOTO :compress
::------------------------------------------------------------------------------------------------------------
:compress
TITLE Интеграция драйверов c помощью PEImg - Сжатье образа
echo.
SET /P Choice=Хотите сжать образ? (это может занять длительное время) (y=да, n=нет): 
IF "%Choice%"=="y" GOTO :export
IF "%Choice%"=="n" GOTO :Exit
::------------------------------------------------------------------------------------------------------------
:export
mkdir \VistaWork\Temp
SET tmpwim=\VistaWork\Temp\install.wim
CLS
%imagex% /export /compress maximum %install.wim% 1 %tmpwim%
move /y %tmpwim% %install.wim%
GOTO :Exit
::------------------------------------------------------------------------------------------------------------
:Exit
echo.
pause
exit
::------------------------------------------------------------------------------------------------------------
:error
color 0c
cls
echo.
echo Ошибка! Образ не найден.
echo.
pause
exit
::------------------------------------------------------------------------------------------------------------
:mount
cls
TITLE Интеграция драйверов c помощью PEImg - Монтирование образа install.wim
IF EXIST %install.wim% %imagex% /mountrw %install.wim% 1 %mount%
IF NOT EXIST %install.wim% GOTO :error
::------------------------------------------------------------------------------------------------------------

В первую очередь спасибо Boa Soft за его пример установки через PEImg, без него я бы (скорее всего) не справился.

...Итак, что же делает cmd-шник? - Создает переменные для папок и нужных утилит, автоматически определяет архитектуру дистрибутива
а также драйверы которые следует интегрировать, монтирует образ install.wim (индекс 1) и интегрирует драйвера.
После окончании сохраняет изменения и предлагает сжать образ (индекс 1).

Требования:
Для того чтобы скрипт заработал, нужно его запустить!

А точнее, должны существовать стандартные папки + папка Drivers в корень VistaWork.
В папке Drivers создайте папки x86 и x64 а в них скопируйте папки с драйверами. Внимание! Поддерживаются только одноуровние папки!
(Я заметил что если создать подпапки, например .\x86\VGA\nVidia, то драйверы не интегрируются. Точнее интегрируются но в содержании
INF-файлов не присутствуют данные драйвера а иероглифы (больше всего китайских

) и разные крякозабы)
Пример создания директорий

Также нужен текстовой редактор который умеет сохранять текст в кодировке 866 (AkelPad, Bred...),
скопированый дистрибутив ОС в \VistaWork\DVD и пара нажатий кнопок.

Мнение автора:
Я подумал, зачем каждый раз открывать WSIM чтобы добавить тот или иной драйвер, плюс к этому ждать (иногда) пока создастся файл каталога
(недостаток еще в том что в 64-разрядной ОС нельзя создать каталог для 32-разрядной версии), потом писать в командной строке
нужные команды для выполнения и так далее... надо как-то автоматизировать данный процесс и вспомнил про сообщение Boa Soft, то что нужно обрадовался я...

P.S. Ваши примечания по поводу скрипта приветствуются.