Бекапирование Оутлук заблокированных pst файлов (backup Outlook) почты через bat/cmd

Организацию бекапов (backup Outlook) почты через бат файл реализовал с помощью батника так:
Имею Файл c:\backup_scripts\comppath.txt с 3 переменными на каждой строчке: 1 - Именем компа по сети, 2- именем учетки, 3- пути к файлу outlook.pst с разделением через пробел:

Код:

Marina maria_ov C:\Docume~1\maria_ov\Locals~1\Applic~1\Microsoft\Outlook

Так-же сделал батник (BAT, CMD SCRIPT) скриптик: c:\backup_scripts\outlook_backup.cmd, который запускается на сервере в шедулере (Scheduled Tasks): c:\backup_scripts\outlook_backup.cmd >backup.log.txt

Код:

--------------------------------------------------------------------------------

@FOR /F "tokens=1,2,3 delims= " %%i in (comppath.txt) do @(

ping -n 1 %%i > pinglog

find "Reply from" < pinglog > nul

@echo --------------------------------------------------- %%i

if errorlevel 1 (

@echo %%i - PING NOT OK - SKIP ALL TASK FOR %%i

) else (

@echo FOR %%i COMPUTER SCRIPT START

@echo @rem %%i OUTLOOK BACKUP SCRIPT>%%i.bat

echo cd c:\>>%%i.bat

echo mkdir Backup>>%%i.bat

echo cd c:\Backup>>%%i.bat

echo mkdir Outlook>>%%i.bat

echo cd c:\>>%%i.bat

echo HoboCopy_xp.exe %%k C:\Backup\Outlook *.pst *.dat>>%%i.bat

echo HoboCopy_xp.exe C:\Docume~1\%%j\Applic~1\Microsoft\Outlook C:\Backup >>%%i.bat

echo del c:\*.rar>>%%i.bat

echo C:\Progra~1\WinRAR\rar.exe a C:\outlook_%%i.rar C:\Backup\*.* -m5 -r -ri1 -df -ag_yyyy-mm-dd>>%%i.bat

xcopy %%i.bat \\%%i\C$\ /y

xcopy HoboCopy_xp.exe \\%%i\C$\ /y

PsExec.exe \\%%i C:\%%i.bat

@echo FOR %%i COMPUTER SCRIPT END

cd x:\_Backup\Outlook

MKDIR X:\_Backup\Outlook\%%i

cd x:\_Backup\Outlook\%%i

DEL x:\_Backup\Outlook\%%i\old*.*

REN x:\_Backup\Outlook\%%i\*.rar old_one*.rar

xcopy \\%%i\c$\*.rar x:\_Backup\Outlook\%%i\ /Y /V

cd C:\backup_scripts

move /Y C:\backup_scripts\%%i.bat C:\backup_scripts\BATS\%%i.bat

)

@echo --------------------------------------------------- %%i

)

@del C:\backup_scripts\pinglog

x:\_Backup\Outlook\COMPNAME - Место, куда складируются бэкапы за последние 2 недели.
2 files: old_one_COMPNAME_2011-05-02.rar и outlook_COMPNAME_2011-04-25.rar, где COMPNAME - имя компа в сети

для Win2k, включая Висту и Вынь7 нужно использовать скрипт с HoboCopy_2k.exe вместо HoboCopy_xp.exe
для Win7 x64 нужно использовать скрипт с файлом HoboCopy_x64.exe вместо HoboCopy_xp.exe

Логи складируются в c:\backup_scripts\backup.log.txt

В папке c:\backup_scripts\ имеем следующие основные файлы:
comppath.txt
HoboCopy_2k.exe
HoboCopy_xp.exe
outlook_backup.cmd
PsExec.exe

Используемые переменные в скрипте, которы заполняются данными из comppath.txt:
%%i - Имя компа по сети
%%j - Имя учетки
%%k - Путь к outlook.pst

Сокращения DOS:
Applic~1 = "Application Data"
Docume~1 = "Documents and Settings"
Locals~1 = "Local Settings"

Вспомогательные программы:
HoboCopy - (копирование файлов, которые используются в данный момент, т.е. открыты на запись или по другому заблокированы для записи, например программой OUTLOOK) - https://github.com/candera/hobocopy/downloads (ранее был в составе Wangdera Tools and Utilities http://sourceforge.net/projects/wang....Controls/0.7/)
PsExec - тулза (Удаленное выполнение программ) из состава PSTOOLS http://technet.microsoft.com/en-ca/s...rnals/bb896649 из сайта Windows Sysinternals набора http://technet.microsoft.com/en-ca/sysinternals
WINRAR - популярный архиватор