[gora]

Код:

@Echo Off
Set src=C:\asd\bkb\example.sql
Set arch=E:\archive\
Set bak=E:\backups\
Set ar7z=c:\Program Files\7-Zip\7z.exe

For /f "delims=+-" %%i In ('WMIC OS Get LocalDateTime^|Find "."') Do Set DT=%%i
"%ar7z%" a "%arch%\%DT:~2,2%%DT:~4,2%%DT:~6,2%.%DT:~8,2%%DT:~10,2%.zip" "%src%" -ssw>Nul
Move "%src%" "%bak%">Nul

Pause

[xe11o]

спасибо!

[firstarey]

вот Вам и rar и 7-z

Код:

@title [ARHIV]
@echo off
Color 0e

rem  --------------rar---------------------
rem  параметры архиватора
set RAR="C:\Program Files\WinRAR\WinRAR.exe"
set RAR_param=a -r -rr15p -os -ow -t -ag+YYYY-MM-DD D:\backup\
set RAR_arhive=C:\asd\bkb\example.sql

rem  создаем архив:
%RAR% %RAR_param% %RAR_arhive%
rem  --------------rar---------------------


rem  --------------7-z---------------------
rem  дата и время
set DD=%date:~0,2%
set DM=%date:~3,2%
set DY=%date:~6,4%
set TH=%TIME:~0,2%
set TM=%TIME:~3,2%

rem  Степень сжатия файлов (3 - минимальная, 5 - нормальная, 7 - максимальная)
set Level=5
rem  Полное имя архива
set PathArch=D:\backup\%DY%-%DM%-%DY%.%TH%-%TM%.zip
rem  Задаем целевой каталог, куда будем складывать 
set RAR_arhive=C:\asd\bkb\example.sql

rem  Определяем расположение архиватора 7Zip через реестр
For /F "UseBackQ Tokens=2*" %%A In (`Reg Query "HKCU\Software\7-Zip"^|Find /I "Path"`) Do Set $7Zip=%%B
if not defined $7Zip (echo Архиватор 7Zip не установлен & pause>nul & goto :eof)
rem  Добавляем бекслэш \ если его нет (установщики msi и exe по-разному прописывают путь в реестре)
if %$7Zip:~-1% NEQ \ Set $7zip=%$7Zip%\

rem  создаем архив:
"%$7zip%7z.exe" a -tzip -mx%Level% "%PathArch%" "%RAR_arhive%"
rem  --------------7-z---------------------

pause

gora, как включили подсветку кода в сообщении ?

[gora]

как включили подсветку кода в сообщении ? »

Так