CMD/BAT - Поиск и переименование файлов с помощью BATника

ovrtke · Отправлено: **10:52, 01-09-2021** | #11

Цитата DJ Mogarych:

ОК, а как вы поймёте, кто изменял? »

Это не нужно знать кто, щас попытаюсь обьяснить

Есть общая папка, в которой работают 3-4 человека, в день открывается/добавляется/изменяется от 30-50 файлов, и сохранять ручками с текущей датой все то что ты открыл/изменил/сохранил не хочется, просто нужно запустить батник, он все изменит (все что ты сохранил/изменил/добавил) на текущую дату и все. В этой общей папке видно кто под каким паролем их сохранял/изменял, нам по большому счету не нужно, нужно лишь изменять на текущую дату изменения и все

мне осталось допилить что бы, если файл имеет имя уже с текущей датой, либо старой, и заново не прописывалась дата, а удалялась старая и ставилась новая, и побольшому счету проблема решена

DJ Mogarych · Конфигурация компьютера

Всё равно непонятно, зачем переименовывать. Если нужно просто получать отчёт об изменённых файлах за сегодня в целях мониторинга, ничего переименовывать не требуется.

ovrtke · Отправлено: **11:07, 01-09-2021** | #13

Цитата DJ Mogarych:

Всё равно непонятно, зачем переименовывать. »

ну вот нужно) такая цель...и нужно побольшому счету просто добавить 2 строчки в код, что то пробую пробую но видимо не хватает знаний в cmd...((

megaloman · Отправлено: **11:13, 01-09-2021** | #14

ovrtke,

Цитата ovrtke:

Такой вот error, и не нашел где прописать путь сканирования файлов ? »

Я считал, что это очевидно. У меня

Код:

Set "BoxIn=Z:\Box_In"

Вы напИшите свой путь. Единственное, если в пути кириллица, сохраните батник в 866 кодировке.
Я делаю тупо и дубОво: я анализирую сегодняшнюю дату (%Date%) c датой/временем модификации файла из Dir (%%~tf), усеченной до даты. Выделяю имя файла: если оно без даты "ггммдд " впереди, то беру его как есть "имябездаты", а если впереди дата, её из имени отбрасываю, получаю "имябездаты"и переименовываю файл с исходным именем в "ггммдд имябездаты" и не завихряюсь.

megaloman · Отправлено: **11:36, 01-09-2021** | #15

Вот вариант, менее чувствительный к формату отображения даты в системе. По крайней мере ггммдд здесь берётся без зависимости от него.

Код:

@Echo Off
cls
	Set "BoxIn=Z:\Box_In"
	Set "Mask=*.xlsx"
	Set "DateMask=^[2-9][0-9][0-1][0-9][0-3][0-9] .*"

	FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "MyDate=%%d" &Call Set "MyDate=%%MyDate:~2,6%% "

	Pushd "%BoxIn%" ||(Echo Filder "%BoxIn%" not found &Pause &Exit /B 1) 

	For /F "usebackq delims=" %%f In (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:-D /O:-D /T:W`) Do (
		For /F "delims= " %%d In ("%%~tf") Do (
			If "%Date%"=="%%d" (
				Set "Name=%%f"
				Call Echo %%Name%%| >nul 2>&1 FindStr /I /X /R /C:"%DateMask%" &&Call Set "Name=%%Name:~7%%"
				Call ReName "%%f" "%MyDate%%%Name%%"
				
			) Else (
				GoTo :Continue
			)
		) 
	)
	:Continue
	Popd
pause
Exit /B 0

ovrtke · Отправлено: **11:37, 01-09-2021** | #16

Цитата megaloman:

megaloman »

Заработало, спасибо, попытаюсь доработать,а мой код который выше реально дописать ?

megaloman · Отправлено: **11:40, 01-09-2021** | #17

Цитата ovrtke:

,а мой код который выше реально дописать »

Я писатель, а не читатель

, возможно кому-то захочется.

ovrtke · Отправлено: **11:44, 01-09-2021** | #18

thx to cooperate )

а реально еще вывести в окно cmd кол-во измененных файлов ?

ovrtke · Отправлено: **12:08, 01-09-2021** | #19

Еще проблемка, пересохранил в 866 кодировке, все равно не хочет. Путь такой:
"c:\Users\borisov.a\Documents\Bitrix24\КМ НЗЧ\210831 ЕВРОПА\210830 Заказы УКРАИНА\"

ovrtke · Отправлено: **12:09, 01-09-2021** | #20

папка Bitrix24 - это диск с битрикса