Запущено слишком много задач-клиентов - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - Запущено слишком много задач-клиентов (http://forum.oszone.net/showthread.php?t=204258)

Запущено слишком много задач-клиентов

Добрый день.
В этой теме http://forum.oszone.net/thread-203670.html megaloman подсказал мне как в базе *.DBF по необходимым параметрам определить количество строк.
Я немного переделал код под свою ситуацию.
Вот что получилось:

Код:

Path = "h:\Работа\Документы\VBS\" 

REESTRO = "REESTRO.DBF"



Connect = "Driver={Microsoft dBase Driver (*.dbf)};DefaultDir=" + Path ' Подключение к базе *.DBF

        Set fso = CreateObject("Scripting.FileSystemObject")

        Set file = fso.OpenTextFile("C:\Взрослые.txt", 8, true) 'Создает файл и записывает в него отфильтрованную информацию

        Set RecSet1 = WScript.CreateObject("ADODB.Recordset")         'ID по которому будут сопоставляться данные

        Set RecSet2 = WScript.CreateObject("ADODB.Recordset")

        Set RecSet3 = WScript.CreateObject("ADODB.Recordset")

        Set RecSet101 = WScript.CreateObject("ADODB.Recordset") 

        Set RecSet102 = WScript.CreateObject("ADODB.Recordset")

        Set RecSet103 = WScript.CreateObject("ADODB.Recordset")

        

SQL = "Select COUNT(*) AS VrachChild From " +REESTRO+ " Where KATEG=3 and CODVR='0480004'" 'Параметры поиска для каждого врача отдельно

        RecSet1.Open SQL , Connect

        SQL = "Select COUNT(*) AS VrachChild From " +REESTRO+ " Where KATEG=1 and CODVR='0480004'" 'Параметры поиска для каждого врача отдельно

        RecSet101.Open SQL , Connect

        file.Write("Врач                 | Акушер-гинеколог = ")        'Задает имя строки для записи

        file.WriteLine(RecSet1.Fields("VrachChild")) + (RecSet101.Fields("VrachChild"))        'Записывает пересчитанные данные на против соответствующего врача и переводит каретку

        RecSet1.Close()

        RecSet101.Close()

        

        SQL = "Select COUNT(*) AS VrachChild From " +REESTRO+ " Where KATEG=3 and CODVR='0380004'"

        RecSet2.Open SQL , Connect

        SQL = "Select COUNT(*) AS VrachChild From " +REESTRO+ " Where KATEG=1 and CODVR='0380004'"

        RecSet102.Open SQL , Connect

        file.Write("Врач                 | Онколог = ")

        file.WriteLine(RecSet2.Fields("VrachChild")) + (RecSet102.Fields("VrachChild"))

        RecSet2.Close()

        RecSet102.Close()

        

        SQL = "Select COUNT(*) AS VrachChild From " +REESTRO+ " Where KATEG=3 and CODVR='0040039'"

        RecSet3.Open SQL , Connect

        SQL = "Select COUNT(*) AS VrachChild From " +REESTRO+ " Where KATEG=1 and CODVR='0040039'"

        RecSet103.Open SQL , Connect

        file.Write("Врач                | Участковый терапевт = ")

        file.WriteLine(RecSet3.Fields("VrachChild")) + (RecSet103.Fields("VrachChild"))

        RecSet3.Close()

        RecSet103.Close()

Так вот таких врачей у меня 70 человек.
После того как их всех забил в скрипт, во время выполнения выходит ошибка:
[Microsoft][Драйвер ODBC dBase] Запущено слишком много задач-клиентов.
Я думал что добавление RecSet*.Close() исправит задачу, но нет. Не получилось.
Подскажите пожалуйста где я ошибся.

Исходники и образец таблицы в приложенном архиве.

Не очень понял Вашу логику, вот попробуйте вариант, но на Ваших данных всё равно нулю, так как указанных значений CODVR в Вашей базе нет
Открывал ваш ДБФ Экселом, брал существующие значения - нечто выбирает. Извините, пути подставил свои.

Код:

Path = "D:\Delete\"

REESTRO = "REESTRO.DBF"



Set fso = CreateObject("Scripting.FileSystemObject")

Set file = fso.OpenTextFile("D:\Delete\Взрослые.txt", 8, True)         'Создает файл и записывает в него отфильтрованную информацию

Connect = "Driver={Microsoft dBase Driver (*.dbf)};DefaultDir=" + Path  ' Подключение к базе *.DBF



Set RecSet = CreateObject("ADODB.Recordset")                    'ID по которому будут сопоставляться данные

        

Sql = "Select COUNT(*) AS VrachChild From " + REESTRO + " Where CODVR='0480004' and (KATEG=3 or KATEG=1)"   'Параметры поиска для каждого врача отдельно

RecSet.Open Sql, Connect

    file.WriteLine "Врач        | Акушер-гинеколог = " + CStr(RecSet.Fields("VrachChild"))    'Задает имя строки для записи

RecSet.Close



Sql = "Select COUNT(*) AS VrachChild From " + REESTRO + " Where CODVR='0380004' and (KATEG=3 or KATEG=1)"   'Параметры поиска для каждого врача отдельно

RecSet.Open Sql, Connect

    file.WriteLine "Врач        | Онколог = " + CStr(RecSet.Fields("VrachChild"))     'Задает имя строки для записи

RecSet.Close



Sql = "Select COUNT(*) AS VrachChild From " + REESTRO + " Where CODVR='0040039' and (KATEG=3 or KATEG=1)"   'Параметры поиска для каждого врача отдельно

RecSet.Open Sql, Connect

    file.WriteLine "Врач        | Участковый терапевт = " + CStr(RecSet.Fields("VrachChild"))     'Задает имя строки для записи

RecSet.Close

    

file.Close

Посмотрел на Ваш скрипт в прикреплённом файле. По видимому, более читаемо сделать вот так:

Код:

Path = "D:\Delete\"

REESTRO = "REESTRO.DBF"



N = 3

ReDim mCode(N), mName(N)

i = 0

i = i + 1

mCode(i) = "'0480004'"

mName(i) = " Акушер-гинеколог = "

i = i + 1

mCode(i) = "'0380004'"

mName(i) = " Онколог = "

i = i + 1

mCode(i) = "'0040039'"

mName(i) = " Участковый терапевт = "



Set fso = CreateObject("Scripting.FileSystemObject")

Set file = fso.OpenTextFile("D:\Delete\Взрослые.txt", 8, True)         'Создает файл и записывает в него отфильтрованную информацию

Connect = "Driver={Microsoft dBase Driver (*.dbf)};DefaultDir=" + Path  ' Подключение к базе *.DBF



Set RecSet = CreateObject("ADODB.Recordset")                    'ID по которому будут сопоставляться данные

        

For i = 1 To N

    Sql = "Select COUNT(*) AS VrachChild From " + REESTRO + " Where CODVR=" + mCode(i) + " and (KATEG=3 or KATEG=1)" 'Параметры поиска для каждого врача отдельно

    RecSet.Open Sql, Connect

        file.WriteLine mName(i) + CStr(RecSet.Fields("VrachChild"))    'Задает имя строки для записи

    RecSet.Close

Next

        

file.Close

Не знаю, зачем Вам это нужно, но ИМХО лучше эту задачу решить в Excel.
В клетках, например, столбцах А и B забить соответствие Код-Врач, макросом прочитать последовательно эти значения и в столбце C выдаватьть ответы

Вот еще вариант

Код:

Public file, Connect, RecSet, REESTRO



Path = "D:\Delete\"

REESTRO = "REESTRO.DBF"



Set fso = CreateObject("Scripting.FileSystemObject")

Set file = fso.OpenTextFile("D:\Delete\Взрослые.txt", 8, True)         'Создает файл и записывает в него отфильтрованную информацию



Connect = "Driver={Microsoft dBase Driver (*.dbf)};DefaultDir=" + Path

Set RecSet = CreateObject("ADODB.Recordset")



dbfSelect "'0480004'", " Акушер-гинеколог = "

dbfSelect "'0380004'", " Онколог = "

dbfSelect "'0040039'", " Участковый терапевт = "

        

file.Close



Sub dbfSelect(mCode, mName)

    

    Sql = "Select COUNT(*) AS VrachChild From " + REESTRO + " Where CODVR=" + mCode + " and (KATEG=3 or KATEG=1)" 'Параметры поиска для каждого врача отдельно

    RecSet.Open Sql, Connect

        file.WriteLine mName + CStr(RecSet.Fields("VrachChild"))    'Задает имя строки для записи

    RecSet.Close



End Sub

Спасибо за совет.
А по поводу exel, то он отпадает потому, что собирать эту информацию буду не я, а операторы ЭВМ и желательно что бы на это дело у них уходило минимум действий)