 |
|
Корректировка кода что б не зависеть от жесткого пути к имени файла
Код, представленный ниже, отлично справляется со своей задачей перемешивания строк в файле. Проблема в том, что у него в условиях жестко задаются пути к файлам in/out. В приведенном примере у меня задан путь "...\MPL\Chillout\Chillout.alb". И естественно обрабатывается только этот файл. У меня же в папке "MPL" лежит 20 подпапок с разными названиями и в каждой лежит файл "*.alb" с таким же именем, как и папка. Мне нужна обработка всех файлов "*.alb" во всех подпапках папки "MPL".
Код:
@echo off
set "in=E:\MIX\MPL\Chillout\Chillout.alb"
set "out=E:\MIX\MPL\Chillout\Chillout.alb"
setlocal enabledelayedexpansion
for /f "usebackq tokens=1,2*" %%i in ("%in%") do (
set $%%j$!random!=%%i %%j %%k
)
for /f "tokens=1,2 delims=$=" %%i in ('set $') do (
if not "%%i"=="!x!" (
set /a m+=1
set x=%%i
)
set !m!$!random!=!$%%i$%%j!
)
for /l %%i in (1 1 %m%) do (
set $random=!random!
for /f "delims==" %%j in ('set %%i$') do (
set !$random!$$!random!=!%%j!
)
for /f "delims==" %%j in ('set !$random!$$') do (
set /a n+=1
set $$!n!$!random!=!%%j!
)
set n=
)
>"%out%" (
for /f "tokens=2 delims==" %%i in ('set $$') do (
echo %%i
)
)
exit /b
|
Например так.
Код:
@echo off
setlocal enabledelayedexpansion
pushd E:\MIX\MPL\
for /f "delims=" %%y in ('dir /b /a:d') do (
set "in=%%~fy\%%~ny.alb"
set "out=%%~fy\%%~ny.alb"
for /f "usebackq tokens=1,2*" %%i in ("%in%") do (
set $%%j$!random!=%%i %%j %%k
)
for /f "tokens=1,2 delims=$=" %%i in ('set $') do (
if not "%%i"=="!x!" (
set /a m+=1
set x=%%i
)
set !m!$!random!=!$%%i$%%j!
)
for /l %%i in (1 1 %m%) do (
set $random=!random!
for /f "delims==" %%j in ('set %%i$') do (
set !$random!$$!random!=!%%j!
)
for /f "delims==" %%j in ('set !$random!$$') do (
set /a n+=1
set $$!n!$!random!=!%%j!
)
set n=
)
>"%out%" (
for /f "tokens=2 delims==" %%i in ('set $$') do (
echo %%i
)
)
)
popd
Скрипт, однако, не учитывает, что есть папки в которых нет указанных файлов, но это уже если нужно будет... Еще прошу учесть что ничего не проверялось, вообще писал по памяти, чет в конец рабочего дня в пятницу вообще все лень. |
Что-то не так. Пробовал и чистый Ваш вариант и меняя
Код:
set "in=E:\MIX\MPL\%%~fi\%%~ni.alb"
set "out=E:\MIX\MPL\%%~fi\%%~ni.alb"
Выдает
Цитата:
Не удается найти файл
Переменная среды $ не определена
Системе не удается найти указанный путь
|
Цитата:
Цитата Elven
Скрипт, однако, не учитывает, что есть папки в которых нет указанных файлов »
|
Таких папок и не будет, так как они создаются перед этим тоже скриптом
Код:
@echo off
setlocal enabledelayedexpansion
>nul chcp 1251
set "src=E:\MIX\MUSIC"
set "dest=E:\MIX\MPL"
set "files=*.mp3"
set "playlistext=.alb"
2>nul (md "%dest%"
for /f "delims=" %%i in ('dir/ad/b "%src%"') do >"%dest%\%%i%playlistext%" dir/a-d/b/s "%src%\%%i\%files%")
For %%a in (E:\MIX\MPL\*.alb) do md "E:\MIX\MPL\%%~na"& move "%%~a" "E:\MIX\MPL\%%~na"
exit /b
Может как раз легче в этот код добавить функцию перемешивания? Что б уже создавались они рандомизированные? |
Та же ошибка. И пути похоже наблюдает. У меня сейчас 18 папок и выдает 18 ошибок. Возможно глупость, но не может это быть из-за кодировок?
|
Цитата:
Цитата krokradio
Код, представленный ниже, отлично справляется со своей задачей ...
|
Не берусь в него вникнуть, поэтому предлагаю:
Шаг 1.
Попробуйте скрипт
Код:
@Echo Off
cls
Set "Where=E:\MIX\MPL"
SetLocal EnableExtensions EnableDelayedExpansion
FOR /F "usebackq delims=" %%d IN (`Dir "%Where%" /b /A:D 2^>nul`) DO (
If Exist "%Where%\%%d\%%d.alb" Call :Working "%Where%\%%d\%%d.alb"
)
GoTo :Eof
:Working
set "in=%~1"
set "out=%~1"
Echo %in%
Echo %out%
Если имена файлов отображаются нормально, то:
Шаг 2.
Вместо двух последних строк c Echo добавьте текст своего скрипта начиная с Вашего первого for |
Попробовал. Имена отображаются нормально. А вот с обработкой загвоздка. Он где-то минуту работает с первой папкой. Прекрасно ее перемешивает. Потом думает 3-4 минуты и выдает следующе
Все остальные папки остаются не перемешанными. |
krokradio, А что вообще вы хотите получить в итоге?
|
Цитата:
Цитата krokradio
Мне нужна обработка всех файлов "*.alb" во всех подпапках папки "MPL". »
|
У меня есть 20 папок:
E:\MIX\MPL\name01\name01.alb
E:\MIX\MPL\name01\name02.alb
E:\MIX\MPL\name01\name03.alb
и т.д.
Это плейлисты, созданные другим скриптом (третий пост темы). В них треки идут по порядку (как лежали в папках при создании плейлистов).
Мне нужно все эти плейлисты рандомизировать (перемешать) для дальнейшей их обработки. |
Я пробовал еще такой вариант
Код:
@echo off
for /f "delims=" %%a in ('dir /a-d /b /s "E:\MIX\MPL\*.alb"') do (
setlocal enabledelayedexpansion
for /f "usebackq tokens=1,2*" %%i in ("%%a") do (
set $%%j$!random!=%%i %%j %%k
)
for /f "tokens=1,2 delims=$=" %%i in ('set $') do (
if not "%%i"=="!x!" (
set /a m+=1
set x=%%i
)
set !m!$!random!=!$%%i$%%j!
)
for /l %%i in (1 1 %m%) do (
set $random=!random!
for /f "delims==" %%j in ('set %%i$') do (
set !$random!$$!random!=!%%j!
)
for /f "delims==" %%j in ('set !$random!$$') do (
set /a n+=1
set $$!n!$!random!=!%%j!
)
set n=
)
>"%%a" (
for /f "tokens=2 delims==" %%i in ('set $$') do (
echo %%i
)
)
)
exit /b
Он обрабатывает все плейлисты по очереди, но оставляет их пустыми. Переменная $$ не определена.
 |
Цитата:
Цитата Foreigner
krokradio, А что вообще вы хотите получить в итоге? »
|
Вооот. С этого надо было начинать :). |
krokradio, Я правильно понял, что нужно найти все *.alb и перемешать их содержимое?
Код:
@echo off
setlocal
for /f "tokens=*" %%i in ('dir /b /s E:\MIX\MPL\*.alb') do (
for /f "tokens=*" %%j in ('type "%%i"') do call:set_random "%%j"
call:set_content "%%i"
)
goto:eof
:set_random
set "line_%random%=%~1"
goto:eof
:set_content
1>%1 (
for /f "tokens=2* delims==" %%i in ('set line_') do echo %%i
)
for /f "tokens=1 delims==" %%i in ('set line_') do set "%%i="
PS. Проверил на тестовых *.txt
|
Foreigner, господи, мил человек, слава тебе! Ты все правильно понял! И оно работает так как нужно! Огромное тебе спасибо!
|
Время: 22:19.
© OSzone.net 2001-