Скрипты Inno Setup. Помощь и советы [часть 3]

Habetdin · Отправлено: **18:43, 23-11-2010** | #51

Devils0411, тогда так:

Код:

#define Const1 "5"
#define Const2 "8"

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Types]
Name: "Const1"; Description: "{#Const1} -> data.ini";
Name: "Const2"; Description: "{#Const2} -> data.ini";

[Components]
Name: "Const1"; Description: "{#Const1} -> data.ini"; Types: "Const1";
Name: "Const2"; Description: "{#Const2} -> data.ini"; Types: "Const2";

[Ini]
filename: {app}\Data.ini; section: Settings; key: Chislo; string: {#Const1}; Components: Const1;
filename: {app}\Data.ini; section: Settings; key: Chislo; string: {#Const2}; Components: Const2;

[Languages]
Name: rus; MessagesFile: compiler:Languages\Russian.isl

vint56 · Отправлено: **09:22, 24-11-2010** | #52

Помогите пожалуйста как вот это сделать только через код
@echo off
set SRC="L:\Call of Duty- Black Ops_disk1.sim"
set DST="c:\Games\Call of Duty: Black Ops"
SimPack.exe x %SRC% %DST% -g42700 -kD9AD91A8DB3258C4C8210D505DCB0F70 -n1
SimPack.exe x %SRC% %DST% -g42701 -kBAD1EC97BB5FB39A08D70AEDAB239DDC -n1
SimPack.exe x %SRC% %DST% -g42702 -kAC17FBAE013EB5D5A549EBF9907C78A5 -n1
SimPack.exe x %SRC% %DST% -g42709 -kD9AD91A8DB3258C4C8210D505DCB0F70 -n1
pause

Habetdin · Отправлено: **19:07, 24-11-2010** | #53

vint56, если {app}=c:\Games\Call of Duty: Black Ops и файлы Call of Duty- Black Ops_disk1.sim, SimPack.exe расположены рядом с инсталлятором, то:

Код:

#define SRCFILE '{src}\Call of Duty- Black Ops_disk1.sim'

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Run]
Filename: "{src}\SimPack.exe"; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42700 -kD9AD91A8DB3258C4C8210D505DCB0F70 -n1"; WorkingDir: {src}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard;
Filename: "{src}\SimPack.exe"; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42701 -kBAD1EC97BB5FB39A08D70AEDAB239DDC -n1"; WorkingDir: {src}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard;
Filename: "{src}\SimPack.exe"; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42702 -kAC17FBAE013EB5D5A549EBF9907C78A5 -n1"; WorkingDir: {src}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard;
Filename: "{src}\SimPack.exe"; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42709 -kD9AD91A8DB3258C4C8210D505DCB0F70 -n1"; WorkingDir: {src}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard;

[Languages]
Name: rus; MessagesFile: compiler:Languages\Russian.isl

vint56 · Отправлено: **20:10, 24-11-2010** | #54

Habetdin,Большое тебе спасибо за помошь и еще один вопрос а как можно сделать чтобы он искал файл на dvd приваде
#define SRCFILE '{drive:{src}}\Call of Duty- Black Ops_disk1.sim' что не работает

Habetdin · Отправлено: **22:07, 24-11-2010** | #55

vint56, только что проверил, работает:

Код:

#define SRCFILE '{drive:{src}}\Call of Duty- Black Ops_disk1.sim'

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Code]
function InitializeSetup(): Boolean;
begin
  MsgBox(ExpandConstant('{#SRCFILE}'), mbInformation, MB_OK);
end;

Если инсталлятор расположен в корне диска, то использовать {drive:...} не обязательно

vint56 · Отправлено: **22:51, 24-11-2010** | #56

Habetdin, если просто делать с {src} то работает если файлы лежат возле setup.exe а мне хотелось как не будь сделать ставил образ в DAEMON Tools чтобы распаковка шла с диска а не копировать файлы на жёсткий диск
#define SRCFILE '{drive:{src}}\Call of Duty- Black Ops_disk1.sim'

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Run]
Filename: {tmp}\SimPack.exe; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42700 -kD9AD91A8DB3258C4C8210D505DCB0F70 -n1"; WorkingDir: {drive:{src}}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard
Filename: {tmp}\SimPack.exe; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42701 -kBAD1EC97BB5FB39A08D70AEDAB239DDC -n1"; WorkingDir: {drive:{src}}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard
Filename: {tmp}\SimPack.exe; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42702 -kAC17FBAE013EB5D5A549EBF9907C78A5 -n1"; WorkingDir: {drive:{src}}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard
Filename: {tmp}\SimPack.exe; Parameters: "x ""{#SRCFILE}"" ""{app}"" -g42709 -kD9AD91A8DB3258C4C8210D505DCB0F70 -n1"; WorkingDir: {drive:{src}}; StatusMsg: Распаковка файлов...; Flags: waituntilterminated HideWizard

