[решено] Нумерация строк в cmd - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - [решено] Нумерация строк в cmd (http://forum.oszone.net/showthread.php?t=212511)

werov

03-08-2011 12:31 1725127

Нумерация строк в cmd

Подскажите, можно ли сделать так, чтобы cmd автоматически нумеровал строки? Например, я задаю ping google.com -t и чтобы вместо стандартного:

Код:

Обмен пакетами с google.com [74.125.39.104] с 32 байтами данных:

Ответ от 74.125.39.104: число байт=32 время=88мс TTL=54

Ответ от 74.125.39.104: число байт=32 время=75мс TTL=54

Ответ от 74.125.39.104: число байт=32 время=73мс TTL=54

Ответ от 74.125.39.104: число байт=32 время=74мс TTL=54

Выдавалось:

Код:

Обмен пакетами с google.com [74.125.39.104] с 32 байтами данных:

1. Ответ от 74.125.39.104: число байт=32 время=88мс TTL=54

2. Ответ от 74.125.39.104: число байт=32 время=75мс TTL=54

3. Ответ от 74.125.39.104: число байт=32 время=73мс TTL=54

4. Ответ от 74.125.39.104: число байт=32 время=74мс TTL=54

Или для этого надо использовать какую-то альтернативную консоль сторонних производителей?

Dzirt2005

03-08-2011 13:22 1725166

Цитата:

Цитата werov

Подскажите, можно ли сделать так, чтобы cmd автоматически нумеровал строки? Например, я задаю ping google.com -t и чтобы вместо стандартного: »

У тебя очень странный пример. Почему это вывод строк, начинающихся с "Ответ от" нумеруется, а "Обмен пакетами ..." и первая пустая строка в выводе - нет?

Например, вариант:

Код:

C:\>ping google.com | findstr /N ".*"

1:

2:Обмен пакетами с google.com [209.85.148.105] с 32 байтами данных:

3:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

4:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

5:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

6:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

7:

8:Статистика Ping для 209.85.148.105:

9:    Пакетов: отправлено = 4, получено = 4, потеряно = 0

10:    (0% потерь)

11:Приблизительное время приема-передачи в мс:

12:    Минимальное = 46мсек, Максимальное = 46 мсек, Среднее = 46 мсек

устроит?

werov

03-08-2011 13:30 1725169

Цитата:

Цитата Dzirt2005

Например, вариант:
Код:
C:\>ping google.com | findstr /N ".*"
1:
2:Обмен пакетами с google.com [209.85.148.105] с 32 байтами данных:
3:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53
4:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53
5:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53
6:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53
7:
8:Статистика Ping для 209.85.148.105:
9: Пакетов: отправлено = 4, получено = 4, потеряно = 0
10: (0% потерь)
11:Приблизительное время приема-передачи в мс:
12: Минимальное = 46мсек, Максимальное = 46 мсек, Среднее = 46 мсек
устроит? »

ага, +/-несколько строк роли не сыграют, спасибо

P.S. Тогда еще маленький вопросец: можно ли увеличить чисто строк в cmd до числа большего чем 9999?

P.P.S. И раз уж такая канитель понеслась, то заодно хотелось бы узнать, можно ли вместо номера строки сделать примерно следующее:

Код:

C:\>ping google.com | findstr /N ".*"

3.08.2011 13:47:21:

3.08.2011 13:47:22:Обмен пакетами с google.com [209.85.148.105] с 32 байтами данных:

3.08.2011 13:47:23:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

3.08.2011 13:47:24:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

3.08.2011 13:47:25:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

3.08.2011 13:47:26:Ответ от 209.85.148.105: число байт=32 время=46мс TTL=53

3.08.2011 13:47:27:

3.08.2011 13:47:28:Статистика Ping для 209.85.148.105:

3.08.2011 13:47:29: Пакетов: отправлено = 4, получено = 4, потеряно = 0

3.08.2011 13:47:30: (0% потерь)

3.08.2011 13:47:31:Приблизительное время приема-передачи в мс:

3.08.2011 13:47:32: Минимальное = 46мсек, Максимальное = 46 мсек, Среднее = 46 мсек

Foreigner

03-08-2011 16:40 1725322

Цитата:

Цитата werov

можно ли вместо номера строки сделать примерно следующее »

Код:

@echo off

setlocal enabledelayedexpansion



for /f "tokens=*" %%i in ('ping google.com') do echo !date! !time!: %%i

werov

03-08-2011 16:45 1725327

Цитата:

Цитата Foreigner

можно ли вместо номера строки сделать примерно следующее »
Код:
@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('ping google.com') do echo !date! !time!: %%i »

ммм.. создать батник из этого я так понимаю?
Сделал батник, пробегает пинг и окошко закрывается, ничего не видно. Если делаю параметр -t после гугл.ком, тогда вообще на экране ничего не видно

сама суть сего действия такова, что иногда у меня отваливается один очень важный сайт, тех. поддержка постоянно пинает меня от одного отдела к другому, ссылаясь на то, что все у них работает. Вот и хочу поставить их сайт на пинг с параметром -t, чтобы круглосуточно шли постоянные пинги, а затем при очередном "падении" их сайта можно было предъявить точные доказательства того, в какое конкретно время сайт падал

kiripanda

03-08-2011 18:18 1725423

Код:

@echo off &setlocal enabledelayedexpansion

set "host=google.com"

:loop

for /f "tokens=*" %%i in ('ping -n 1 %host% ^|findstr "=" ^|^|ping -n 1 %host%') do (

echo !date! !time!: %%i>> "!date:/=-!.log"

echo !date! !time!: %%i

ping -n 59 localhost >nul

goto :loop

)

Foreigner

03-08-2011 19:25 1725452

Цитата:

Цитата werov

Сделал батник, пробегает пинг и окошко закрывается, ничего не видно »

Попробовал еще раз -- работает:

Цитата:

> 1
03.08.2011 19:17:56,33: Обмен пакетами с google.com [74.125.43.106] с 32 байтами данных:
03.08.2011 19:17:56,33: Ответ от 74.125.43.106: число байт=32 время=46мс TTL=55
03.08.2011 19:17:56,33: Ответ от 74.125.43.106: число байт=32 время=46мс TTL=55
03.08.2011 19:17:56,33: Ответ от 74.125.43.106: число байт=32 время=47мс TTL=55
03.08.2011 19:17:56,34: Ответ от 74.125.43.106: число байт=32 время=47мс TTL=54
03.08.2011 19:17:56,34: Статистика Ping для 74.125.43.106:
03.08.2011 19:17:56,34: Пакетов: отправлено = 4, получено = 4, потеряно = 0
03.08.2011 19:17:56,34: (0% потерь)
03.08.2011 19:17:56,34: Приблизительное время приема-передачи в мс:
03.08.2011 19:17:56,34: Минимальное = 46мсек, Максимальное = 47 мсек, Среднее = 46 мсек

>

Как запускали, я прямо из cmd, если мышью, то допишите pause в конце батника или перенаправляйте вывод батника в файл.

Anonymоus

04-08-2011 03:48 1725632

Код:

Started at [04.08.2011 -  2:39:06]

04.08.2011 -  2:39:20 >> 127.0.0.1 is active



Started at [04.08.2011 -  2:39:46]

04.08.2011 -  2:40:01 >> google.ru is active

04.08.2011 -  2:40:43 >> google.ru is offline

04.08.2011 -  2:41:59 >> google.ru is active

Сам скрипт:

Код:

@Echo Off

:: Anonymous, 2011

Cls

Title Ping2Host



:: Ведение лога

Set Logging=true

:: Таймаут в секундах

Set Timeout=15



Echo.

Set /P Host=  Enter IP or hostname: ^> 

Cls&Set Total=0&Set Succes=0&Set Fail=0&Set Status=Not checked yet&Set StartTime=[%date% - %time:~-0,8%]

Set /A Sleep=(Timeout-1)*1000

If %Logging%==true (Set LogFile="%~n0.log") Else (Set LogFile=nul)

Echo.>>%LogFile%&Echo Started at %StartTime%>>%LogFile%

:ShowStats

Call :Stats

.\bin\nc.exe wait %Sleep%

Ping -n 1 -w 1000 -l 1024 %Host%>nul

If %ErrorLevel% GTR 0 (

Set /A Fail+=1

If Not "%Status%"=="Offline" (Echo %date% - %time:~-0,8% ^>^> %Host% is offline>>%LogFile%)

Set Status=Offline

Title Offline [%Host%] - Ping2Host

) Else (

Set /A Succes+=1

If Not "%Status%"=="Online" (Echo %date% - %time:~-0,8% ^>^> %Host% is active>>%LogFile%)

Set Status=Online

Title Online [%Host%] - Ping2Host

)

GoTo ShowStats



:Stats

Cls

Echo.

Echo  Started at: %StartTime%

Echo.

Echo  Target: %Host%

Echo  Online: %Succes% times, Offline: %Fail% times

Echo  Current status: [%date% - %time:~-0,8%] - %Status%

Echo.

Exit /B

Для его правильной работы нужно скачать NirCmd (консольная версия), переименовать exe-файл в nc.exe, создать рядом со скриптом директорию bin и положить туда nc.exe.

werov

04-08-2011 10:13 1725708

Цитата:

Цитата kiripanda

@echo off &setlocal enabledelayedexpansion set "host=google.com" :loop for /f "tokens=*" %%i in ('ping -n 1 %host% ^|findstr "=" ^|^|ping -n 1 %host%') do ( echo !date! !time!: %%i>> "!date:/=-!.log" echo !date! !time!: %%i ping -n 59 localhost >nul goto :loop ) »

Создал бат-файл, запускаю, выдает одну строчки:

Код:

04.08.2011  9:22:19,49: Ответ от 74.125.39.99: число байт=32 время=85мс TTL=54

04.08.2011  9:23:17,78: Ответ от 74.125.39.99: число байт=32 время=86мс TTL=54

04.08.2011  9:24:16,10: Ответ от 74.125.39.105: число байт=32 время=85мс TTL=54

Видно, что пинг идет раз в минуту. Что означает число после запятой не знаю, но догадываюсь, что это сотые доли секунды. Хотелось бы, чтобы пинги шли каждую секунду, как при стандартной команде ping. А так скрипт, как раз то что надо

Цитата:

Цитата Foreigner

Как запускали, я прямо из cmd, если мышью, то допишите pause в конце батника или перенаправляйте вывод батника в файл. »

Из cmd напрямую:

Код:

S:\>@echo off

setlocal enabledelayedexpansion

for /f "tokens=*" %%i in ('ping google.com') do echo !date! !time!: %%i

Непредвиденное появление: %%i.

Из батника с командой pause в конце запустилось, но мне надо пинговать с параметром -t, а если его прописать, то ничего опять же не появляется

Dzirt2005

04-08-2011 10:55 1725732

Цитата:

Цитата werov

Из батника с командой pause в конце запустилось, но мне надо пинговать с параметром -t, а если его прописать, то ничего опять же не появляется »

Потому что for ждет окончания вывода. Вариант с внешней программой не устраивает? Например, с mtee :

Код:

C:\>ping -t google.com | mtee /d /t

2011-08-04 09:53:02.606

2011-08-04 09:53:02.606 Обмен пакетами с google.com [209.85.148.105] с 32 байтами данных:

2011-08-04 09:53:02.637 Ответ от 209.85.148.105: число байт=32 время=44мс TTL=53

2011-08-04 09:53:03.637 Ответ от 209.85.148.105: число байт=32 время=44мс TTL=53

2011-08-04 09:53:04.637 Ответ от 209.85.148.105: число байт=32 время=44мс TTL=53

2011-08-04 09:53:05.637 Ответ от 209.85.148.105: число байт=32 время=44мс TTL=53

2011-08-04 09:53:06.638 Ответ от 209.85.148.105: число байт=32 время=44мс TTL=53

2011-08-04 09:53:07.638 Ответ от 209.85.148.105: число байт=32 время=44мс TTL=53

2011-08-04 09:53:08.069

2011-08-04 09:53:08.069 Статистика Ping для 209.85.148.105:

2011-08-04 09:53:08.069     Пакетов: отправлено = 6, получено = 6, потеряно = 0

2011-08-04 09:53:08.069     (0% потерь)

2011-08-04 09:53:08.070 ^Приблизительное время приема-передачи в мс:

C2011-08-04 09:53:08.070     Минимальное = 44мсек, Максимальное = 44 мсек, Среднее = 44 мсек

2011-08-04 09:53:08.070 Control-C

werov

04-08-2011 10:55 1725733

Цитата:

Цитата Anonymоus

Вот мое решение, думаю, Вам подойдет. Скрипт периодически (с настраиваемым интервалом, по умолчанию - 15 сек) пингует выбранный хост, отображает статистику - сколько раз смог удачно пропинговать, сколько раз сайт был недоступен, и при любой смене статуса хоста записывает это событие в лог. В логе вы увидите примерно такое:
Код:
Started at [04.08.2011 - 2:39:06]
04.08.2011 - 2:39:20 >> 127.0.0.1 is active
Started at [04.08.2011 - 2:39:46]
04.08.2011 - 2:40:01 >> google.ru is active
04.08.2011 - 2:40:43 >> google.ru is offline
04.08.2011 - 2:41:59 >> google.ru is active
Сам скрипт:
Код:
@Echo Off
:: Anonymous, 2011
Cls
Title Ping2Host
:: Ведение лога
Set Logging=true
:: Таймаут в секундах
Set Timeout=15
Echo.
Set /P Host= Enter IP or hostname: ^>
Cls&Set Total=0&Set Succes=0&Set Fail=0&Set Status=Not checked yet&Set StartTime=[%date% - %time:~-0,8%]
Set /A Sleep=(Timeout-1)*1000
If %Logging%==true (Set LogFile="%~n0.log") Else (Set LogFile=nul)
Echo.>>%LogFile%&Echo Started at %StartTime%>>%LogFile%
:ShowStats
Call :Stats
.\bin\nc.exe wait %Sleep%
Ping -n 1 -w 1000 -l 1024 %Host%>nul
If %ErrorLevel% GTR 0 (
Set /A Fail+=1
If Not "%Status%"=="Offline" (Echo %date% - %time:~-0,8% ^>^> %Host% is offline>>%LogFile%)
Set Status=Offline
Title Offline [%Host%] - Ping2Host
) Else (
Set /A Succes+=1
If Not "%Status%"=="Online" (Echo %date% - %time:~-0,8% ^>^> %Host% is active>>%LogFile%)
Set Status=Online
Title Online [%Host%] - Ping2Host
)
GoTo ShowStats
:Stats
Cls
Echo.
Echo Started at: %StartTime%
Echo.
Echo Target: %Host%
Echo Online: %Succes% times, Offline: %Fail% times
Echo Current status: [%date% - %time:~-0,8%] - %Status%
Echo.
Exit /B
Для его правильной работы нужно скачать NirCmd (консольная версия), переименовать exe-файл в nc.exe, создать рядом со скриптом директорию bin и положить туда nc.exe. »

скрипт тоже отличный, только вот потестил я его около часа, нашел один недостаток: файлик обновляет при первом запуске скрипта строчкой:

Код:

04.08.2011 - 10:32:56 >> google.com is active

И на этом все, даже после принудительного завершения срипта через ctrl+c файлик не обновляется. Обновление происходит только во время разрыва связи. Оно конечно и понятно с одной стороны: зачем захламлять лог-файл лишними записями. Но было бы удобно, чтобы логи писались хотя бы при выходе из скрипта, что-то типа:

Код:

04.08.2011 - 10:32:56 >> google.com is active

***тут я завершаю работу скрипта***

04.08.2011 - 10:55:51 >> google.com is active

Цитата:

Цитата Dzirt2005

Вариант с внешней программой не устраивает? Например, с mtee : »

да внешняя программулина не проблема. Скачал этот mtee. чет не пойму как он работает. Его надо в директорию виндоус кинуть рядом с cmd?

Dzirt2005

04-08-2011 11:19 1725741

Цитата:

Цитата werov

да внешняя программулина не проблема. Скачал этот mtee. чет не пойму как он работает. Его надо в директорию виндоус кинуть рядом с cmd? »

В любой каталог, прописанный в переменной PATH (можешь и в %SystemRoot%\System32). Если нужно чтобы и в лог-файл писалось, то вызов будет такой:

Код:

ping -t google.com | mtee /d /t /+ result.log

В файл result.log будет писаться все то, что выводится на экран

Foreigner

04-08-2011 12:21 1725771

Цитата:

Цитата werov

Из cmd напрямую:
Код:
S:\>@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('ping google.com') do echo !date! !time!: %%i
Непредвиденное появление: %%i. »

Ну так зачем все это вставлять в окошко cmd??!! Создай батник и запускай:

Код:

S:\> batfile.cmd

Anonymоus

04-08-2011 17:57 1725939

Цитата:

Цитата werov

Дополнил скрипт. Для корректного выхода (с сохранением времени выхода в лог и текущего статуса на тот момент) создайте рядом со скриптом файл stop.txt.

Пример лога:

Код:

Started at [04.08.2011 - 16:54:18]

04.08.2011 - 16:54:32 >> 192.168.50.5 is active

Closed at [04.08.2011 - 16:55:42], last status: Online

Скрипт:

Код:

@Echo Off

:: Anonymous, 2011

Cls

Title Ping2Host



:: Ведение лога

Set Logging=true

:: Таймаут в секундах

Set Timeout=15



Echo.

Set /P Host=  Enter IP or hostname: ^> 

Cls&Set Total=0&Set Succes=0&Set Fail=0&Set Status=Not checked yet&Set StartTime=[%date% - %time:~-0,8%]

Set /A Sleep=(Timeout-1)*1000

If %Logging%==true (Set LogFile="%~n0.log") Else (Set LogFile=nul)

Echo.>>%LogFile%&Echo Started at %StartTime%>>%LogFile%

:ShowStats

Call :Stats

.\bin\nc.exe wait %Sleep%

Ping -n 1 -w 1000 -l 1024 %Host%>nul

If %ErrorLevel% GTR 0 (

Set /A Fail+=1

If Not "%Status%"=="Offline" (Echo %date% - %time:~-0,8% ^>^> %Host% is offline>>%LogFile%)

Set Status=Offline

Title Offline [%Host%] - Ping2Host

) Else (

Set /A Succes+=1

If Not "%Status%"=="Online" (Echo %date% - %time:~-0,8% ^>^> %Host% is active>>%LogFile%)

Set Status=Online

Title Online [%Host%] - Ping2Host

)

If Exist stop.txt (

Echo Closed at [%date% - %time:~-0,8%], last status: %Status%>>%LogFile%

Exit

)

GoTo ShowStats



:Stats

Cls

Echo.

Echo  Started at: %StartTime%

Echo.

Echo  Target: %Host%

Echo  Online: %Succes% times, Offline: %Fail% times

Echo  Current status: [%date% - %time:~-0,8%] - %Status%

Echo.

Exit /B

kiripanda

04-08-2011 20:23 1726000

Цитата:

Цитата werov

Хотелось бы, чтобы пинги шли каждую секунду, как при стандартной команде ping. А так скрипт, как раз то что надо »

В моём варианте 1 сек. собственно пинг — 59 сек. пауза;
Удали\закомментируй ping -n 59 localhost >nul и будет тебе счастье.
После запятой действительно сотые

werov

05-08-2011 10:17 1726268

Цитата:

Дополнил скрипт. Для корректного выхода (с сохранением времени выхода в лог и текущего статуса на тот момент) создайте рядом со скриптом файл stop.txt.

обновил скрипт, создал рядом с файлом 1.bat файлик stop.txt. Запускаю скрипт, прописываю google.com, проходит 15 сек, консольное окно закрывается, файл 1.log обновляется с такой записью:

Код:

Started at [05.08.2011 - 10:06:28]

05.08.2011 - 10:06:42 >> google.com is active

Closed at [05.08.2011 - 10:06:42], last status: Online

Далее снова запускаю скрипт, задаю google.com -t, на экране консольного окна появляется:

Код:

Started at: [05.08.2011 - 10:11:21]



Target: google.com -t

Online: 0 times, Offline: 0 times

Current status: [05.08.2011 - 10:11:21] - Not checked yet

И висит таким образом пока не закроешь консольное окно. В лог файле появляется запись:

Код:

Started at [05.08.2011 - 10:11:21]

И все...

Т.е. проблема в том, что при наборе google.com срабатывает стандартная команда пинг гугл.ком, без параметра -t, как это работало в предыдущей версии скрипта. А если жестко руками прописать google.com -t, тогда скрипт отказывается работать

З.Ы. удалил файл stop.txt скрипт снова стал работать нормально. Как только создал файл заново, скрипт автоматически сам вылетает после первых удачных 15 секунд

Anonymоus

05-08-2011 16:11 1726442

werov, зачем вы приписываете ключ -t к адресу? Скрипт и без этого будет работать до того момента, как вы не прекратите его работу. Файл stop.txt нужно создавать только тогда, когда хотите выключить скрипт, чтобы он корректно отработал выключение с записью в лог.

werov

05-08-2011 16:26 1726455

а ну так с этого и надо было начинать, что файл stop.txt надо создать непосредственно перед отключением скрипта. Тогда все ясно. Спасибо! Очень выручил

werov

08-08-2011 10:13 1727711

Anonymоus
И еще одна маленькая просьба. Можно сделать так, чтобы при открытии батника не надо было вводить google.com, а сразу же после запуска начинались пинги? Т.е. чтобы какой сайт пинговать можно было править в самом батнике

Anonymоus

08-08-2011 12:08 1727763

werov, держите, адрес выделен жирным:

Код:

@Echo Off

:: Anonymous, 2011

Cls

Title Ping2Host



:: Ведение лога

Set Logging=true

:: Таймаут в секундах

Set Timeout=15

:: Адрес

Set Host=google.com





Set Total=0&Set Succes=0&Set Fail=0&Set Status=Not checked yet&Set StartTime=[%date% - %time:~-0,8%]

Set /A Sleep=(Timeout-1)*1000

If %Logging%==true (Set LogFile="%~n0.log") Else (Set LogFile=nul)

Echo.>>%LogFile%&Echo Started at %StartTime%>>%LogFile%

:ShowStats

Call :Stats

.\bin\nc.exe wait %Sleep%

Ping -n 1 -w 1000 -l 1024 %Host%>nul

If %ErrorLevel% GTR 0 (

Set /A Fail+=1

If Not "%Status%"=="Offline" (Echo %date% - %time:~-0,8% ^>^> %Host% is offline>>%LogFile%)

Set Status=Offline

Title Offline [%Host%] - Ping2Host

) Else (

Set /A Succes+=1

If Not "%Status%"=="Online" (Echo %date% - %time:~-0,8% ^>^> %Host% is active>>%LogFile%)

Set Status=Online

Title Online [%Host%] - Ping2Host

)

If Exist stop.txt (

Echo Closed at [%date% - %time:~-0,8%], last status: %Status%>>%LogFile%

Exit

)

GoTo ShowStats



:Stats

Cls

Echo.

Echo  Started at: %StartTime%

Echo.

Echo  Target: %Host%

Echo  Online: %Succes% times, Offline: %Fail% times

Echo  Current status: [%date% - %time:~-0,8%] - %Status%

Echo.

Exit /B

werov

08-08-2011 12:22 1727775

большое спасибо!

Время: 04:25.