Переименование группы файлов по дате создания

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

Переименование группы файлов по дате создания

Добрый день!

Подскажите, как в некоторой папке, по какой-либо маске (к примеру *.arj) переименовать все файлы удовлетворяющие маске добавив впереди дату создания до секунд.
например было Dat_day1.arj, а будет, например, 2012-04-09-23-44-25_Dat_day1.arj, где сначала идет год, месяц, день и т.д. Как переименовать отдельный файл знаю, а вот обойти все в цикле затрудняюсь. Необходимо сделать все проверки на наличие папки, файлов и т.д. что там по уму нужно.

Пробовал найденное на форуме, но почему то не срабатывает, пишет не найден файл
Спасибо.

Serg2010, WSH устроит?

Первым аргументом указываете путь, вторым — расширение.

Добрый вечер!

Да надо именно в cmd. Так как другие какие либо скрипты и программы запрещены отделом защиты информации.

:-(

Serg2010, а Вы проверьте.

Цитата:

Цитата Serg2010

Да надо именно в cmd »

Serg2010, на CMD только до минут, без секунд.

Код:

@Echo Off

SetLocal

If "%~1"=="" Echo:Параметры не заданы.&Exit /B 1

If "%~2"=="" Echo:Не задан второй параметр.&Exit /B 1

If Not Exist "%~1" Echo:Папка %~1 не найдена.&Exit /B 1



For /F "Tokens=1-6* Delims=.: " %%A In ('Dir /A-D /TC /-C "%~1\*.%~2"^|FindStr /i .%~2$') Do Ren "%~1\%%G" "%%C-%%B-%%A-%%D-%%E_%%G"

Пример вызова: script.bat "C:\Source" "arj"

Цитата:

Цитата Serg2010

Так как другие какие либо скрипты и программы запрещены отделом защиты информации. »

Чем мотивируют-то?

Цитата:

Цитата El Sanchez

Чем мотивируют-то? »

«Низзяяяя!» ;)

Цитата:

Цитата El Sanchez

…только до минут, без секунд. »

Можно по пути брать из Wbem:

Код:

wmic.exe DataFile where "Name = 'c:\\boot.ini'" get CreationDate /value

Iska, спасибо, что напомнили, получилось вот что:

Код:

@Echo Off

SetLocal

If "%~1"=="" Echo:Параметры не заданы.&Exit /B 1

If "%~2"=="" Echo:Не задан второй параметр.&Exit /B 1

If Not Exist "%~1" Echo:Папка %~1 не найдена.&Exit /B 1



Set Source=%~pn1

:Loop

If Not "%Source%"=="" If "%Source:~-1%"=="\" Set Source=%Source:~0,-1%& GoTo :Loop

For /F "Tokens=2* Delims=," %%A In ('WMIC DataFile Where ^"Drive^=^'%~d1^' And Path^=^'%%Source:\^=\\%%\\^' And Extension^=^'%~2^'^" Get Name^,CreationDate /Format:CSV 2^>nul^|FindStr /i .%~2$') Do (

        Set dF=%%A

        Call Ren "%%B" "%%dF:~0,4%%-%%dF:~4,2%%-%%dF:~6,2%%-%%dF:~8,2%%-%%dF:~10,2%%-%%dF:~12,2%%_%%~nxB"

)

спасибо.... секунды в принципе и не важны .... ну что так всё сложно то а :-)

Serg2010, если секунды не важны, то это проще.