[решено] Помогите разобраться с циклом - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - [решено] Помогите разобраться с циклом (http://forum.oszone.net/showthread.php?t=316577)

Помогите разобраться с циклом

Ребят подскажите. Есть такая задача:

Есть набор компьютеров от 1 до 200. Каждому компьютеру надо присвоить некий номер, назовём его условно id в диапазоне от 5 до 7 в таком порядке

Код:

Если компьютер 1 то id присвоить 5

Если компьютер 2 то id присвоить 6

Если компьютер 3 то id присвоить 7

Если компьютер 4 то id присвоить 5

Если компьютер 5 то id присвоить 6

Если компьютер 6 то id присвоить 7

ну и так далее.

Знаю что такое можно сделать через цикл, подскажите пример как это можно сделать.

Каков принцип присвоения id (каким условиям должен отвечать компьютер для присвоения конкретного id)? Куда этот id должен записываться?

Опишу проще. Как сделать следующею картину?

Код:

Если a=1 тогда переменной b присвоить 5

Если a=2 тогда переменной b присвоить 6

Если a=3 тогда переменной b присвоить 7



Если a=4 тогда переменной b присвоить 5

Если a=5 тогда переменной b присвоить 6

Если a=6 тогда переменной b присвоить 7



Если a=7 тогда переменной b присвоить 5

Если a=8 тогда переменной b присвоить 6

Если a=9 тогда переменной b присвоить 7



Если a=10 тогда переменной b присвоить 5

ну и так далее. То есть переменная a будет идти с 1 и до 100, с шагом 1. А переменная b будет присваиваться от 5 до 7.

Код:

@Echo Off

cls

SetLocal EnableExtensions EnableDelayedExpansion



FOR /L %%a IN (1,1,200) DO Set /A b=%%a+4-((%%a-1)/3)*3 & Echo %%a !b!



pause

Либо

Код:

@Echo Off

cls



FOR /L %%a IN (1,1,200) DO Call :A_to_B %%a



pause

GoTo :Eof



:A_to_B

      Set /A a=%1

      Set /A b=%a%+4-((%a%-1)/3)*3

      Echo %a% %b%

GoTo :Eof

Megaloman большое спасибо что ответили. Почти так, только первую переменную "а" надо проверять. К примеру я чуть выше в переменную "а" запишу некое значение, например set a=8. И по этому значению и надо присвоить значение переменной "b". То есть если взять пример

Код:

Если a=1 тогда переменной b присвоить 5 

Если a=2 тогда переменной b присвоить 6 

Если a=3 тогда переменной b присвоить 7  

Если a=4 тогда переменной b присвоить 5 

Если a=5 тогда переменной b присвоить 6 

Если a=6 тогда переменной b присвоить 7  

Если a=7 тогда переменной b присвоить 5 

Если a=8 тогда переменной b присвоить 6 

Если a=9 тогда переменной b присвоить 7  

Если a=10 тогда переменной b присвоить 5

тогда если переменная "а" = 8, то тогда надо переменной "b" надо присвоить 6.

Цитата:

К примеру я чуть выше в переменную "а" запишу некое значение, например set a=8. И по этому значению и надо присвоить значение переменной "b"

А причём тут цикл? Или зачем что-то проверять? Переменная b согласно предложенной мной формуле, однозначно соответствует а.

Код:

@Echo Off

cls



Set /A a=8

Set /A b=%a%+4-((%a%-1)/3)*3



Echo %a%  %b%

pause

Зачем программировать то, что решается аналитически? Я придумал для Вас формулу, т е решил задачу в аналитическом виде. Зачем накручивать циклы или ифы?
Или я что-то не догоняю в постановке задачи? :o
Кстати, для числовых данных я Вам настоятельно советую писать не, например set a=8, а например set /A a=8
Это избавит Вас от возможных ошибок типа определения переменной с концевыми пробелами, если они случайно присутствуют.

Если не нужно, но очень хочется, вот и цикл с условиями

Код:

@Echo Off

cls



Set /A a=8



SetLocal EnableExtensions EnableDelayedExpansion

Set /A b=4

FOR /L %%i IN (1,1,%a%) DO (

        Set /A b+=1

        If !b! EQU 8 Set /A b=5

        If %%i EQU %a% GoTo :Continue

)

:Continue



Echo %a%  %b%

pause

По ip адресу я получаю переменную comp. А дальше мне в конфиг надо прописывать нужный мне параметр. Но проблема в том, что компьютеров десятки и десятки, а параметров всего 20. Поэтому я решил эту проблему так:

Код:

if "%comp%"=="1" (

set a=70

                )

if "%comp%"=="2" (

set a=71

                )

if "%comp%"=="3" (

set a=72

                )

if "%comp%"=="4" (

  set a=73





                )

if "%comp%"=="5" (

set a=70

                )

if "%comp%"=="6" (

set a=71

                )

if "%comp%"=="7" (

set a=72

                )

if "%comp%"=="8" (

  set a=73

                )

ну и так далее.

Это работает, но у меня уже больше 100 записей. Такой длинный код. А если понадобится ещё 30 компьютеров прописать - это же 30 записей делать. Вот я и подумал про цикл. Или можно как то иначе сделать?

Ей богу, обидно, так старался в предыдущем решении, но Вы не осознали его рациональное зерно: надо лениться такие задачи решать в лоб, надо почухать потылицу и написать формулу: Вы получаете переменную %comp% которая однозначно пересчитывается в %a%, и не надо никаких циклов (если хочется цикл, флаг в руки, можно написать, слегка изменив предыдущий код) и никаких проверок значений. Отличие от предыдущего в том, что в первом случае у Вас было 3 значения, а здесь Вы потребовали 4 (то есть изменили постановку задачи)

Код:

@Echo Off

cls



Set /A comp=7

Set /A a=%comp%+69-((%comp%-1)/4)*4



Echo %comp% %a%



pause

Проверьте для любого %comp% от 1 до бесконечности.
То есть вместо бесконечного числа строк кода напишИте 1

Цитата:

Цитата Вы писали

а параметров всего 20

О чём речь? Надо %comp% пересчитать не в 3 или 4 значения, как Вы писали, а в 20? В каком порядке?

Гораздо интереснее задача: если comp сопоставляется с %a% нерегулярным образом в соответствии с заданным порядком.

Код:

@Echo Off

cls



rem      1  2  3  4  5  6  7  8  9  10 11 12 13  14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150"  

Set mas="25 26 38 76 99 54 77 12 45 2  65 88 123 22 46 65 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 238 139 140 141 142 143 144 145 146 147 148 149 150" 



SetLocal EnableExtensions EnableDelayedExpansion



Set /A comp=138

Call :Define %mas% %comp% "a"

Echo %comp% %a%



Set /A comp=6

Call :Define %mas% %comp% "a"

Echo %comp% %a%



Set /A comp=13

Call :Define %mas% %comp% "a"

Echo %comp% %a%



Set /A comp=5

Call :Define %mas% %comp% "a"

Echo %comp% %a%



pause

GoTo :Eof



:Define

        Set /A i=0

        FOR %%a IN (%~1) DO Set /A i+=1 & If %2 EQU !i! (set /A %~3=%%a & GoTo :Eof)

GoTo :Eof

Andrei_IW, Извините за оффтоп, решил Вашу задачу в общем виде:

Пусть %comp% принимает значения от 1 до любого числа с шагом 1
Пусть %а% может принимать значения от %N1% до %N2% c шагом 1

Последовательность чисел %a% укладывается циклически в последовательность %comp%
Тогда формула для пересчета (сразу написал в виде кода) имеет вид (для примера взял данные из Вашего последнего поста):

Код:

@Echo Off

cls



Set /A N1=70

Set /A N2=73



Set /A comp=138



Set /A a=%comp%+%N1%-1-((%comp%-1)/(%N2%-%N1%+1))*(%N2%-%N1%+1)



Echo %comp%  %a%

pause

Задавайте нужные Вам N1 и N2, и для любого %comp% получИте нужное Вам %a% без циклов и условий в одну строчку

megaloman вот это голова! Я ход ваших мыслей уловил, теперь по вашему примеру запилю остальное. Спасибо большое!!!