|
|
|
|
| Компьютерный форум OSzone.net » Программирование, базы данных и автоматизация действий » Программирование и базы данных » Разное - [решено] Помогите подобрать кодировку |
|
|
Разное - [решено] Помогите подобрать кодировку
|
Новый участник Сообщения: 49 |
Здравствуйте. Подскажите пожалуйста чем лучше подобрать кодировку к файлу.
Файл - программа на бейсике, писалась давненько, еще в 89 году, я догадываюсь что кодировка ОЕМ 866 но все еще остаются непонятные символы. Если что файл здесь. Заранее благодарен за помощь. |
|
|
Отправлено: 19:25, 22-04-2011 |
|
Ветеран Сообщения: 27449
|
Профиль | Отправить PM | Цитировать Demolution, это так называемый двоичный формат хранения файлов *.bas. Применялся в BASICA, GW-BASIC и некоторых других вариантах приложений BASIC'а во времена, когда размер файлов был критичен (подобный формат занимал меньше места). Чтобы получить чистый текст, нужно загрузить файл в соответствующем приложении командой:
Код:
 LOAD "LR2.BAS" Код:
SAVE "LR2TXT.BAS", A Цитата SAVE Command:
Код:
100 REM ЛАБОРАТОРНАЯ РАБОТА #2 ( LR2.BAS )
120 REM МОДЕЛИРОВАНИЕ ВОЗДЕЙСТВИЯ ИСКАЖЕНИЙ ФЧХ
140 REM СОСТАВИТЕЛИ: НУДЕЛЬМАН П.Я.,ФОМИНА Г.Т.
150 REM
160 ' Исходные данные
170 REM N1 - количество отсчетов импульсных реакций.
180 REM N1 - количество отсчетов АЧХ.
190 REM H1(i) - значения отсчетов импульсной реакции канала #1.
200 REM R1(i) - значения отсчетов импульсной реакции
210 REM Преобразователя Гильберта.
220 REM W(i) - Значения отсчетов АЧХ каналов #1 и #2.
230 DEF FNLOG10(X)=LOG(X)/LOG(10)
232 KEY OFF:COLOR 14,6,9:OUT 989,3:WIDTH 80:SCREEN 0,0,0
235 OPEN "LR2.DAT" FOR OUTPUT AS #1
240 DIM R(50),R1(50),R2(50),G(100),X(50),H(50),H1(50),H2(50),H3(50),H4(50)
245 DIM G1(100),D(50),R3(50),W(50),F(50)
250 N1=21 : N2=51:COLOR 14,1
260 REM ------------------- W(I) ----------------------------------
270 DATA 1.0018,1.00146,1.00057,.999473,.998596,.998266,.998585,.99939,1.00033
280 DATA 1.00103,1.00127,1.0011,1.00084,1.00087,1.00133,1.022,1.00068,.995681
290 DATA .9834,.98008,.922256,.86754,.795318,.707167,.606869,.5,.39313,.292833
300 DATA .204681,.132459,.0777435,.0399192,.0165994,4.31807E-03,6.80218E-04
310 DATA 1.74021E-03,1.32886E-03,8.65701E-04,8.36424E-04,1.10091E-03,1.271E-03
320 DATA 1.03298E-03,3.32715E-04,6.09218E-04,1.41482E-03,1.73358E-03
330 DATA 1.40348E-03,5.26462E-04,5.69771E-04,1.46256E-03,1.8047E-03
340 REM --------------------- H1(I) ----------------------------------
350 DATA -3.33786E-07,.0353678,3.57628E-07,-.0454728,-3.57628E-07,.063662
360 DATA 3.57628E-07,-.106103,-3.57628E-07,.31831,.5,.31831,-3.57628E-07
370 DATA -.106103,3.57628E-07,.063662,-3.57628E-07,-.0454728,3.57628E-07
380 DATA .0353678,-3.33786E-07
390 Y5=24 : X5=30:GOTO 490
400 REM ------- SUB < УСТАНОВКА > --------------
410 CLS
420 LOCATE 8,12
430 RETURN
440 REM ------- SUB <Нажмите любую клавишу > -----------
450 LOCATE Y5,X5
460 PRINT "<Нажмите любую клавишу >";:A$=INPUT$(1) : IF A$="Y" OR A$="y" THEN 4000
462 IF A$=CHR$(27) THEN CLOSE:CLS:SCREEN 0,0,0:END
464 IF A$=CHR$(13) THEN PLAY "mll64dad"
470 IF A$="S" OR A$="s" THEN 490
475 COLOR 14,9,9
480 RETURN
490 FOR I=0 TO N2-1 : READ W(I) : NEXT I
500 FOR I=0 TO N1-1 : READ H(I) : NEXT I
510 GOSUB 400
520 COLOR 2,9,9:PRINT TAB(24);"ЛАБОРАТОРНАЯ РАБОТА #2" : PRINT
530 PRINT TAB(16);"МОДЕЛИРОВАНИЕ ВОЗДЕЙСТВИЯ ИСКАЖЕНИЙ ФЧХ " : PRINT:COLOR 6
540 PRINT : PRINT TAB(25);" В Н И М А Н И Е ! " : PRINT:COLOR 5
550 PRINT TAB(20);"ПРИ ВЫПОЛНЕНИИ ЛАБОРАТОРНОЙ РАБОТЫ" : PRINT
560 PRINT TAB(14);"1.РУКОВОДСТВУЙТЕСЬ УКАЗАНИЯМИ, НА ЭКРАНЕ ДИСПЛЕЯ." : PRINT
570 GOSUB 450 : CLS : PRINT : PRINT : PRINT
580 PRINT TAB(10);"2.ВВОД ДАННЫХ И НАЖАТИЕ КЛАВИШИ <ВК> ПРОИЗВОДИТЕ"
585 PRINT TAB(10);" ТОЛЬКО ПОСЛЕ ПОЯВЛЕНИЯ ЗНАКА <?>": PRINT:COLOR 14,9,9
590 GOSUB 450 : REM <НАЖМИТЕ <ВК>> : IF A$="R" or A$="a" Then 530
600 GOSUB 400 : REM <УСТАНОВКА>
610 PRINT "РЕЖИМ РАБОТЫ:" : PRINT : PRINT
620 PRINT TAB(10);"-ПОСЛЕДОВАТЕЛЬНОЕ ВЫПОЛНЕНИЕ ПУНКТОВ 1.5.1-1.5.6"
630 PRINT TAB(10);" ЛАБОРАТОРНОГО ЗАДАНИЯ (НАЖАТЬ КЛАВИШУ <ВК>)" : PRINT
640 PRINT TAB(10);"-ВЫПОЛНЕНИЕ ПУНКТА 1.5.6 (ВВЕДЕНИЕ ОТСЧЕТОВ СИГНАЛА"
650 PRINT TAB(10);" ПРОИЗВОЛЬНОЙ ФОРМЫ)(НАЖАТЬ КЛАВИШУ <G>)" : PRINT
660 PRINT TAB(10);"-ВОЗВРАТ К ПРЕДЫДУЩЕМУ ПУНКТУ ЗАДАНИЯ"
670 PRINT TAB(10);" (НАЖАТЬ КЛАВИШУ <R>)" : PRINT
680 PRINT TAB(10);"-ВОЗВРАТ К НАЧАЛУ ЛАБОРАТОРНОЙ РАБОТЫ"
690 PRINT TAB(10);" (НАЖАТЬ КЛАВИШУ <S>)" : PRINT
700 PRINT TAB(10);"-АВАРИЙНОЕ ЗАВЕРШЕНИЕ ЛАБОРАТОРНОЙ РАБОТЫ"
702 PRINT TAB(10);" (НАЖАТЬ КЛАВИШИ <Y>)": PRINT : PRINT
703 PRINT TAB(10);"ВЫБРАВ РЕЖИМ, НАЖМИТЕ НУЖНЫЕ КЛАВИШИ" : PRINT
704 GOSUB 450 : IF A$="S" THEN 240
705 IF A$="Y" OR A$="y" THEN 4000
706 IF A$="G" OR A$="g" THEN 3420
707 IF A$="R" OR A$="r" THEN 510
710 GOSUB 400 : REM <УСТАНОВКА> '---------------->>>>>>
720 PRINT"Выведите на экран и зарисуйте график фазо-частотной "
730 PRINT TAB(18);"характеристики канала #1,":PRINT:L2=1
740 PRINT TAB(10);"Отметьте, является ли эта характеристика искажающей ;"
750 GOSUB 450:IF A$="r" OR A$="R" GOTO 600
760 FOR I=0 TO 4:F(I)=I*1.8:NEXT
770 FOR I=5 TO 8 :F(I)=I*1.8:NEXT:K=20 'было I*1.8+0.8 02.04.90
780 GOSUB 3470:GOSUB 450:IF A$="r" OR A$="R" GOTO 600
790 GOSUB 400
800 PRINT"Выведите на экран и зарисуйте график частотной характеристики"
810 PRINT TAB(10);"Затухания канала #1 ( ЧХЗ )":PRINT:PRINT
830 PRINT TAB(11);"Измерьте и запишите величину затухания на частотах :"
840 PRINT TAB(12);"100, 200, 300, 400, 500 ГЦ."
860 GOSUB 450 :IF A$="r" OR A$="R" GOTO 600
870 FOR I=0 TO N2-1:W(I)=20*FNLOG10(W(I)):W(I)=ABS(W(I))/5:NEXT
880 GOSUB 3230:GOSUB 450 :IF A$="r" OR A$="R" GOTO 710
890 GOSUB 400
900 PRINT"Выведите на экран значения отсчетов импульсной"
910 PRINT TAB(10);"Реакции канала #1":PRINT
920 PRINT TAB(10);"Измерьте величину главного отсчетного значения"
930 PRINT TAB(10);"Импульсной реакции (отсчет с номером 10)":PRINT
940 PRINT TAB(10);"(отсчеты импульсной реакции следуют через "
950 PRINT TAB(10);" Интервал времени 1мС )":PRINT
960 GOSUB 450 :IF A$="r" OR A$="R" GOTO 790
970 K=10:FOR I=0 TO N1-1:G1(I)=H(I)*K:NEXT
980 GOSUB 400
985 PRINT #1,"Отсчеты импульсной реакции канала #1"
990 PRINT TAB(10);"Отсчеты импульсной реакции канала #1 h(t):":PRINT
1000 FOR I=0 TO N1-1 STEP 2
1005 PRINT #1,"H(";I;")=";H(I),"h(";I+1;")=";H(I+1)
1010 PRINT TAB(10);"h(";I+1;")= ";:PRINT USING "##.###";H(I+1);
1020 PRINT TAB(50);"h(";I;")= ";:PRINT USING "##.###";H(I)
1030 NEXT:L=1:PRINT
1040 PRINT TAB(10);"Выведите на экран график импульсной реакции канала #1"
1050 GOSUB 450 :IF A$="r" OR A$="R" GOTO 890
1060 R$="h(t) Импульсная реакция канала #1 "
1070 GOSUB 2440
1080 PRINT "Используя табличные значения,"
1090 PRINT " отметьте величину главного отсчетного значения имп. реакции"
1100 GOSUB 450 :IF A$="r" OR A$="R" GOTO 890:
1105 N1=0
1110 L=2: GOSUB 2870 :
1120 GOSUB 400:N1=21
1130 PRINT "Выведите на экран значения отсчетов выходного сигнала канала #1 "
1150 PRINT :PRINT TAB(10);"(отсчеты следуют через интервал времени 1 мС),";
1160 PRINT " Запишите их"
1170 GOSUB 450
1180 GOSUB 400
1185 PRINT #1,"Отсчеты выходного сигнала канала #1"
1190 PRINT "Отсчеты выходного сигнала y(t):"
1200 GOSUB 3080
1210 PRINT TAB(10);"Выведите на экран график выходного сигнала канала #1 "
1220 GOSUB 450 :IF A$="r" OR A$="R" GOTO 890
1230 R$="h(t) Отсчеты выходного сигнала канала #1 "
1240 FOR I=0 TO N1+M-1:G1(I)=D(I)*K:NEXT
1250 GOSUB 2440
1260 PRINT TAB(15);"Оцените форму импульса после прохождения его"
1270 PRINT TAB(21);" через канал #1 "
1280 GOSUB 450
1290 IF A$="r" OR A$="R" GOTO 1130
1292 IF A$="r" OR A$="R" THEN GOSUB 400
1300 CLS : PRINT:PRINT:PRINT " Переходите к исследования канала #2 "
1310 FOR I=0 TO 5 :PRINT:NEXT:L2=2
1320 PRINT " Введите значение фазы (в градусах), B=";:INPUT B
1330 PRINT:PRINT:PRINT #1,"B=";B
1340 PRINT TAB(10);"Выведите на экран фазо-частотную х-ку канала #2 "
1350 PRINT TAB(10);"(Зарисуйте ее в протоколе лаб. работы)"
1360 PRINT:PRINT TAB(10);"Отметьте, является ли она искажающей"
1370 GOSUB 450 :IF A$="r" OR A$="R" GOTO 1130
1380 IF B>40 GOTO 1400
1390 K=5:GOTO 1430
1400 IF B>40 GOTO 1420
1410 K=15:GOTO 1430
1420 K=30
1430 FOR I=0 TO 5 :F(I)=-B/K:F(I+5)=B/K:NEXT
1440 GOSUB 3710:GOSUB 450 :IF A$="r" OR A$="R" GOTO 1130
1450 GOSUB 400
1460 PRINT"Выведите на экран значения отсчетов импульсной "
1470 PRINT TAB(10);"Реакции канала #2"
1480 PRINT TAB(10);"(Отсчеты импульсной реакции следуют"
1490 PRINT TAB(10);"через интервалы времени 1 мС)":PRINT
1500 PRINT TAB(10);"Запишите их и постройте график импульсной "
1510 PRINT TAB(10);"Реакции канала #2"
1520 GOSUB 450 :IF A$="r" OR A$="R" GOTO 1300
1530 GOSUB 2280
1540 GOSUB 400
1550 PRINT " Отсчеты импульсной реакции канала #2":PRINT
1560 A1=B/180*3.1415926535#
1570 C1=COS(A1):S1=SIN(A1)
1580 FOR I=0 TO N1-1
1590 H1(I)=H(I)*C1:H2(I)=R1(I)*S1:H3(I)=H1(I)+H2(I)
1600 NEXT I
1605 PRINT #1," Отсчеты импульсной реакции канала #2"
1610 FOR I=0 TO N1-1 STEP 2
1615 PRINT #1,"H(";I;")=";H3(I),"h(";I+1;")=";H3(I+1)
1620 PRINT TAB(10);"h(";I+1;")= ";:PRINT USING "##.###";H3(I+1);
1630 PRINT TAB(50);"h(";I;")= ";:PRINT USING "##.###";H3(I)
1635 NEXT:PRINT
1640 PRINT TAB(10);"Запишите значения отсчетов импульсной реакции канала #2"
1650 GOSUB 450
1660 R$="h(t) Импульсная реакция канала #2 "
1670 K=16:L=1:FOR I=0 TO 50:G1(I)=0:NEXT
1680 FOR I1=0 TO N1-1 :G1(I1)=H3(I1)*K:NEXT I1
1690 FOR I2=0 TO N1-1 :H(I2)=H3(I2):NEXT I2
1700 GOSUB 400
1710 PRINT "Определите величину главного отсчетного значения"
1720 PRINT TAB(10);"импульсной реакции канала #2"
1730 PRINT TAB(10);"(Отсчет с номером 10),":PRINT
1740 PRINT TAB(10);"Сравните его с главным отсчетным значением"
1750 PRINT TAB(10);"импульсной реакции канала #1"
1760 PRINT TAB(10);"По записанным данным постройте график "
1770 PRINT TAB(10);"импульсной реакции канала #2"
1790 GOSUB 450 :IF A$="r" OR A$="R" GOTO 1540
1795 GOSUB 400
1800 GOSUB 2440:PRINT TAB(25);"B=";B;"град."
1810 PRINT TAB(15);"Сравните табличные значения в нескольких точках"
1820 PRINT TAB(15);"со значениями соотв. отсчетов на графике"
1830 GOSUB 450
1840 IF A$="r" OR A$="R" GOTO 1540:
1845 GOSUB 400
1850 PRINT"Выведите на экран график частотной х-ки затухания"
1860 PRINT TAB(10);"канала #2"
1870 GOSUB 450 :IF A$="r" OR A$="R" GOTO 1540:
1875 GOSUB 400
1880 GOSUB 3230
1900 PRINT TAB(16);"И сравните рез-ты измерения с предыдущими"
1910 GOSUB 450 :IF A$="r" OR A$="R" GOTO 1700:
1915 N1=0
1920 GOSUB 2870:N1=21:L=2
1930 GOSUB 400
1935 PRINT #1, "Отсчеты выходного сигнала канала #2"
1940 PRINT "Отсчеты выходного сигнала y(t):"
1950 GOSUB 3080:GOSUB 450:IF A$="r" OR A$="R" GOTO 1300
1960 R$="y(y) Отсчеты выходного сигнала канала #2 "
1970 GOSUB 400
1980 PRINT"Выведите на экран значения отсчетов выходного сигнала #2 "
2000 GOSUB 450:IF A$="r" OR A$="R" GOTO 1300
2010 FOR I=0 TO N1+M-1 : G1(I)=D(I)*K : NEXT I : GOSUB 2440
2030 PRINT TAB(14);"Оцените форму импульса после прохождения его"
2040 PRINT TAB(21);"через канал #2";
2050 GOSUB 450
2060 GOSUB 400: IF A$="r" OR A$="R" GOTO 1300
2070 PRINT"Переходите к последнему пункту лабораторной работы"
2080 GOSUB 450:IF A$="r" OR A$="R" GOTO 1300
2090 GOSUB 400
2100 PRINT "Выведите на экран отсчеты импульсной реакции "
2110 PRINT TAB(10);" Преобразователя Гильберта."
2120 GOSUB 450:IF A$="r" OR A$="R" GOTO 1300
2130 GOSUB 400
2140 GOSUB 2320
2150 PRINT "Зарисуйте график имп. реакции преобразователя Гильберта."
2160 GOSUB 450:IF A$="r" OR A$="R" GOTO 1300
2170 R$="Оформите протокол в соответствии с указаниями"
2180 C$="П. 2.6. Методического руководства"
2190 D$="Построение графиков функции выполняйте , используя"
2200 E$="для этого табличные значения отсчетов"
2210 GOSUB 400:PRINT B$
2220 PRINT TAB(10);C$:PRINT:PRINT TAB(10);D$:PRINT TAB(10);E$
2230 GOSUB 450:IF A$="r" OR A$="R" GOTO 1300:
2235 GOSUB 400
2240 PRINT "РАБОТА ЗАКОНЧЕНА !":BEEP
2250 GOTO 4000
2260 '----------------------- П О Д П Р О Г Р А М М Ы ------------------------
2270 '---- Р А С Ч Е Т импульс. реакции преобразователя Гильберта. ----------
2280 D=1.5708:R(0)=0
2290 FOR I=1 TO 10: D1=D*I:R(I)=(SIN(D1))^2/D1*.25 :NEXT I
2300 FOR I1=0 TO 10 :R1(I1)=-R(10-I1):R1(11+I1)=R(I1+1)
2310 NEXT I1:RETURN
2320 ' --------------- ВЫВОД ОТСЧЕТОВ ---------------------
2330 PRINT TAB(10);"Oтсчеты импульсной реакции Преобразователя Гильберта."
2335 FOR I=0 TO 20
2340 PRINT TAB(20);"R(";I;" )= ";:PRINT USING "##.###";R1(I)*2
2350 NEXT I
2360 '-----------------------------------------------------
2370 K=40:GOSUB 450
2380 R$="r(t) Импульсная реакция Преобразователя Гильберта "
2390 FOR I1=0 TO 50: G1(I1)=0: NEXT I1
2400 FOR I2=0 TO 20: G1(I2)=R1(I2)*K: NEXT I2
2410 K=20:L=1:GOSUB 2440:
2420 RETURN
2430 '-----------------------------------------------------
2440 CLS:LOCATE 3,4: PRINT " ^";:PRINT R$
2470 FOR I=0 TO 15
2480 J=(8-I)/K
2490 PRINT USING "##.##";J; : PRINT " │"
2500 NEXT I
2510 O$="--------------------"
2520 LOCATE 12,8
2530 PRINT O$;O$;O$;"> t,mC"
2540 J=10
2550 FOR I=1 TO 5
2560 LOCATE 12,7+J:PRINT"+"
2570 LOCATE 14,6+J:PRINT USING "##";J/2
2580 J=J+10
2590 NEXT I
2600 I1=0:I3=0
2610 FOR I2=0 TO M+N1-1
2620 LOCATE 12-G1(I2),7+I1:PRINT"*"
2630 I1=I1+2
2640 NEXT I2
2650 IF L=2 GOTO 2720
2660 FOR I2=0 TO (M+N1-1)/2
2670 'LOCATE 12.5-G1(I*2),7+I3:PRINT"&"
2680 I3=I3+4
2690 NEXT I2
2720 LOCATE 20,10
2750 RETURN
2860 '---------------------------------------------------------------
2870 GOSUB 400
2880 PRINT "Введите необходимое кол-во отсчетов входного сигнала";:INPUT M
2890 PRINT:PRINT:PRINT
2900 FOR I=0 TO 50: G1(I)=0: NEXT I
2910 PRINT TAB(10);"Введите амплитуды ";M;" отсчетов сигнала"
2920 FOR I1=0 TO M-1
2930 PRINT TAB(20);"X(";I1;")=";:INPUT X(I1):IF X(I1)>1.6 OR X(I1)<-1.6 THEN BEEP:GOTO 2930 ELSE NEXT I1
2940 PRINT:PRINT TAB(10);"Данные введены верно ? Нажмите клавишу <ВК>,"
2950 PRINT TAB(10);"для повторения исходных данных нажмите <R>";
2960 INPUT A$:IF A$="r" OR A$="R" GOTO 2870
2970 GOSUB 400
2980 PRINT"Выведите на экран отсчеты входного сигнала,"
2990 PRINT" измерьте его длительность":K=5:L=2
3000 FOR I2=0 TO M-1: G1(I2)=X(I2)*K: NEXT I2
3010 GOSUB 450 :IF A$="r" OR A$="R" GOTO 2870
3020 R$="x(t) Отсчеты входного сигнала"
3030 GOSUB 2440
3040 PRINT"Пропустите входной сигнал через канал с заданной ФЧХ"
3050 GOSUB 450
3060 RETURN
3070 '------------------- С В Е Р Т К А ----------------------------
3080 PRINT TAB(10);"(ждите, работает программа свертки)"
3085 PRINT#1,
3090 FOR J=0 TO N1+M-1:S1=0
3100 FOR I=0 TO N1-1
3110 IF I>J GOTO 3130
3120 S1=S1+H(I)*X(J-I)
3130 NEXT I
3140 D(J)=S1
3150 NEXT J
3160 FOR J=0 TO N1+M-2 STEP 2
3165 PRINT#1,"Y(";J;")=";D(J),"Y(";J+1;")=";D(J+1)
3170 PRINT TAB(10);"Y(";J;")=";:PRINT USING "##.###";D(J);
3175 PRINT TAB(32);"Y(";J+1;")=";:PRINT USING "##.###";D(J+1)
3180 NEXT J:PRINT
3190 PRINT TAB(10);"Запишите значения отсчетов выходного сигнала"
3195 PRINT#1,
3200 RETURN
3210 '--------------------------------------------------------------
3230 CLS
3240 LOCATE 3,5
3250 PRINT" ^ A(f),ДБ Частотная характеристика затухания канала #";L2
3260 FOR I=0 TO 15
3270 J=(16-I)*5
3280 PRINT USING "###.##";J;:PRINT " │"
3290 NEXT I
3295 V$="------------------"
3300 PRINT " │-";V$;V$;V$;">"
3310 LOCATE 20,68
3320 PRINT"f,ГЦ."
3330 J=0
3340 FOR I=0 TO 5
3350 LOCATE 20,8+J:PRINT"+"
3360 LOCATE 21,7+J:PRINT I*100
3370 J=J+10:NEXT I
3380 I1=0
3390 FOR I2=0 TO N2-1
3400 LOCATE 20-W(I2),8+I2:PRINT"*"
3410 I1=I1+4:NEXT I2
3420 LOCATE 22,15
3430 PRINT" Измерьте величину затухания на частотах 100..500 гц"
3450 GOSUB 450:RETURN
3460 '--------------------------------------------------------------
3470 CLS : LOCATE 2,28
3490 PRINT"^ ГРАД. Фазо-частотная характеристика канала #";L2
3500 FOR I=0 TO 16 : J=(8-I)*K
3520 LOCATE 3+I,22:PRINT USING "#### ";J;:PRINT CHR$(179) : NEXT I
3550 LOCATE 11,2
3560 PRINT"-----------------------------------------------....------> f,ГЦ."
3570 J=0
3580 FOR I3=0 TO 10: I1=(I3-5)*10
3590 LOCATE 11,3+J:PRINT "+"
3600 LOCATE 12,2+J:PRINT USING "###";I1
3610 J=J+5:NEXT I3
3620 LOCATE 12,53:PRINT"500":I2=0
3630 FOR I=0 TO 8
3640 LOCATE 18-F(I),8+I2:PRINT"*"
3650 I2=I2+5:NEXT I
3660 LOCATE 21,3
3670 PRINT"Зарисуйте график фазо-частотной х-ки канала #1 и рассчитайте"
3680 PRINT TAB(3);"по ней частотную характеристику ГВП.";
3690 GOSUB 450 : RETURN
3700 '--------------------------------------------------------------
3710 CLS
3720 LOCATE 3,27
3730 PRINT"^ ГРАД. Фазо-частотная характеристика канала #";L2
3740 FOR I=0 TO 16:J=(8-I)*K
3750 LOCATE 4+I,22:PRINT USING"####";J; : PRINT " │"
3770 NEXT I
3780 LOCATE 12,3
3790 PRINT"---------------------------------------------....------> f,ГЦ."
3800 J=0
3810 FOR I3=0 TO 10
3820 I1=(I3-5)*10
3830 LOCATE 12,2+J:PRINT"+"
3840 LOCATE 13,1+J:PRINT USING "###";I1
3850 J=J+5:NEXT I3
3860 LOCATE 13,52:PRINT"500"
3870 I2=0
3880 FOR I=0 TO 9
3890 LOCATE 12-F(I),2+I2:PRINT"*"
3900 I2=I2+5:NEXT I
3910 LOCATE 12-F(7),28:PRINT"*"
3920 LOCATE 22,3
3930 PRINT TAB(10);"Зарисуйте график фазо-частотной х-ки канала #2"
3950 RETURN
4000 CLOSE #1
4005 GOSUB 450:CLS
4010 OUT 989,0
|
|
|
Отправлено: 22:55, 22-04-2011 | #2 |
|
Новый участник Сообщения: 49
|
Профиль | Сайт | Отправить PM | Цитировать Спасибо огромное! Я в GW-BASIC'е делал методом - F3 (Load) и потом F4 (Save), и выходили все те же непонятные символы, а вот команды не смотрел. Спасибо еще раз!
|
|
Отправлено: 23:14, 22-04-2011 | #3 |
Необычный
Сообщения: 4463
|
Профиль | Сайт | Отправить PM | Цитировать Iska, спасибо, ценно, я не знал про этот формат. С текстового QBasic начинал.
|
|
------- Отправлено: 00:12, 23-04-2011 | #4 |
|
Ветеран Сообщения: 27449
|
Профиль | Отправить PM | Цитировать Хе-хе, у меня даже русская версия наличествует (версии 1.0), позаимствованная в своё время с немецкой Siemens'овской машинки, шедшей в комплекте с локализованной MS DOS 5.0, у одного знакомого из ЗГВ
 : |
