[Iska]

truvo, назначьте такой макрос:

Скрытый текст

Код:

Option Explicit

Sub Sample()
    Dim strLetters As String
    Dim i As Integer
    
    Dim objPrevSelection As Range
    
    
    strLetters = ""
    
    For i = Asc("a") To Asc("z")
        strLetters = strLetters & Chr(i)
    Next i
    
    For i = Asc("A") To Asc("Z")
        strLetters = strLetters & Chr(i)
    Next i
    
    For i = Asc("а") To Asc("я")
        strLetters = strLetters & Chr(i)
    Next i
    
    For i = Asc("А") To Asc("Я")
        strLetters = strLetters & Chr(i)
    Next i
    
    strLetters = strLetters & "ё"
    strLetters = strLetters & "Ё"
    
    
    With Selection
        Set objPrevSelection = .Range
        
        .MoveStartWhile Cset:=strLetters, Count:=wdBackward
        .InsertBefore Text:="«"
        
        .MoveEndWhile Cset:=strLetters, Count:=wdForward
        .InsertAfter Text:="»"
        
        .SetRange objPrevSelection.Start, objPrevSelection.End
        
        Set objPrevSelection = Nothing
    End With
End Sub

на какую-либо горячую клавишу. Прокручиваете документ до нужного места, щёлкаете мышкой на потребном слове, нажимаете горячую клавишу.