[Iska]

alex19451, вопрос в чём?

[alex19451]

вопрос в чём? »

Почему не работает скрипт. Данный скрипт распространен в инете, ошибка 57 строке не знаю даже в чем. ОС Windows server 2012 r2. Может быть кто-то сталкивался с такой проблемой....

[Iska]

ошибка 57 строке не знаю даже в чем. »

В том, что указанный объект не существует/не может быть найден в каталоге. Потому и ошибка.

Для начала Вам стоит избавиться от незначимых пробелов либо непосредственно в текстовом файле, либо убирать их при разборе текстового файла.

[alex19451]

В том, что указанный объект не существует/не может быть найден в каталоге. Потому и ошибка. Для начала Вам стоит избавиться от незначимых пробелов либо непосредственно в текстовом файле, либо убирать их при разборе текстового файла. »

Все пробелы убрал. Та же самая ошибка "Объект на сервере отсутствует". Строка 57 Символ 2

[alex19451]

Set objOU = GetObject("LDAP://OU=SIB,ASOIU" & ContainerDN) ставил так. выводит ошибку 80005000

[Iska]

alex19451, я пока пытаюсь привести кошмарный код к мало-мальски вменяемому виду.

Попробуйте так:

Скрытый текст

Код:

Option Explicit

Dim strSourceFile

Dim objFSO

Dim arrContent
Dim strLine
Dim arrRecord

Dim strDomainDNSName
Dim strDomainDN
Dim strContainerDN


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FileExists(strSourceFile) Then
		With objFSO.OpenTextFile(strSourceFile)
			arrContent = Split(.ReadAll(), vbCrLf)
			
			.Close
		End With
		
		strDomainDNSName = WScript.CreateObject("ADSystemInfo").DomainDNSName
		strDomainDN = GetObject("LDAP://RootDSE").Get("DefaultNamingContext")
		
		For Each strLine In arrContent
			arrRecord = Split(strLine, ";")
			
			If UBound(arrRecord) = 7 Then
				strContainerDN = "ou=" & arrRecord(6) & "," & strDomainDN
				
				'!!! ВАЖНО !!!***Указываем ЗАРАНЕЕ СОЗДАННУЮ OU в которую кидаются новые пользователи *******
				
				' Создаем аккаунт пользователя домена
				With GetObject("LDAP://" & strContainerDN).Create("User", "cn=" & arrRecord(0))
					.Put "sAMAccountName", arrRecord(0) ' Login
					.SetInfo
				End With
				
				With GetObject("LDAP://cn=" & arrRecord(0) & "," & strContainerDN)
					.AccountDisabled = False  ' Enable account
					.SetPassword arrRecord(1) ' пароль
					
					.Put "userPrincipalName", arrRecord(0) & "@" & strDomainDNSName     ' UPN
					.Put "givenName",         arrRecord(2)                              ' Имя
					.Put "sn",                arrRecord(3)                              ' Фамилия
					.Put "displayName",       arrRecord(3) & " " & arrRecord(2)         ' Выводимое имя
					.Put "initials",          _
						Left(Split(arrRecord(2))(0), 1) & "." & _
						Left(Split(arrRecord(2))(1), 1) & "."                           ' Инициалы
					.Put "title",             arrRecord(4)                              ' Должность
					.Put "department",        arrRecord(5)                              ' Отдел
					.Put "Company",           arrRecord(6)                              ' Организация
					
					.Put "pwdLastSet", CLng(0)       ' Уст. Требовать смену пароля при следующем входе в систему
					.Put "ProfilePath", arrRecord(7) ' Адрес папки перемещаемого профиля пользователя
					
					.SetInfo
				End With
				
				WScript.Echo "Пользователь — " & arrRecord(6) & " добавлен в AD"
			Else
				WScript.Echo "Line [" & strLine & "] has not 7 items."
			End If
		Next
		
		WScript.Echo "Пользователи добавлены в AD"
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Добавляет пользователей в домен."
	WScript.Echo "create_users.vbs [имя файла]"
	WScript.Echo " user.txt[имя файла] — файл со списком пользователей"
	WScript.Echo " формат файла: Логин; Пароль; Имя-Отчество; Фамилия; Должность; Отдел; OU(Организация); Адрес папки профиля"
	
	WScript.Quit 1
End If

WScript.Quit 0

Содержимое исходного файла:

Код:

manager4;1qaz2WSX;Ivan Ivanovich;Ivanov;manager;management;ASOIU;\\WINSERVER\Profiles\manager4
security3;1qaz2WSX;Petr Petrovich;Petrov;security;security;SIB;\\WINSERVER\Profiles\security3

Пробелы — значимые символы. В конце строки не надо ставить лишний разделитель «;».

[alex19451]

Все тоже самая ошибка на 40 строке. Скрипт который выше я взял из хабра. не уверен, что можно здесь ссылки указывать.

[Iska]

Все тоже самая ошибка на 40 строке. »

Покажите скриншот консоли AD «Пользователи и компьютеры», на котором будет видно, что Вы действительно создали в корне домена подразделения (OU) «ASOIU» и «SIB» из примера.

Скрипт который выше я взял из хабра. не уверен, что можно здесь ссылки указывать. »

Ссылки указывать можно, но особого смысла не вижу, исходный код попросту кошмарен.

[alex19451]

Ссылки указывать можно, но особого смысла не вижу, исходный код попросту кошмарен. »

http://habrahabr.ru/post/146980/ Вот ссылка.
https://www.dropbox.com/s/svbmo5ud60...D0%B9.jpg?dl=0