[Languages]
Name: rus; MessagesFile: compiler:Languages\Russian.isl
[Files]
Source: SimPack.exe; DestDir: {tmp}
Source: GcfFiles.dat; DestDir: {tmp}

Habetdin · Отправлено: **00:07, 25-11-2010** | #57

vint56,

Цитата vint56:

чтобы распаковка шла с диска а не копировать файлы на жёсткий диск »

Где вы увидели копирование? В приведенных выше примерах и инсталлятор, и SimPack.exe, и Call of Duty- Black Ops_disk1.sim будут на CD/DVD/там, где вы расположите
А вот

Цитата vint56:

{tmp} »

...это как раз с копированием на жесткий диск во временную папку

Попробуйте скомпилить скрипт из моего предыдущего поста и запустить его с C:\, D:\ итд, посмотреть что он показывает в начале..

shao · Отправлено: **17:12, 25-11-2010** | #58

Может кто знает - почему после редактирования в Рестораторе версии инсталлятора , созданного в Инно,
при попытке запуска получается вот такая вот ситуация :

Habetdin · Отправлено: **19:23, 25-11-2010** | #59

shao, потому что проверяется CRC

Используйте VersionInfoVersion
По умолчанию VersionInfoVersion=0.0.0.0

necromanster · Отправлено: **12:24, 26-11-2010** | #60

Здравствуйте господа.

Подскажите пожалуйста, как в этом скрипте, сделать так, чтобы рисунок на первой странице был на весь инсталятор, а в конце установки (на последней странице инсталятора) можно было поставить обычный ресунок (который с боку). И еще. Подскажите пожалуйста, где здесь менять цвет текста в инсталяторе.

Заранее спасибо.

Код:

[\code\]
var
  MyPanel: TPanel;

procedure InitializeWizard();
begin
  MyPanel := TPanel.Create(WizardForm);
  with MyPanel do
  begin
    Align := alClient;
    Parent := WizardForm;
  end;

  with WizardForm.WizardBitmapImage do
  begin
    Align := alClient;
    Parent := MyPanel;
  end;

  with TLabel.Create(WizardForm) do 
  begin 
    AutoSize := WizardForm.WelcomeLabel1.AutoSize; 
    WordWrap := WizardForm.WelcomeLabel1.WordWrap; 
    Left := WizardForm.WelcomeLabel1.Left; 
    Top := WizardForm.WelcomeLabel1.Top; 
    Width := WizardForm.WelcomeLabel1.Width; 
    Height := WizardForm.WelcomeLabel1.Height; 
    Caption := WizardForm.WelcomeLabel1.Caption; 
    Font.Size := WizardForm.WelcomeLabel1.Font.Size; 
    Font.Style := WizardForm.WelcomeLabel1.Font.Style; 
    Font.Color := clWhite; 
    TransParent := True; 
    Parent := MyPanel;
  end; 
 
  with TLabel.Create(WizardForm) do 
  begin 
    AutoSize := WizardForm.WelcomeLabel2.AutoSize; 
    WordWrap := WizardForm.WelcomeLabel2.WordWrap; 
    Left := WizardForm.WelcomeLabel2.Left; 
    Top := WizardForm.WelcomeLabel2.Top; 
    Width := WizardForm.WelcomeLabel2.Width; 
    Height := WizardForm.WelcomeLabel2.Height; 
    Caption := WizardForm.WelcomeLabel2.Caption; 
    Font.Size := WizardForm.WelcomeLabel2.Font.Size; 
    Font.Style := WizardForm.WelcomeLabel2.Font.Style; 
    Font.Color := clWhite; 
    TransParent := True; 
    Parent := MyPanel;
  end;

  WizardForm.NextButton.BringToFront;
  WizardForm.CancelButton.BringToFront;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  MyPanel.Hide;
  if CurPageID = wpWelcome then
    MyPanel.Show;
end;