Добавление строк по шаблону... - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - Добавление строк по шаблону... (http://forum.oszone.net/showthread.php?t=267074)

Добавление строк по шаблону...

Доброго дня! Я понимаю, что задача, которая возникла передо мной с моими знаниями не выполнима.. Поэтому надеюсь хоть на какую-то помощь)))... Если такое возможно средствами командной строки... Опишу ситуацию и цель..
Есть csv-файл образец-шаблон:

Это эталон будущей примерной структуры необходимого файла...
Есть файл work.csv с примерной структурой:

Это как образец.... То есть структура не стабильная, первые ДВЕ строки, начинаюшиеся с 20100 и 20300 стабильны и считаются началом нового блока информации..., вполь до следующих "20100 и 20300"...
Остальные строки или есть или нет, или все или не все.. без всяких правил....
Цель преобразовать файл, добавив нехватающие строки по шаблону, со значением равным нулю, приведя к такому виду:

Помогите или подскажите как такое реализовать.... Средствами поиска и замены, это нереально много условий... Может кто-то знает, как это сделать проще?!

Цитата:

Цитата adrobkov@vk

первые ДВЕ строки, начинаюшиеся с 20100 и 20300 стабильны и считаются началом нового блока информации..., вполь до следующих "20100 и 20300"... »

То есть, может если просто «20100» — то это не начало очередного блока?

Цитата:

То есть, может если просто «20100» — то это не начало очередного блока?

Начало... Строка начинающаяся с 20100 считается новым блоком... Все что находится после нее вплоть до следующих 20100 не включительно...

Код:

@Echo Off

SetLocal EnableDelayedExpansion



Set Input=work.csv

Set SphericalStandardFileInVacuum=standard.csv



:: Подготавливаем входящий файл

Copy "%Input%" "%Input%.bak">nul

Echo.>"%Input%"

:: Читаем файл-эталон и пишем строки из него в массив

Set StdData[]=

For /F "usebackq eol= tokens=1 delims=;" %%A In ("%SphericalStandardFileInVacuum%") Do (Set StdData[]=!StdData[]! %%A )

:: Разбираем входящий файл поблочно

For /F "usebackq eol= delims=" %%A In ("%Input%.bak") Do (

        Set Data=%%A

::        Работа с содержимым

        If "!Block!"=="true" If "!Data:~,6!"=="20100;" (

                Set Block=false

::                Обрабатываем данные

                Call :ParseBlock

::                Удаление

                Call :DeleteBlock

        )

::        Определение начала блока

        If "!Data:~,6!"=="20100;" (

                Set Block=true

                Set i=0

        )

::        Запись содержимого блока

        If "!Block!"=="true" (

                Set /A i+=1

                Set BlockData_!i!=!Data!

        )

)

:: Обработка завершающего блока

If Defined BlockData_1 (

        Call :ParseBlock

        Call :DeleteBlock

)

Del "%Input%.bak"

Pause&Exit



:ParseBlock

:: Пишем в массив строки, входящие в блок, одновременно с тем сохраняя их значения для последующего использования

Set BlockData[]=

For /F "eol= tokens=2,* delims=;=" %%A In ('Set BlockData_') Do (

        Set BlockData[]=!BlockData[]! %%A 

        Set Data_%%A=%%B

)

:: Проходимся по массиву файла-эталона, определяя, какие строки в него включены

For %%A In (!StdData[]!) Do (

        Echo "!BlockData[]!"|Find " %%A ">nul&&(

                >>"%Input%" Echo %%A;!Data_%%A!

        )||(

                >>"%Input%" Echo %%A;0

        )

)

Exit /B



:DeleteBlock

:: Удаляем все записи блока

For /F "tokens=1 delims==" %%B In ('Set BlockData_') Do (Set %%B=)

Exit /B

Anonymоus, это героически ;).