 |
|
Ultimate X Project Аддон
Здравствуйте.
В директории есть файлы(D:\Work\ Resources).Как найти их в папке I386 (Дистр.Windows) и распаковать в заданную папку(D:\Work\1\temp)?
Вот список файлов
читать дальше »
Код:
7z.dll
7zfm.exe
7zg.exe
access.cpl
acctres.dll
accwiz.exe
admparse.dll
ahui.exe
appmgr.dll
appwiz.cpl
asctrls.ocx
audiodev.dll
autodisc.dll
avtapi.dll
batmeter.dll
batt.dll
browselc.dll
browseui.dll
bthci.dll
bthprops.cpl
cabview.dll
calc.exe
capesnpn.dll
cards.dll
cdfview.dll
certmgr.dll
charmap.exe
ciadmin.dll
cleanmgr.exe
cliconfg.exe
clipbrd.exe
clipsrv.exe
cmd.exe
cmdial32.dll
cmdl32.exe
cmmon32.exe
cmprops.dll
cmstp.exe
comctl2.dll
comctl3.dll
comctl32.dll
comdlg32.dll
compatui.dll
compstui.dll
comres.dll
conf.exe
conime.exe
console.dll
credui.dll
cryptui.dll
cscdll.dll
cscript.exe
ctfmon.exe
dataclen.dll
ddeshare.exe
desk.cpl
deskadp.dll
deskmon.dll
deskperf.dll
devmgr.dll
dfrgres.dll
dfrgui.dll
dialer.exe
digest.dll
diskcopy.dll
dmdlgs.dll
dmdskres.dll
dpmodemx.dll
dpvoice.dll
drwtsn32.exe
dskquoui.dll
dsprop.dll
dsquery.dll
dsuiext.dll
dvdplay.exe
dxmasf.dll
els.dll
eqnclass.dll
eudcedit.exe
eventvwr.exe
extmgr.dll
extmgr.dll.mui
fde.dll
filemgmt.dll
firewall.cpl
fldrclnr.dll
fm20enu.dll
fontext.dll
fontview.exe
freecell.exe
fsquirt.exe
fxscfgwz.dll
fxsclnt.exe
fxsclntr.dll
fxscover.exe
fxswzrd.dll
gcdef.dll
gpedit.dll
gpprefcl.dll
gptext.dll
grpconv.exe
h323.tsp
hdwwiz.cpl
helpctr.exe
hh.exe
hmmapi.dll
hnetwiz.dll
hotplug.dll
hticons.dll
hypertrm.dll
hypertrm.exe
icm32.dll
icmui.dll
icwconn1.exe
icwconn2.exe
icwdial.dll
icwhelp.dll
icwres.dll
idecoi.dll
idecoiins.dll
ieaksie.dll
ieakui.dll
ieframe.dll
ieframe.dll.mui
iepeers.dll
iernonce.dll
iesetup.dll
iexplore.exe
iexpress.exe
iis.dll
inetcfg.dll
inetcpl.cpl
inetcplc.dll
inetppui.dll
inetres.dll
inetwiz.exe
infocardcpl.cpl
input.dll
intl.cpl
ipsecsnp.dll
ipsmsnap.dll
irclass.dll
irftp.exe
irmon.dll
irprops.cpl
isign32.dll
isignup.exe
itss.dll
jobexec.dll
joy.cpl
keymgr.dll
lights.exe
localsec.dll
loghours.dll
magnify.exe
main.cpl
mapi32.dll
mapi32tb.dll
mapistub.dll
mciavi32.dll
mdminst.dll
mdwmdmsp.dll
midimap.dll
migpwd.exe
mmc.exe
mmcbase.dll
mmcndmgr.dll
mmcshext.dll
mmsys.cpl
mnmsrvc.exe
mobsync.dll
mobsync.exe
modemui.dll
mplay32.exe
mplayer2.exe
mprui.dll
mqsnap.dll
mqutil.dll
msacm32.dll
msconf.dll
msconfig.exe
mscorier.dll
msdxm.ocx
mshta.exe
msi.dll
msident.dll
msidntld.dll
msieftp.dll
msiexec.exe
msihnd.dll
mspaint.exe
mspmsp.dll
msports.dll
msratelc.dll
msrating.dll
mstask.dll
msutb.dll
msvfw32.dll
muweb.dll
mycomput.dll
mydocs.dll
narrator.exe
ncpa.cpl
netcfgx.dll
netid.dll
netplwiz.dll
netsetup.cpl
netsetup.exe
netshell.dll
newdev.dll
notepad.exe
nslookup.exe
ntbackup.exe
ntkrnlmp.exe
ntkrnlpa.exe
ntkrpamp.exe
ntlanui2.dll
ntmsmgr.dll
ntoc.dll
ntoskrnl.exe
ntsd.exe
ntshrui.dll
nusrmgr.cpl
nwprovau.dll
objsel.dll
occache.dll
occache.dll.mui
oleprn.dll
oobebaln.exe
osk.exe
osuninst.dll
osuninst.exe
packager.exe
pautoenr.dll
perfmon.exe
photowiz.dll
powercfg.cpl
printui.dll
progman.exe
proquota.exe
psbase.dll
rasphone.exe
regedit.exe
regedt32.exe
regwizc.dll
remotepg.dll
remotesp.tsp
rsmui.exe
rsnotify.exe
rtcshare.exe
rundll32.exe
runonce.exe
scarddlg.dll
scrobj.dll
servdeps.dll
setup.exe
setupdll.dll
setupn.exe
sfc_os.dll
shdoclc.dll
shdocvw.dll
shimgvw.dll
shlwapi.dll
shrpubw.exe
shscrap.dll
sigverif.exe
smlogcfg.dll
sndvol32.exe
sport.dll
srchui.dll
srclient.dll
srrstr.dll
sti.dll
stimon.exe
stobject.dll
storprop.dll
strmdll.dll
sxs.dll
syncui.dll
sysdm.cpl
syskey.exe
sysocmgr.exe
syssetup.dll
tapisrv.dll
tapiui.dll
taskmgr.exe
telephon.cpl
telnet.exe
themeui.dll
timedate.cpl
unimdm.tsp
upnpui.dll
url.dll
urlmon.dll
usbui.dll
user32.dll
userenv.dll
utilman.exe
verifier.exe
webcheck.dll
wextract.exe
wgatray.exe
wiaacmgr.exe
wiadefui.dll
wiaservc.dll
wiashext.dll
winbrand.dll
wininet.dll
winlogon.exe
winmm.dll
winntbbu.dll
winsrv.dll
wintrust.dll
wmiscmgr.dll
wmplayer.exe
wmploc.dll
wmpsrcwp.dll
wordpad.exe
wpabaln.exe
wpdshext.dll
write.exe
wscript.exe
wscui.cpl
wsecedit.dll
wuapi.dll
wuaucpl.cpl
wuaueng1.dll
wucltui.dll
wupdmgr.exe
wuweb.dll
xpnetdiag.exe
xpsp1res.dll
xpsp2res.dll
xpsp3res.dll
zipfldr.dll
Вот изначальный скрипт(из пака Ultimate X Project)
читать дальше »
Код:
@Echo off
TITLE=ULTIMATE BLUE PROJECT
Color 0A
CD /D %~dp0
Echo Подготовка к работе скрипта...
Set KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx
Set KEY0=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce
Set KEY1=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\DriveIcons\%SYSTEMDRIVE:~0,-1%
Set comctl2=%WINDIR%\WinSxS\x86_Microsoft.Windows.Common-Controls_6595b64144ccf1df_6.0.0.0_x-ww_1382d70a\comctl32.dll
Set comctl3=%WINDIR%\WinSxS\x86_Microsoft.Windows.Common-Controls_6595b64144ccf1df_6.0.2600.5512_x-ww_35d4ce83\comctl32.dll
xCopy %1\* Resources /s /e /i /y >nul
xCopy theme\* %windir%\Resources\Themes /s /e /i /y >nul
theme.exe
If Not Exist Backup MD Backup
If Not Exist NewFiles MD NewFiles
If Not Exist Logs MD Logs
Echo Создание списка файлов для патча...
For /F "UseBackQ Delims=" %%I In (`Dir Resources /AD /B /ON 2^>nul`) Do Call :GetFullPatch %%~I
Echo Копирование файлов согласно списку в каталог Backup...
For /F "Delims=" %%I In (FileList.lst) Do Call :PrepareBackup "%%~I"
If Exist Resources\comctl2.dll Call :SpFileCopy "Backup\comctl2.dll" "%comctl2%" 1
If Exist Resources\comctl3.dll Call :SpFileCopy "Backup\comctl3.dll" "%comctl3%" 1
Color 0C
CLS
Echo Патчим ресурсы файлов...
For /F "UseBackQ Delims=" %%I In (`Dir Backup /B /ON 2^>nul`) Do (
Echo %%~I
reshacker.exe -script Resources\%%~I\rcscript.txt
)
Color 0A
CLS
Echo Считаем контрольную сумму...
For /F "UseBackQ Delims=" %%I In (`Dir NewFiles /B /ON 2^>nul`) Do modifype.exe NewFiles\%%~I -c >nul
Echo Создание списка файлов для отключения WFP...
For /F "UseBackQ Delims=" %%I In (`Dir NewFiles /B /ON 2^>nul`) Do Echo %%~I>> KillWpf.lst
Echo Патчим SfcFiles.dll этим списком...
Copy /Y %WINDIR%\system32\SfcFiles.dll >nul
SfcPatch.exe SfcFiles.dll KillWpf.lst >nul
Color 0F
WfpAdmin.exe /DeprotectAll >nul
Echo Изменяем иконку системного диска и копируем файлы в систему...
Reg Add "%KEY1%\DefaultIcon" /ve /d "%WINDIR%\system32\shell32.dll,41" /f >nul
Reg Add "%KEY1%\DefaultLabel" /ve /d "System" /f >nul
Copy /y SfcFiles.dll %WINDIR%\system32\dllcache\ >nul
Zap.exe %WINDIR%\system32\SfcFiles.dll >nul
Copy /y SfcFiles.dll %WINDIR%\system32\ >nul
TaskKill /f /im explorer.exe >nul
For /F "Delims=" %%I In (FileList.lst) Do Call :ReplaceFiles "%%~I"
Call :SpFileCopy "%comctl2%" "NewFiles\comctl2.dll" 2
Call :SpFileCopy "%comctl3%" "NewFiles\comctl3.dll" 2
If Exist "%USERPROFILE%\Local Settings\Application Data\IconCache.db" (
Del /F /Q /AH "%USERPROFILE%\Local Settings\Application Data\IconCache.db"
Reg Add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer /V "Max Cached Icons" /D 2000 /F >nul
)
Reg Add %KEY0% /V UBPClear1 /D "cmd.exe /C Del /F /Q %SystemDrive%\*.tmp" /f >nul
Reg Add %KEY0% /V UBPClear2 /D "cmd.exe /C RD /S /Q %WINDIR%\UBP" /f >nul
ping -n 3 127.0.0.1>nul
Start /b Shutdown -r -t 3 -c "Завершение работы патча и перезагрузка компьютера" -f
Exit
:GetFullPatch
If Not %1#==# (
For %%I In (
"%WINDIR%"
"%WINDIR%\pchealth\helpctr\binaries"
"%WINDIR%\system"
"%WINDIR%\system32"
"%WINDIR%\srchasst"
"%WINDIR%\system32\drivers"
"%WINDIR%\system32\Restore"
"%WINDIR%\system32\ru-ru"
"%WINDIR%\system32\Setup"
"%WINDIR%\system32\usmt"
"%WINDIR%\system32\wbem"
"%WINDIR%\Network Diagnostic"
"%COMMONPROGRAMFILES%\Microsoft Shared\MSInfo"
"%COMMONPROGRAMFILES%\Microsoft Shared\Speech"
"%COMMONPROGRAMFILES%\System"
"%COMMONPROGRAMFILES%\System\Mapi\1033"
"%COMMONPROGRAMFILES%\System\Ole DB"
"%PROGRAMFILES%\7-Zip"
"%PROGRAMFILES%\Internet Explorer"
"%PROGRAMFILES%\Internet Explorer\Connection Wizard"
"%PROGRAMFILES%\Movie Maker"
"%PROGRAMFILES%\NetMeeting"
"%PROGRAMFILES%\Outlook Express"
"%PROGRAMFILES%\Windows Media Player"
"%PROGRAMFILES%\Windows NT"
"%PROGRAMFILES%\Windows NT\Accessories"
"%PROGRAMFILES%\Windows NT\Pinball"
) Do If Exist "%%~I\%1" Echo "%%~I\%1">> FileList.lst
)
GoTo :EOF
:PrepareBackup
If Exist %1 (
VerCheck.exe Backup\%~nx1 %1
If ERRORLEVEL 255 (
Copy %1 Backup\ >nul
Echo %~1
)
) Else Echo %1>> NotFound.txt
GoTo :EOF
:ReplaceFiles
If Exist "NewFiles\%~nx1" (
Echo %~1
hidconAll.exe Repl_F.cmd %1 "NewFiles\%~nx1"
) Else Echo NewFiles\%~nx1>> NotCopy.txt
GoTo :EOF
:SpFileCopy
If Not %3==1 (
If Not Exist %2 GoTo :EOF
Echo %~1
Zap.exe %1 >nul
) Else Echo %~2
Copy /y %2 %1 >nul
If %3==1 GoTo :EOF
Echo %1>> zap.txt
GoTo :EOF
Я так понимаю: вся трабла в том, что расширения из директории не совпадают с запакованными cab' ами.
For /F "UseBackQ Delims=" %%I In (`Dir Resources /AD /B /ON 2^>nul`) Do Expand -r "%I386%\%%~I" "%WorkDir%\DTmp" >nul
Помогите пожалуйста. |
Как-то так:
Код:
@echo off
setlocal
for /f "tokens=*" %%i in (' dir /b /a D:\Work\Resources ') do call:expand "%%i"
goto:eof
:expand
set "file=%~1"
set "file=%file:~0,-1%_"
if exist "F:\I386\%file%" expand "F:\I386\%file%" "D:\Work\1\temp\%~1"
Я так понимаю, что файлы в i386 имеют расширения вида: .ex_ .dl_ и т.д. |
Foreigner спасибо
А можно узнать, какие файлы не были найдены.Т.е если в папке Resources есть файл 123.exe, а в папке i386 его нет, чтобы эти файлы записались в log.
|
Тогда просто исправить:
Код:
if exist "F:\I386\%file%" (expand "F:\I386\%file%" "D:\Work\1\temp\%~1") else (1>>error.log echo Not Found: %~1)
|
Время: 21:18.
© OSzone.net 2001-