[Georgio]

А вообще я батникам удивляюсь, для каждого чиха язык заново почти что создавать надо! ((( »

Это уж точно. "Бои без правил". Но в этом их прелесть.


Вы это хотели получить в результате:

Код:

@echo off
setlocal enabledelayedexpansion
set n=
for %%i in (key1=value1;key2=value2;key3=value3) do (
  set /a n+=1
  if !n!==1 (
   set key=%%i
) else (
   set !key!=%%i
   set n=
  )
)
set key=
set key
pause>nul
endlocal
exit /b

???

[Sphinx114]

Применил небольшую хитрость:

Код:

@echo off
set "str=key1=value2;key2=value2;key3=value3"
set %str:;=&set %
set k
pause

[Acuna]

Это уж точно. "Бои без правил". Но в этом их прелесть.

Вот-вот, я бы даже сказал "на любителя"!)
Лично я предпочитаю, чтобы язык все-таки подчинялся каким-либо законам)

Спасибо, оба приема действительно режут. Но я, возможно, не совсем точно описал задачу. В итоге мне нужно выводить эти переменные в echo.

То есть echo %key1% выведет value1, echo %key2% выведет value2 и т. д. А изначально строка должна быть именно строкой (она будет вводиться как аргумент функции). Вообще, суть в том, что в батник нужно вбросить около 50 значений (то есть больше 9 возможных). Вот я и хотел их ввести всего одним аргументом...

[Georgio]

около 50 значений (то есть больше 9 возможных) »

Возможно и более 50 значений. Например, вот так:

Код:

@echo off
call:# "key1=value1" "key2=value2" "key3=value3" "key4=value4" "key5=value5"^
 "key6=value6" "key7=value7" "key8=value8" "key9=value9" "key10=value10"^
 "key11=value11" "key12=value12" "key13=value13" "key14=value14" "key15=value15"

echo %key1%
echo %key2%
echo %key3%
echo %key4%
echo %key5%
echo %key6%
echo %key7%
echo %key8%
echo %key9%
echo %key10%
echo %key11%
echo %key12%
echo %key13%
echo %key14%
echo %key15%

echo.

rem Или проще:
for /l %%i in (1 1 15) do call echo %%key%%i%%

pause>nul
exit /b

:#
for %%i in (%*) do set %%i
exit /b

[Acuna]

Ах да, действительно, решение

Код:

for %%i in (%*) do set %%i

оказалось наредкость изящным, а главное действенным. И без присущей батникам лишней писанины.

Код:

rem Или проще:
for /l %%i in (1 1 15) do call echo %%key%%i%%

Это понятно, просто количество аргументов изначально не известно. В том-то и прелесть этой задачи: юзер может ввести различное количество аргументов. Получается что-то сродни массиву.

А что, если эту задачу немного усложнить, скажем еще одним аргументом ввести просто переменную:

Код:

set var=ggg
moysuperbatnik.bat %var% "key1=value1" "key2=value2"

Что самое интересное, echo %1 в moysuperbatnik.bat при этом работает, но выводит сообщение "Переменная var не определена". Хотя ggg выводит. Это сообщение можно просто подавить, но боюсь того, как он может себя при этом повести на разных машинах...

[Foreigner]

Что самое интересное, echo %1 в moysuperbatnik.bat при этом работает, но выводит сообщение "Переменная var не определена" »

У меня все в порядке:

Код:

:: Вызывать -- mybatch.cmd %var% "key1=1;key2=2;key3=3"

@echo off
setlocal

echo %1
set str="%~2"

for %%i in (%str:;=","%) do set %%i

set key

[Acuna]

Foreigner, ой, да этот mybatch.cmd выкинул мне все мои установленные переменные и плюс надпись "Переменная среды key не определена". Это он ругается на строку set key(

Мне бы только второй аргумент распарсить в mybat.bat:

Код:

mybatch.cmd %var% "key1=value1;key2=value2;key3=value3"

А все остальные передавать в него as is...

Ну все равно, ларчик хоть и фомкой, но все-равно уже потихоньку поддается)

[Foreigner]

выкинул мне все мои установленные переменные и плюс надпись "Переменная среды key не определена" »

[Iska]

Изображения Тип файла: png 1.png »

Foreigner, «Console2»?