[решено] Файл перемещения - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - [решено] Файл перемещения (http://forum.oszone.net/showthread.php?t=297304)

Jokerxman

22-03-2015 22:02 2486210

Файл перемещения

Здраствуйте, весь день искал и не могу найти и выполнить задание...

Требуется создать bat файл, чтобы он к примеру из папки " C:\1 " в которой находится 3 файла, с разными расширениями... в папку " C:\2 " только в папке " 2 " он создал папки с расширениями файлов и кинул туда тот файл.
Срочно до завтра нужно...

Jokerxman

22-03-2015 22:52 2486228

а можно как нибудь по короче что-то вроде такого?

Ведь " %1 " это кажись расширение файла...
Мне по проще, чтобы легче запомнить и обьяснить можно было...
Просто там столько команд которых я даже не знаю...

Iska	23-03-2015 00:29 2486266

Код:

@echo off

setlocal enableextensions enabledelayedexpansion



set sSourceFolder=C:\1

set sDestFolder=C:\2



if exist "%sSourceFolder%" (

        if exist "%sDestFolder%" (

                pushd "%sSourceFolder%"

                

                for /f "usebackq delims=" %%i in (

                        `2^>nul dir /b /a:-d`

                ) do (

                        set sDestPath=%sDestFolder%\%%~xi

                        if not exist "!sDestPath!" md "!sDestPath!"

                        echo [%%~i] ---^> [!sDestPath!]

                        >nul move "%%~i" "!sDestPath!\"

                )

                

                popd

        ) else (

                echo Can't find destination folder [%sDestFolder%].

                exit /b 2

        )

) else (

        echo Can't find source folder [%sSourceFolder%].

        exit /b 1

)



endlocal

exit /b 0

Время: 09:11.