Получить из файла значение только пятой строки.

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

Получить из файла значение только пятой строки.

Всем доброго времени суток!

Помогите с задачкой одной. Необходимо с помощью батника получить значение пятой строки в файле. И вывести его на экран.

Как это можно сделать?
заранее спасибо!

Код:

powershell -command "(gc D:\temp\filelist.txt)[4]"

О, а вот так будет работать быстрее:

Код:

powershell -command "gc D:\temp\filelist.txt -first 5 |select -last 1"

C powershell вариант мне известен... спасибо! но вот хотелось бы такое же но с помощью батника.

Это код для батника.

Код:

@Echo Off

cls

        Set "FileIn=Z:\Box_In\Fi Le.txt"

        Set /A N=5



        Set /A N-=1

        For /F "usebackq delims=" %%f In (`2^>nul More +%N% "%FileIn%"`) Do Set "NStr=%%f" &GoTo :Continue

        :Continue

        Echo "%NStr%"

pause

Exit /B 0

И skip же ещё (если первые строки не пустые).

Цитата:

Цитата Iska

И skip же ещё (если первые строки не пустые). »

Iska, more /? :) Скип никак не нужен. Неприятность - если выводимая строка пустая. А скип при пустых строках не спасает.
А вот вариант, переменная при искомой пустой строке будет правильная, фантазия привела к наиболее оптимальному варианту

Код:

@Echo Off

cls

        Set "FileIn=Z:\Box_In\Fi Le.txt"

        Set /A N=5 



        For /F "usebackq tokens=1* delims=:" %%i In (`2^>nul FINDSTR /R /C:".*" /N "%FileIn%"`) Do If "%%i"=="%N%" Set "NStr=%%j"

        Echo "%NStr%"

pause

Exit /B 0

Или, вот еще одно циничное извращение

Код:

@Echo Off

cls

        Set "FileIn=Z:\Box_In\Fi Le.txt"



        For /F "usebackq tokens=1* delims=:" %%i In (`2^>nul FINDSTR /R /C:".*" /N "%FileIn%"`) Do Call Set "NStr%%i=%%j"

        Echo "%NStr5%"

pause

Exit /B 0

Получай строку какую хочется

подкину и я:
1.

Код:

@echo off

<"file.txt" (more +4|set /p x=^& call echo %%x%%)

pause

Код:

@echo off

<"file.txt" (for /f "tokens=2 delims=[]" %%a in ('find /n /v ""^|find "[5]"') do @echo:%%a)

pause

Цитата:

Цитата megaloman

Iska, more /? »

Не, ну, more Вы уже сделали же :).