[megaloman]

Вот вариант

Код:

@Echo Off
Cls 

Set "FileIn=xxx.txt"

Set /A Found=0
If Exist "%FileIn%" (
	find /i "404 Not Found" "%FileIn%" >Nul &&Set /A Found=1
	find /i "403 Forbidden" "%FileIn%" >Nul &&Set /A Found=1
	find /i "501 Not Implemented" "%FileIn%" >Nul &&Set /A Found=1
)
If %Found%==1 Echo tralala
pause

Чуть короче, но медленнее

Код:

@Echo Off
Cls 

Set "FileIn=xxx.txt"

Set /A Found=0

find /i "404 Not Found" "%FileIn%" >Nul &&Set /A Found=1
find /i "403 Forbidden" "%FileIn%" >Nul &&Set /A Found=1
find /i "501 Not Implemented" "%FileIn%" >Nul &&Set /A Found=1

If %Found%==1 Echo tralala
pause

[greg zakharov]

Код:

findstr /irc:"[4-5]0[1,3,4] [not|forbidden]" xxx.txt

[Freddy1984]

[4-5]0[1,3,4] »

можно вас попросить расшифровать значение этих цифр?
И ещё доп. вопросик. Если у примеру мне ещё понадобится добавить ответ от сервака к примеру 500 Internal Server Error, то как я понял надо будет сделать так [not|forbidden|Internal Server Error] ??

[Iska]

findstr — да, но я бы делал не регуляркой, а тупым перечислением (на будущее):

Код:

type "xxx.txt" | findstr.exe /i /l /c:"404 Not Found" /c:"403 Forbidden" /c:"501 Not Implemented" && (
    echo Found
)

Update: ну, собственно, вот будущее:

Если у примеру мне ещё понадобится добавить ответ от сервака »

уже и наступило .

Код:

type "xxx.txt" | findstr.exe /i /l /c:"404 Not Found" /c:"403 Forbidden" /c:"500 Internal Server Error" /c:"501 Not Implemented" && (
    echo Found
)

[Freddy1984]

уже и наступило »

[greg zakharov]

можно вас попросить расшифровать значение этих цифр?

Это шаблон числового значения, который должен присутствовать в строке.

но я бы делал не регуляркой

А аргументы в пользу перечисления? Ну будете Вы искать строки дословно и что? Или Вы полагаете, что за раз все заданные выражения из потока извлекутся? И потом, проще подправить регулярку, например:

Код:

findstr /irc:"[4-5]0[0-1,3-4] [not|int|for]" xxx.txt

чем набивать новое выражение для поиска. Но, есть одно обстоятельство, умаляющее роль штатного инструментария Windows (в том числе findstr). Во-первых, ограничение длины строки, накладываемое на findstr, то есть при использовании регулярок захватывается не часть строки (как это делает, например, grep), а строка целиком, и если длина строки превышает предельно допустимую, выводится соответсвующее сообщение. То же, кстати, справедливо и для поиска со строгим соответствием (ключ /L), а раз так, а также то, что регулярки значительно компактней, то и смысл затевать перечисления невелик. По этой причине лучше использовать:
1) более продвинутые инструменты поиска соответствий в строке
2) регулярные выражения

[Iska]

А аргументы в пользу перечисления? »

Я ж написал — так проще для коррекции списка, нежели подбирать регулярки. И посему никак не могу согласиться с Вами в:

проще подправить регулярку, … чем набивать новое выражение для поиска. »

В чём проблема регулярок как таковых? В маловменяемости шаблонов для понимания, в жёстком ограничении на входные данные.

[greg zakharov]

В чём проблема регулярок как таковых? В маловменяемости шаблонов для понимания, в жёстком ограничении на входные данные.

Эти условия соответсвуют правде тогда (и только тогда), когда регулярные выражения либо не знают, либо не понимают. А список - это не аргумент. Представьте сто (или более) шаблонных строк, имеющих схожие признаки. Вы будете составлять список или все же будете использовать регулярное выражение из пары десятков символов? Можно было бы сказать, что выбор очевиден (а он и впрямь очевиден), но хотелось бы выслушать Ваши контраргументы и увидеть очередные благодарности к ним со стороны третьих лиц

[Busla]

greg zakharov, проблема в ложных срабатываниях, т.к. шаблон шире. Сейчас это прокатывает, т.к. по сути автору нужно отфильтровать всё, что не "200 OK"