Узнать ip, dns, netbios и скинуть в текстовик
Доброго времени суток. Помогите написать батник с запросами ("Узнать IP машины... Нажмите кнопку...", например), который узнаёт IP, DNS, NetBIOS машины и скидывает их в текстовый файл. Заранее спасибо
|
Код:
for /f "tokens=1-3 skip=1 delims={} " %%i in (
'"WMIC NICCONFIG Where IPEnabled=TRUE Get DNSHostName,DNSServerSearchOrder,IPAddress"') do (
echo NETBIOS: %%i
echo DNS IP: %%j
echo HOST IP: %%k
echo.
)>> file.txt
|
amel27, если прописаны основной и альтернативный DNS, то в "HOST IP" будет как раз альтернативный, вместо IP данного компьютера.
|
Anonymоus, справедливое замечание, не хотелось громоздить без нужды: ;)
Код:
@echo off
SETLOCAL EnableDelayedExpansion
for /f "tokens=* skip=1" %%i in (
'"WMIC NICCONFIG Where IPEnabled=TRUE Get DNSHostName,DNSServerSearchOrder,IPAddress|FindStr ."
') do set "$i=%%i"& set "$i=!$i: =!"& set $i=!$i:"=!
for /f "tokens=1-3 delims={}" %%a in ("%$i%") do (
echo NETBIOS: %%a
echo DNS IP: %%b
echo HOST IP: %%c
echo.
)>> file.txt
ADD: то же, но без использования отложенной подстановки:
Код:
for /f "tokens=* skip=1" %%i in ('"WMIC NICCONFIG Where IPEnabled=TRUE Get DNSHostName,DNSServerSearchOrder,IPAddress|FindStr ."') do set "$i=%%i"
set $i=%$i:"=%
set $i=%$i: =%
for /f "tokens=1-3 delims={}" %%a in ("%$i%") do (
echo NETBIOS: %%a
echo DNS IP: %%b
echo HOST IP: %%c
echo.
)>>file.txt
|
Время: 01:38.
© OSzone.net 2001-
