| mcintosh55 |
23-04-2017 14:34 2731674 |
очистка windows
Привет всем! Есть команда появляется окно отмечаешь галочками, что надо чистить в дальнейшем. Подскажите как можно автоматизировать процесс, что через скрипт выбиралась, что надо чистить. |
| mcintosh55 |
23-04-2017 15:43 2731704 |
Цитата:
Цитата megaloman
Очистка диска в Windows 10, 8.1 и 7: расширенная настройка и запуск по расписанию »
|
Я читал этот мануал, Я вопрос задал как автоматически выбрать пункты, а не вручную галочки ставит. |
mcintosh55,
Цитата:
Цитата В мануале написано
n - любое целое число в диапазоне от 0 до 9999 включительно. Это число - номер конфигурации (соответственно, можно создать 10000 различных конфигураций), его необходимо запомнить для дальнейшего запуска.
|
по любому, конфигурацию настроек придётся как-то задавать, что птичками, что каким-то образом в, например, батнике для изменения реестра. Неужели 10000 возможных запомненных конфигураций не решают проблемы? В чём автоматизация? В чём ускользающий от меня смысл?
|
| mcintosh55 |
23-04-2017 17:00 2731737 |
на ms сайте нашел похожую тему, там пришли к выводу что ни как, ручками ставим галки => запоминаем в реестре => а потом запускаем
|
Цитата:
Цитата mcintosh55
там пришли к выводу что ни как, ручками ставим галки »
|
Да ну? :)
Код:
rem Задаём утилите Cleanmg выполнить контрольное удаление содержимого всех корзин, папок Temp, устаревших обновлений в winsxs
Set rst=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches
REG Add "%rst%\Recycle Bin" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Add "%rst%\Temporary Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Update Cleanup" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Delete "%rst%\Compress old files" /f 2>nul
Cleanmgr /sagerun:1
|
Для Себя делал такой сценарий
Код:
@echo off
Setlocal EnableDelayedExpansion
echo.Startup cleanmgr with full settings without "Recycle Bin"
for /f "usebackq delims=" %%i in (`reg.exe query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches" ^| find.exe /v /i "Recycle Bin"`) do reg add "%%i" /v StateFlags0001 /t REG_DWORD /f /d 2
cleanmgr /sagerun:1
)
|
| mcintosh55 |
23-04-2017 18:32 2731773 |
сделал полный набор удалить строки по надобности, спасибо большое sov4 за пример
Код:
echo off
rem cleanmgr
Set rst=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches
REG Add "%rst%\Recycle Bin" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Add "%rst%\Temporary Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Update Cleanup" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Active Setup Temp Folders" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\BranchCache" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\D3D Shader Cache" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Downloaded Program Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Internet Cache Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Old ChkDsk Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Previous Installations" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Recycle Bin" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\RetailDemo Offline Content" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Service Pack Cleanup" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Setup Log Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\System error memory dump files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\System error minidump files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Temporary Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Temporary Setup Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Thumbnail Cache" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Upgrade Discarded Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\User file versions" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Windows Defender" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Windows Error Reporting Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Windows ESD installation files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Windows Upgrade Log Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Delete "%rst%\Compress old files" /f 2>nul
cleanmgr /sagerun:1
|
кому надо - в профиль :)
Код:
echo off
for %%a in (^
"Recycle Bin"^
"Temporary Files"^
"Update Cleanup"^
"Active Setup Temp Folders"^
"BranchCache"^
"D3D Shader Cache"^
"Downloaded Program Files"^
"Internet Cache Files"^
"Old ChkDsk Files"^
"Previous Installations"^
"Recycle Bin"^
"RetailDemo Offline Content"^
"Service Pack Cleanup"^
"Setup Log Files"^
"System error memory dump files"^
"Temporary Files"^
"Temporary Setup Files"^
"Thumbnail Cache"^
"Upgrade Discarded Files"^
"User file versions"^
"Windows Defender"^
"Windows Error Reporting Files"^
"Windows ESD installation files"^
"Windows Upgrade Log Files"
) do (
REG Add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\%%~a" /v StateFlags0001 /t REG_DWORD /d 2 /f >nul 2>&1
REG Delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Compress old files" /f >nul 2>&1
)
cleanmgr /sagerun:1
pause
|
Время: 09:33.
© OSzone.net 2001-