|
|
Отправлено: 02:07, 23-04-2011 | #5 |
|
Ветеран Сообщения: 3487
|
Профиль | Сайт | Отправить PM | Цитировать А я вообще с программированием не знаком. Вы такие молодцы. "Полезное сообщение".
|
|
------- Отправлено: 09:19, 23-04-2011 | #6 |
|
Участник сейчас на форуме |
 |
Участник вне форума |
 |
Автор темы |
 |
Сообщение прикреплено |
| |||||
| Название темы | Автор | Информация о форуме | Ответов | Последнее сообщение | |
| Помогите подобрать конфигурацию | SolVeig | Выбор отдельных компонентов компьютера и конфигурации в целом | 4 | 28-12-2010 22:08 | |
| Помогите подобрать наушники | БелыйКлык | Выбор отдельных компонентов компьютера и конфигурации в целом | 1 | 22-09-2010 21:10 | |
| Помогите подобрать | VbInt | Выбор отдельных компонентов компьютера и конфигурации в целом | 1 | 15-06-2010 00:38 | |
| Помогите подобрать | Pavel__ | Видеокарты | 2 | 26-05-2010 15:26 | |
| помогите подобрать системник | Half | Выбор отдельных компонентов компьютера и конфигурации в целом | 9 | 09-01-2009 17:29 | |
|
|
Время: 05:42. | © OSzone.net 2001-
|
|
Powered by: vBulletin Copyright ©2000 - 2025, Jelsoft Enterprises Ltd. |
